Verehrte Gäste,
Ich habe eine Frage zu den Bonferroni-Grenzwerten. Mein Ziel ist es, ein Datenauswertungsverfahren zu entwickeln, bei dem anhand der Bonferroni-Limits Ausreißer erkannt werden können. Mein Datensatz besteht aus Releasetests, zu denen in regelmäßigen Abständen weitere Daten hinzugefügt werden. Natürlich könnte ich auch den Stud verwenden. Restdiagramm der Fit-Model-Plattform, aber ich möchte die Ausreißererkennung über Bonferroni-Grenzwerte automatisieren und muss dies nicht manuell mithilfe des Diagramms tun. Gibt es eine Möglichkeit, die Werte der Bonferroni-Grenzwerte des Gestüts zu extrahieren? Restgrundstücke? Ein kleines Script würde hier auch für mich funktionieren. Ich hatte das bereits mit besprochen @Jonas_Rinne und er empfahl mir, diese Frage hier in der Community anzusprechen.
Vielen Dank im Voraus!
Bester Johann
Vielen Dank für die Lösung, bei mir funktioniert das Skript perfekt!
Bester Johann
Bitte verwenden Sie dieses Beispiel, das zeigt, wie Sie auf den Wert zugreifen, der zum Zeichnen der Linie für die Bonferroni-Grenzwerte verwendet wird.
Names Default To Here( 1 );
// example
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );
// fit least squares with studentized residuals
obj = dt << Fit Model(
Y( :ABRASION ),
Effects( :SILICA, :SILANE, :SULFUR ),
Personality( "Standard Least Squares" ),
Emphasis( "Minimal Report" ),
Run(
:ABRASION << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
Parameter Estimates( 1 ), Scaled Estimates( 0 ),
Plot Actual by Predicted( 0 ), Plot Regression( 0 ),
Plot Residual by Predicted( 0 ), Plot Studentized Residuals( 1 ),
Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
Box Cox Y Transformation( 0 )}
)
);
// access report layer
rpt = obj << Report;
// access plot frame
frame = rpt["Studentized Residuals"][FrameBox(1)];
// access line segments in plot frame
line = frame << Find Segs;
// ask for value of line representing Bonferroni limits (only positive necessary)
bonferroni = (line[2] << Get Y Values)[1];
// display limit in Log
Show( bonferroni );
