567691_zh-CN

liliconcom

使用 Bonferroni 限制自动识别异常值

亲爱的大家，

 

我有一个关于 Bonferroni 限制的问题。 我的目标是开发一个数据评估过程，在这个过程中可以使用 Bonferroni 限制检测异常值。 我的数据集由发布测试组成，定期向其中添加额外的数据。 当然，我也可以使用 Stud。 拟合模型平台的残差图，但我想通过 Bonferroni 限制自动检测异常值，而不必使用该图手动进行。 有没有办法提取螺柱的 Bonferroni 极限值。 残差图？ 一个小脚本在这里也适用于我。 我已经讨论过这个问题@Jonas_Rinne他建议我在社区中解决这个问题。

 

提前谢谢！

 

最佳约翰

 

 

 

分析脚本回复：使用 Bonferroni 限制自动识别异常值

请使用此示例说明如何访问用于绘制 Bonferroni 限制线的值。

 

Names Default To Here( 1 );

// example
dt = Open( "$SAMPLE_DATA/Tiretread.jmp" );

// fit least squares with studentized residuals
obj = dt << Fit Model(
 Y( :ABRASION ),
 Effects( :SILICA, :SILANE, :SULFUR ),
 Personality( "Standard Least Squares" ),
 Emphasis( "Minimal Report" ),
 Run(
  :ABRASION << {Summary of Fit( 1 ), Analysis of Variance( 1 ),
  Parameter Estimates( 1 ), Scaled Estimates( 0 ),
  Plot Actual by Predicted( 0 ), Plot Regression( 0 ),
  Plot Residual by Predicted( 0 ), Plot Studentized Residuals( 1 ),
  Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
  Box Cox Y Transformation( 0 )}
 )
);

// access report layer
rpt = obj << Report;

// access plot frame
frame = rpt["Studentized Residuals"][FrameBox(1)];

// access line segments in plot frame
line = frame << Find Segs;

// ask for value of line representing Bonferroni limits (only positive necessary)
bonferroni = (line[2] << Get Y Values)[1];

// display limit in Log
Show( bonferroni );

回复：使用 Bonferroni 限制自动识别异常值

非常感谢您的解决方案，对我来说，脚本完美运行！

 

最佳约翰