559110_es-ES

liliconcom

Responder a todos: notación científica como 6,02 × 10²³ usando formatos de eje personalizados

A artículo reciente de la lista de deseos pidió un formato de número que era una versión de la notación científica usando exponenciación de superíndice en lugar de los separadores computarizados "e" para potencias de 10. En otras palabras, 3,4 × 10⁵ en lugar de 3,4e+5. Dado que los dígitos en superíndice están disponibles como caracteres Unicode, es posible escribir dichos números como texto normal, sin necesidad de un superíndice explícito. Y eso significa que podemos obtener esos números en un eje con un formato de etiqueta personalizado.

Los ejes de gráficos han admitido durante mucho tiempo formatos de etiquetas personalizados, que son expresiones JSL que pueden producir etiquetas de eje arbitrarias. Aquí hay un ejemplo que agrega "°F" a las etiquetas del eje y.

Lo hice seleccionando Personalizado como Formato en el cuadro de diálogo Configuración del eje.

Y luego haga clic en "Formato personalizado" para abrir una versión del Editor de fórmulas para crear esta fórmula simple.

La fórmula para científico es más complicada pero aún encaja dentro del marco. Creé esta fórmula, que comienza con la notación científica regular de JMP y luego reemplaza los dígitos del exponente con los caracteres en superíndice correspondientes.

Local( {supers = "⁰¹²³⁴⁵⁶⁷⁸⁹", d, parts},
 parts = Words( Format( value, "Scientific", width, dec ), "e" ); // split on e
 Substitute Into( parts[2], "+", "", "-", "⁻" ); // ignore +, superscript -
 For( d = 0, d <= 9, d++, // superscript each digit
  Substitute Into( parts[2], Char( d ), Substr( supers, d + 1, 1 ))
 );
 if (value == 0, "0", parts[1] || " × 10" || parts[2]); // add x10 unless 0
)

Aquí hay un gráfico usando ese formato.

 

Finalmente, aquí está la secuencia de comandos completa para el gráfico, con el formato personalizado como parte de las personalizaciones del eje y el filtro de datos para mostrar solo los estados principales.

Open( "$SAMPLE_DATA/Corn Wheat Soybean Production.jmp" );
Graph Builder(
 Transform Column(
  "Maximum[Commodity Acres Planted][State,Commodity]",
  Formula( Col Maximum( :Commodity Acres Planted, :State, :Commodity ) )
 ),
 Size( 658, 487 ),
 Show Control Panel( 0 ),
 Variables(
  X( :Year ),
  Y( :Commodity Acres Planted ),
  Group X( :Commodity ),
  Overlay( :State )
 ),
 Elements( Points( X, Y, Legend( 35 ) ), Smoother( X, Y, Legend( 36 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :"Maximum[Commodity Acres Planted][State,Commodity]"n ),
   Where(
    :"Maximum[Commodity Acres Planted][State,Commodity]"n >= 4658000
   )
  )
 ),
 SendToReport(
  Dispatch( {}, "Year", ScaleBox,
   {Min( 1999.5 ), Max( 2017.5 ), Inc( 10 ), Minor Ticks( 1 )}
  ),
  Dispatch( {}, "Commodity Acres Planted", ScaleBox,
  {Format( "Custom",
   Formula(
    Local( {supers = "⁰¹²³⁴⁵⁶⁷⁸⁹", d, parts},
     parts = Words( Format( value, "Scientific", width, dec ), "e" );
     Substitute Into( parts[2], "+", "", "-", "⁻" );
     For( d = 0, d <= 9, d++,
      Substitute Into( parts[2], Char( d ), Substr( supers, d + 1, 1 ))
     );
     if (value == 0, "0", parts[1] || " × 10" || parts[2]);
    )
   )
  ), Min( 0 ), Max( 15.5e6 ), Inc( 5e6 ), Minor Ticks( 4 )}
 ))
);

 

Cómo usar el formato de etiqueta personalizada del eje para obtener notación científica en superíndice (¡y más!)

 

Re: Responder a todos: Notación científica como 6,02×10²³ usando formatos de eje personalizados

Estimado,

Gracias por las explicaciones.

Con la ayuda del foro, obtuve esta presentación para mi gráfico Anova.

Usé esta fórmula:

Pero como ha demostrado, me gustaría eliminar "^" y tener el último número en el exponente. Pero no entiendo, como soy un principiante de JMP, cómo implementar su superíndice. ¿Me lo podrías explicar paso a paso?

gracias de antemano

Saludos cordiales