561474_fr-FR

liliconcom

Étiquette de valeur

J'essaie de modifier les valeurs de plusieurs colonnes à l'aide d'une boucle For et d'une instruction If. Malheureusement, bien qu'il crée correctement les nouvelles colonnes, les valeurs de la deuxième colonne sont pour une raison quelconque également copiées dans la première colonne. Qu'est-ce qui me manque ?

New Table( "Untitled 11",
	Add Rows( 4 ),
	New Column( "Column_1",
		Character,
		"Nominal",
		Set Values( {"A1000", "A2000", "A3000", "A4000"} )
	),
	New Column( "Column_2",
		Character,
		"Nominal",
		Set Values( {"B5000", "B6000", "B7000", "B8000"} )
	)
);

OldColNames = { "Column_1", "Column_2" };

NewColNames = { "New_Column_1", "New_Column_2" };

nCols = N Items( OldColNames );

For( i = 1, i <= nCols, i++, 

	oldcol = OldColNames[i];
	newcol = NewColNames[i];

	New Column( newcol,
		Character,
		"Nominal",
		Formula(
			If(
				"A10" <= Left( As Column( oldcol ), 3 ) <= "A19", "A-One",
				"A20" <= Left( As Column( oldcol ), 3 ) <= "A29", "A-Two",
				"A30" <= Left( As Column( oldcol ), 3 ) <= "A39", "A-Three",
				"A40" <= Left( As Column( oldcol ), 3 ) <= "A49", "A-Four",
				"B50" <= Left( As Column( oldcol ), 3 ) <= "B59", "B-Five",
				"B60" <= Left( As Column( oldcol ), 3 ) <= "B69", "B-Six",
				"B70" <= Left( As Column( oldcol ), 3 ) <= "B79", "B-Seven",
				"B80" <= Left( As Column( oldcol ), 3 ) <= "B89", "B-Eight",
			)
		)
	);
);

Merci!

Modélisation statistique avancéeÉtudes de marché et de consommationAccès aux donnéesFusion et nettoyage des donnéesIngénierie de la qualité et des procédésRe : Étiquette de valeur

C'est parce que le nom ancien col à l'intérieur des formules n'est évalué (résolu) que lorsque la formule est exécutée, et la formule ne s'exécute pas lorsque la colonne est créée mais ultérieurement.À ce stade ultérieur, les deux colonnes font référence à ancien col , qui se résout maintenant dans la même colonne

 

Pour résoudre ce problème, vous devez définir l'ancienne valeur col au moment de la création de la colonne, comme ceci :

New Table( "Untitled 11",
 Add Rows( 4 ),
 New Column( "Column_1",
  Character,
  "Nominal",
  Set Values( {"A1000", "A2000", "A3000", "A4000"} )
 ),
 New Column( "Column_2",
  Character,
  "Nominal",
  Set Values( {"B5000", "B6000", "B7000", "B8000"} )
 )
);

OldColNames = { "Column_1", "Column_2" };

NewColNames = { "New_Column_1", "New_Column_2" };

nCols = N Items( OldColNames );

For( i = 1, i <= nCols, i++, 

 oldcol = OldColNames[i];
 newcol = NewColNames[i];

 Eval( Eval Expr(
 New Column( newcol,
  Character,
  "Nominal",
  Formula(
   As Constant( col = As Name( Expr( old col ) ) );
   If(
    "A10" <= Left( col, 3 ) <= "A19", "A-One",
    "A20" <= Left( col, 3 ) <= "A29", "A-Two",
    "A30" <= Left( col, 3 ) <= "A39", "A-Three",
    "A40" <= Left( col, 3 ) <= "A49", "A-Four",
    "B50" <= Left( col, 3 ) <= "B59", "B-Five",
    "B60" <= Left( col, 3 ) <= "B69", "B-Six",
    "B70" <= Left( col, 3 ) <= "B79", "B-Seven",
    "B80" <= Left( col, 3 ) <= "B89", "B-Eight",
   )
  )
 );
 ) );
);

Ici, j'utilise le Eval( Eval Expr( ... Expr( var ) ... ) ) construire pour pré-évaluer une partie du script, et la Comme constante() évalue uniquement pour la première ligne et conserve cette valeur pour toutes les lignes suivantes (cela peut accélérer les formules en empêchant le temps de recherche du nom)

Re : Étiquette de valeur

Excellent!Merci beaucoup.