561474_es-ES

liliconcom

Etiqueta de valor

Estoy intentando cambiar valores en varias columnas mediante un bucle For y una declaración If. Lamentablemente, si bien crea las nuevas columnas correctamente, por alguna razón los valores de la segunda columna también se copian en la primera. ¿Qué me estoy perdiendo?

New Table( "Untitled 11",
	Add Rows( 4 ),
	New Column( "Column_1",
		Character,
		"Nominal",
		Set Values( {"A1000", "A2000", "A3000", "A4000"} )
	),
	New Column( "Column_2",
		Character,
		"Nominal",
		Set Values( {"B5000", "B6000", "B7000", "B8000"} )
	)
);

OldColNames = { "Column_1", "Column_2" };

NewColNames = { "New_Column_1", "New_Column_2" };

nCols = N Items( OldColNames );

For( i = 1, i <= nCols, i++, 

	oldcol = OldColNames[i];
	newcol = NewColNames[i];

	New Column( newcol,
		Character,
		"Nominal",
		Formula(
			If(
				"A10" <= Left( As Column( oldcol ), 3 ) <= "A19", "A-One",
				"A20" <= Left( As Column( oldcol ), 3 ) <= "A29", "A-Two",
				"A30" <= Left( As Column( oldcol ), 3 ) <= "A39", "A-Three",
				"A40" <= Left( As Column( oldcol ), 3 ) <= "A49", "A-Four",
				"B50" <= Left( As Column( oldcol ), 3 ) <= "B59", "B-Five",
				"B60" <= Left( As Column( oldcol ), 3 ) <= "B69", "B-Six",
				"B70" <= Left( As Column( oldcol ), 3 ) <= "B79", "B-Seven",
				"B80" <= Left( As Column( oldcol ), 3 ) <= "B89", "B-Eight",
			)
		)
	);
);

¡Gracias!

Modelado estadístico avanzadoInvestigación de mercado y consumoAcceso a datosCombinación y limpieza de datosIngeniería de Calidad y ProcesosRe: Etiqueta de valor

Es porque el nombre col viejo dentro de las fórmulas solo se evalúa (resuelve) cuando se ejecuta la fórmula, y la fórmula no se ejecuta cuando se crea la columna, sino en un momento posterior.En ese punto posterior, ambas columnas se refieren a col viejo , que ahora se resuelve en la misma columna

 

Para solucionar esto, debe establecer el valor anterior de la columna en el momento en que crea la columna, así:

New Table( "Untitled 11",
 Add Rows( 4 ),
 New Column( "Column_1",
  Character,
  "Nominal",
  Set Values( {"A1000", "A2000", "A3000", "A4000"} )
 ),
 New Column( "Column_2",
  Character,
  "Nominal",
  Set Values( {"B5000", "B6000", "B7000", "B8000"} )
 )
);

OldColNames = { "Column_1", "Column_2" };

NewColNames = { "New_Column_1", "New_Column_2" };

nCols = N Items( OldColNames );

For( i = 1, i <= nCols, i++, 

 oldcol = OldColNames[i];
 newcol = NewColNames[i];

 Eval( Eval Expr(
 New Column( newcol,
  Character,
  "Nominal",
  Formula(
   As Constant( col = As Name( Expr( old col ) ) );
   If(
    "A10" <= Left( col, 3 ) <= "A19", "A-One",
    "A20" <= Left( col, 3 ) <= "A29", "A-Two",
    "A30" <= Left( col, 3 ) <= "A39", "A-Three",
    "A40" <= Left( col, 3 ) <= "A49", "A-Four",
    "B50" <= Left( col, 3 ) <= "B59", "B-Five",
    "B60" <= Left( col, 3 ) <= "B69", "B-Six",
    "B70" <= Left( col, 3 ) <= "B79", "B-Seven",
    "B80" <= Left( col, 3 ) <= "B89", "B-Eight",
   )
  )
 );
 ) );
);

Aquí estoy usando el Eval( Eval Expr( ... Expr( var ) ... ) ) construir para preevaluar parte del guión, y el como constante() evalúa solo para la primera fila y solo mantiene ese valor para todas las filas siguientes (puede acelerar las fórmulas al evitar el tiempo de búsqueda del nombre)

Re: Etiqueta de valor

¡Excelente!Muchas gracias.