565412_de-DE

liliconcom

Regelkarten verwenden gespeicherte RegelgrenzenHallo,

Ich hoffe, es geht dir gut.

Ich habe eine Frage zu den in einer Datentabelle gespeicherten Kontrollgrenzen. Gibt es eine Möglichkeit, dem Benutzer ein Textfeld vorzuschlagen, das alle in einer Datentabelle gespeicherten Eingriffsgrenzen anzeigt? Und der Benutzer kann ein Häkchen bei dem setzen, das für das Kontrolldiagramm verwendet werden soll?

Vielen Dank für Ihre Antwort und einen schönen Tag,

JeanSkripterstellungBetreff: Regelkarten verwenden gespeicherte Regelgrenzen

Meinst du die Spalteneigenschaften der Kontrollgrenzen? Dies könnte mit Skripten erfolgen, aber ich bin mir nicht sicher, ob Sie die Spalteneigenschaften "deaktivieren" können. Sie müssen sie also möglicherweise in einer anderen Tabelle/Tabellenvariablen/Variablen speichern und sie dann nach Bedarf hinzufügen/entfernen.

Betreff: Regelkarten verwenden gespeicherte RegelgrenzenAh ja, ich meine: Meine Frage war, wie kann ich die Eingriffsgrenzen (in einer anderen Tabelle gespeichert) mit einem dynamischen Textfeld verwenden?Betreff: Regelkarten verwenden gespeicherte Regelgrenzen

Hier ist ein ziemlich vereinfachtes Beispiel, wie Sie es tun könnten.

// https://www.jmp.com/support/help/en/16.2/#page/jmp/example-of-control-limits.shtml#ww1447886

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Steam Turbine Historical.jmp");


dt_specs = New Table("Turbine Specs",
 Add Rows(3),
 New Column("Measurement", Character, Nominal, Values({"Fuel", "MW", "Cool Temp"})),
 New Column("LCL", Numeric, Continuous, Values([200000, 19, 53])),
 New Column("UCL", Numeric, Continuous, Values([250000, 22, 55])),
 invisible
);

possible_measurements = Column(dt_specs, "Measurement") << get values;
nw = New Window("Select Limits", << modal, << return result,
 V List Box(
  Text Box("Select measurements to use predefined specs limits for:"),
  cb_selections = Check Box(possible_measurements, << Set(1))
 );
);

aa_specs = Associative Array();
For Each({selection_idx}, nw["cb_selections"],
 aa_specs[possible_measurements[selection_idx]] = dt_specs[selection_idx, {"LCL", "UCL"}];
);

obj = dt << Control Chart Builder(
 Show Control Panel(0),
 Variables(Y(:Fuel)),
);

If(Contains(aa_specs, "Fuel"),
 Eval(EvalExpr(
  obj << Chart(Position(1), Set Control Limits({
   LCL(Expr(aa_specs["Fuel"][1])), UCL(Expr(aa_specs["Fuel"][2]))
  }))
 )); 
);
Write();

Wie Sie dies tun sollten, hängt von Ihren Ausgangsmessdaten, der Regelgrenzentabelle, davon ab, wie Sie Regelkarten anzeigen möchten, wie dynamisch und robust Sie dies benötigen, von Ihrem Scripting-Fähigkeitsniveau und so weiter