285869_fr-FR

liliconcom

Graph Builder - Boîte à moustaches avec groupes de colonnes ?

J'ai un petit jeu de données avec plusieurs colonnes.

Certaines de ces colonnes sont groupées. Dans le générateur de graphiques, puis-je créer un diagramme à boîte unique avec des données par groupe, au lieu de colonnes individuelles ?

 

 

Tableau de donnéesGraphiqueRe: Graph Builder - Box plot avec groupes de colonnes ?

La façon de le faire est de simplement

1. Empilez les colonnes
2. Créer une nouvelle colonne qui regroupe les données
3. Exécutez le générateur de graphiques avec la colonne de regroupement comme axe X

Vous trouverez ci-dessous un exemple utilisant JSL, mais chaque étape du script peut être facilement effectuée de manière interactive.Voir le script ci-dessous

names default to here(1);

// Create a sample data table for illustration
dt=new table("TO_CPTO_C",
 add rows(5),
 new column("A.1", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("A.2", formula(randomuniform(70,140)),format("fixed dec",6,2)), 
 new column("A.3", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("A.4", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("A.5", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("A.6", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("B.1", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("B.2", formula(randomuniform(70,140)),format("fixed dec",6,2)), 
 new column("B.3", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("B.4", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("C.1", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("C.2", formula(randomuniform(70,140)),format("fixed dec",6,2)), 
 new column("C.3", formula(randomuniform(70,140)),format("fixed dec",6,2)),
 new column("C.4", formula(randomuniform(70,140)),format("fixed dec",6,2))
);

// Pause so one can see initial data table before moving on
Wait( 5 );

// Stack the columns
// Tables==>Stack
dtStack = dt << Stack(
 columns(
  :A.1,
  :A.2,
  :A.3,
  :A.4,
  :A.5,
  :A.6,
  :B.1,
  :B.2,
  :B.3,
  :B.4,
  :C.1,
  :C.2,
  :C.3,
  :C.4
 ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" )
);

// Pause so one can see stacked data table before moving on
Wait( 5 );

// Create a grouping column
dtStack << New Column("Group", character, formula( left(:Label,1 )));

// Pause so one can see new column before moving on
Wait( 5 );

// Create the Graph, using the Group column as the X axis and Data as the Y axis
dtStack << Graph Builder(
 Size( 534, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :Group ), Y( :Data ) ),
 Elements( Box Plot( X, Y, Legend( 3 ) ) )
);

 

Re: Graph Builder - Box plot avec groupes de colonnes ?

J'interprète peut-être mal votre question, et à l'avenir, si vous joignez la table de données JMP, il sera peut-être plus facile de vous montrer, mais je vous pouvez empiler les colonnes A, B et C afin que vous ayez maintenant trois colonnes de données avec A, B et étiquettes C.