Queridos todos,
Tengo una pregunta sobre los límites de Bonferroni. Mi objetivo es desarrollar un proceso de evaluación de datos en el que se puedan detectar valores atípicos utilizando los límites de Bonferroni. Mi conjunto de datos consta de pruebas de lanzamiento, a las que se agregan datos adicionales a intervalos regulares. Por supuesto, también podría usar el Stud. Residual Plot de Fit Model Platform, pero me gustaría automatizar la detección de valores atípicos a través de los límites de Bonferroni y no tener que hacerlo manualmente usando el gráfico. ¿Hay alguna forma de extraer los valores de los Límites de Bonferroni del Stud? ¿Parcelas residuales? Un pequeño Script aquí también funcionaría para mí. Ya había hablado de esto con @Jonas_Rinne y me recomendó tratar esta pregunta aquí en la comunidad.
¡Gracias por adelantado!
mejor johann
Utilice este ejemplo que ilustra cómo acceder al valor utilizado para trazar la línea de los límites de Bonferroni.
Names Default To Here( 1 );
// example
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
// fit least squares with studentized residuals
obj = dt << Fit Model(
Y( :ABRASION ),
Effects( :SILICA, :SILANE, :SULFUR ),
Personality( "Standard Least Squares" ),
Emphasis( "Minimal Report" ),
Run(
:ABRASION << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
Parameter Estimates( 1 ), Scaled Estimates( 0 ),
Plot Actual by Predicted( 0 ), Plot Regression( 0 ),
Plot Residual by Predicted( 0 ), Plot Studentized Residuals( 1 ),
Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
Box Cox Y Transformation( 0 )}
)
);
// access report layer
rpt = obj << Report;
// access plot frame
frame = rpt["Studentized Residuals"][FrameBox(1)];
// access line segments in plot frame
line = frame << Find Segs;
// ask for value of line representing Bonferroni limits (only positive necessary)
bonferroni = (line[2] << Get Y Values)[1];
// display limit in Log
Show( bonferroni );¡Muchas gracias por la solución, para mí el script funciona perfectamente!
mejor johann
