565412_it-IT

liliconcom

Le carte di controllo utilizzano i limiti di controllo salvatiCiao,

Spero tu stia bene.

Ho una domanda sui limiti di controllo salvati in una tabella di dati. C'è un modo per proporre all'utente una casella di testo che mostri tutti i limiti di controllo salvati in una tabella di dati. E l'utente può mettere un segno di spunta su quello da utilizzare per il Grafico di controllo?

Grazie mille per la risposta e buona giornata,

JeanSceneggiaturaRe: Le carte di controllo utilizzano i limiti di controllo salvati

Intendi le proprietà della colonna dei limiti di controllo? Questo potrebbe essere fatto con lo scripting ma non sono sicuro che tu possa "disabilitare" le proprietà della colonna. Quindi potrebbe essere necessario salvarli in un'altra tabella/variabile di tabella/variabile e quindi aggiungerli/rimuoverli secondo necessità.

Re: Le carte di controllo utilizzano i limiti di controllo salvatiAh si, voglio dire: la mia domanda era come posso usare i limiti di controllo (salvati in un'altra tabella) con una casella di testo dinamica?Re: Le carte di controllo utilizzano i limiti di controllo salvati

Ecco un esempio abbastanza semplificato di come potresti farlo.

// https://www.jmp.com/support/help/en/16.2/#page/jmp/example-of-control-limits.shtml#ww1447886

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Steam Turbine Historical.jmp");


dt_specs = New Table("Turbine Specs",
 Add Rows(3),
 New Column("Measurement", Character, Nominal, Values({"Fuel", "MW", "Cool Temp"})),
 New Column("LCL", Numeric, Continuous, Values([200000, 19, 53])),
 New Column("UCL", Numeric, Continuous, Values([250000, 22, 55])),
 invisible
);

possible_measurements = Column(dt_specs, "Measurement") << get values;
nw = New Window("Select Limits", << modal, << return result,
 V List Box(
  Text Box("Select measurements to use predefined specs limits for:"),
  cb_selections = Check Box(possible_measurements, << Set(1))
 );
);

aa_specs = Associative Array();
For Each({selection_idx}, nw["cb_selections"],
 aa_specs[possible_measurements[selection_idx]] = dt_specs[selection_idx, {"LCL", "UCL"}];
);

obj = dt << Control Chart Builder(
 Show Control Panel(0),
 Variables(Y(:Fuel)),
);

If(Contains(aa_specs, "Fuel"),
 Eval(EvalExpr(
  obj << Chart(Position(1), Set Control Limits({
   LCL(Expr(aa_specs["Fuel"][1])), UCL(Expr(aa_specs["Fuel"][2]))
  }))
 )); 
);
Write();

Il modo in cui dovresti farlo dipende dai tuoi dati di misurazione iniziali, dalla tabella dei limiti di controllo, da come desideri visualizzare i grafici di controllo, da quanto dinamico e robusto ne hai bisogno, dal tuo livello di abilità di scripting e così via