218937_fr-FR

liliconcom

Comment mettre à jour plusieurs substitutions pour ajouter Ns au script GraphBuilder : Script inclus

Bonjour l'équipe,

Je voudrais modifier le script ci-dessous pour ajouter Ns au GraphBuilder via la substitution des espaces réservés "_text0_" à "_text5_".

Je sais comment implémenter une seule substitution pour l'espace réservé "_Yname_", mais je rencontre un blocage mental pour comprendre la substitution multiple.

De plus, je ne sais pas comment appeler une statistique de colonne pour générer dynamiquement les N pour chaque superposition sur les tracés (voir l'image ci-dessous)

 

Names Default to Here (1);

dt = Current Data Table ();

Clist = dt << Get Column Names (String);

For (i = 932, i<= 935, i++, 
  
  gb = Expr ( Graph Builder(
      Size( 789, 440 ),
      Variables(
       X( :Visit ),
       Y( column (i) ),
       Group X( :LEAD TAG ),
       Overlay( :SHORT TAG )
      ),
      Elements( Line( X, Y, Legend( 7 ), Error Bars( "Standard Error" ) ) ),
      SendToReport(
       Dispatch(
        {},
        _Yname_,
        ScaleBox,
        {Format( "Best", 12 ), Min( -1.8 ), Max( 1.0 ),
        Inc( 0.2 ), Minor Ticks( 1 ),
        Add Ref Line( 0, "Dotted", "Black", "", 2 )}
       ),
       Dispatch(
        {},
        "Graph Builder",
        FrameBox,
        {Add Graphics Script(
         2,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.6}, "_text0_" )
        ), Add Graphics Script(
         3,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.75}, "_text1_" )
        ), Grid Line Order( 5 ), Reference Line Order( 6 )}
       ),
       Dispatch(
        {},
        "Graph Builder",
        FrameBox( 2 ),
        {Left( 1 ), Right( 0 ), Top( 0 ), Bottom( 1 ),
        Add Graphics Script(
         2,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.75}, "_text3_" )
        ), Add Graphics Script(
         3,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.6}, "_text2_" )
        ), Grid Line Order( 5 ), Reference Line Order( 6 )}
       ),
       Dispatch(
        {},
        "Graph Builder",
        FrameBox( 3 ),
        {Left( 1 ), Right( 1 ), Top( 0 ), Bottom( 1 ),
        Add Graphics Script(
         2,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.6}, "_text4_" )
        ), Add Graphics Script(
         3,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.75}, "_text5_" )
        ), Grid Line Order( 5 ), Reference Line Order( 6 )}
       )
      )
     )
   ); 
  gbe = Eval (substitute(Name Expr (gb), Expr (_Yname_), Clist [i]));
  
  gbe << journal;
  gbe << close window;
);

Re : Comment mettre à jour plusieurs substitutions pour ajouter Ns au script GraphBuilder : Script inclus

Salut txnelson,

 

Merci beaucoup pour votre aide. Comme vous l'aviez prédit, le script était à 99%, j'ai juste dû ajouter quelques appels à la table principale (dt) comme indiqué ci-dessous.

 

For (i = 932, i<= 1115, i++, 
  
  try( close( dtSum, nosave ) );
  dtSum = <FONT color="#FF0000">dt</FONT> << Summary(invisible,
   Group( :LEAD TAG, :SHORT TAG ),
   N( as column( Clist[i] ) ),
   Freq( "None" ),
   Weight( "None" ),
   statistics column name format( "column" )
      
 );
  
    
  gb = Expr ( <FONT color="#FF0000">dt</FONT> << Graph Builder(
       Size( 789, 440 ),
       Variables(
        X( :Visit ),
        Y( column (i) ),
        Group X( :LEAD TAG ),
        Overlay( :SHORT TAG )
       ),
       Elements( Line( X, Y, Legend( 7 ), Error Bars( "Standard Error" ) ) ),
       SendToReport(
        Dispatch(
         {},
         _Yname_,
         ScaleBox,
         {Format( "Best", 12 ), Min( -1.8 ), Max( 1.0 ),
         Inc( 0.2 ), Minor Ticks( 1 ),
         Add Ref Line( 0, "Dotted", "Black", "", 2 )}
        ),
        Dispatch(
         {},
         "Graph Builder",
         FrameBox,
         {Add Graphics Script(
          2,
          Description( "Script" ),
          Text( Center Justified, {0.5, -1.6}, _text0_ )
         ), Add Graphics Script(
          3,
          Description( "Script" ),
          Text( Center Justified, {0.5, -1.75}, _text1_ )
         ), Grid Line Order( 5 ), Reference Line Order( 6 )}
        ),
        Dispatch(
         {},
         "Graph Builder",
         FrameBox( 2 ),
         {Left( 1 ), Right( 0 ), Top( 0 ), Bottom( 1 ),
         Add Graphics Script(
          2,
          Description( "Script" ),
          Text( Center Justified, {0.5, -1.75}, _text3_ )
         ), Add Graphics Script(
          3,
          Description( "Script" ),
          Text( Center Justified, {0.5, -1.6}, _text2_ )
         ), Grid Line Order( 5 ), Reference Line Order( 6 )}
        ),
        Dispatch(
         {},
         "Graph Builder",
         FrameBox( 3 ),
         {Left( 1 ), Right( 1 ), Top( 0 ), Bottom( 1 ),
         Add Graphics Script(
          2,
          Description( "Script" ),
          Text( Center Justified, {0.5, -1.6}, _text4_ )
         ), Add Graphics Script(
          3,
          Description( "Script" ),
          Text( Center Justified, {0.5, -1.75}, _text5_ )
         ), Grid Line Order( 5 ), Reference Line Order( 6 )}
        )
       )
      )
   ); 
  gbe = Eval (substitute(Name Expr (gb), Expr (_Yname_), Clist [i],
   Expr ( _text0_ ), char( column( dtSum, Clist[i] )[1] ),
   Expr ( _text1_ ), char( column( dtSum, Clist[i] )[2] ),
   Expr ( _text2_ ), char( column( dtSum, Clist[i] )[3] ),
   Expr ( _text3_ ), char( column( dtSum, Clist[i] )[4] ),
   Expr ( _text4_ ), char( column( dtSum, Clist[i] )[5] ),
   Expr ( _text5_ ), char( column( dtSum, Clist[i] )[6] )
  ));
  
  gbe << journal;
  gbe << close window;
    
);

Re : Comment mettre à jour plusieurs substitutions pour ajouter Ns au script GraphBuilder : Script inclus

Vous pouvez effectuer plusieurs substitutions avec un seul appel de la fonction Substitute().

gbe = Eval(
 Substitute( Name Expr( gb ),
  Expr( _Yname_ ), Clist[i],
  Expr( "_text0_"), "actual text",
...
 )
);

Re : Comment mettre à jour plusieurs substitutions pour ajouter Ns au script GraphBuilder : Script inclus

Voici une façon de procéder.Je ne peux pas garantir que le code fonctionnera du premier coup, car il s'agit d'un code non testé, car je n'ai pas d'exemple de table de données.Cependant, cela devrait être assez proche.

Names Default to Here (1);

dt = Current Data Table ();

Clist = dt << Get Column Names (String);

For (i = 932, i<= 935, i++, 

 try( close( dtsum, nosave ) );
 dtSum = << Summary(invisible,
  Group( :LEAD TAG, :SHORT TAG ),
  N( as column( Clist[i] ) ),
  Freq( "None" ),
  Weight( "None" ),
  statistics column name format( "column" ),
  Link to original data table( 0 )
 );
  
  gb = Expr ( dt << Graph Builder(
      Size( 789, 440 ),
      Variables(
       X( :Visit ),
       Y( column (i) ),
       Group X( :LEAD TAG ),
       Overlay( :SHORT TAG )
      ),
      Elements( Line( X, Y, Legend( 7 ), Error Bars( "Standard Error" ) ) ),
      SendToReport(
       Dispatch(
        {},
        _Yname_,
        ScaleBox,
        {Format( "Best", 12 ), Min( -1.8 ), Max( 1.0 ),
        Inc( 0.2 ), Minor Ticks( 1 ),
        Add Ref Line( 0, "Dotted", "Black", "", 2 )}
       ),
       Dispatch(
        {},
        "Graph Builder",
        FrameBox,
        {Add Graphics Script(
         2,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.6}, _text0_ )
        ), Add Graphics Script(
         3,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.75}, _text1_ )
        ), Grid Line Order( 5 ), Reference Line Order( 6 )}
       ),
       Dispatch(
        {},
        "Graph Builder",
        FrameBox( 2 ),
        {Left( 1 ), Right( 0 ), Top( 0 ), Bottom( 1 ),
        Add Graphics Script(
         2,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.75}, _text3_ )
        ), Add Graphics Script(
         3,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.6}, _text2_ )
        ), Grid Line Order( 5 ), Reference Line Order( 6 )}
       ),
       Dispatch(
        {},
        "Graph Builder",
        FrameBox( 3 ),
        {Left( 1 ), Right( 1 ), Top( 0 ), Bottom( 1 ),
        Add Graphics Script(
         2,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.6}, _text4_ )
        ), Add Graphics Script(
         3,
         Description( "Script" ),
         Text( Center Justified, {0.5, -1.75}, _text5_ )
        ), Grid Line Order( 5 ), Reference Line Order( 6 )}
       )
      )
     )
   ); 
  gbe = Eval (substitute(Name Expr (gb), Expr (_Yname_), Clist [i],
   Expr ( _text0_ ), char( column( dtSum, Clist[i] )[1] ),
   Expr ( _text1_ ), char( column( dtSum, Clist[i] )[2] ),
   Expr ( _text2_ ), char( column( dtSum, Clist[i] )[3] ),
   Expr ( _text3_ ), char( column( dtSum, Clist[i] )[4] ),
   Expr ( _text4_ ), char( column( dtSum, Clist[i] )[5] ),
   Expr ( _text5_ ), char( column( dtSum, Clist[i] )[6] )
  ));
  
  gbe << journal;
  gbe << close window;