Carissimi,
Ho una domanda sui limiti Bonferroni. Il mio obiettivo è sviluppare un processo di valutazione dei dati in cui i valori anomali possono essere rilevati utilizzando i Bonferroni Limits. Il mio set di dati è costituito da test di rilascio, a cui vengono aggiunti dati aggiuntivi a intervalli regolari. Ovviamente potrei anche usare lo Stud. Grafico residuo della piattaforma del modello Fit, ma vorrei automatizzare il rilevamento dei valori anomali tramite Bonferroni Limits e non doverlo fare manualmente utilizzando il grafico. C'è un modo per estrarre i valori dei Limiti Bonferroni dello Stud. Appezzamenti residui? Un piccolo script qui funzionerebbe anche per me. Ne avevo già discusso con @Jonas_Rinne e mi ha raccomandato di affrontare questa domanda qui nella comunità.
Grazie in anticipo!
Miglior Johann
Si prega di utilizzare questo esempio che illustra come accedere al valore utilizzato per tracciare la linea per i limiti Bonferroni.
Names Default To Here( 1 );
// example
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
// fit least squares with studentized residuals
obj = dt << Fit Model(
Y( :ABRASION ),
Effects( :SILICA, :SILANE, :SULFUR ),
Personality( "Standard Least Squares" ),
Emphasis( "Minimal Report" ),
Run(
:ABRASION << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
Parameter Estimates( 1 ), Scaled Estimates( 0 ),
Plot Actual by Predicted( 0 ), Plot Regression( 0 ),
Plot Residual by Predicted( 0 ), Plot Studentized Residuals( 1 ),
Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
Box Cox Y Transformation( 0 )}
)
);
// access report layer
rpt = obj << Report;
// access plot frame
frame = rpt["Studentized Residuals"][FrameBox(1)];
// access line segments in plot frame
line = frame << Find Segs;
// ask for value of line representing Bonferroni limits (only positive necessary)
bonferroni = (line[2] << Get Y Values)[1];
// display limit in Log
Show( bonferroni );Grazie mille per la soluzione, per me lo script funziona perfettamente!
Miglior Johann
