UN article récent de la liste de souhaits a demandé un format numérique qui était une version de la notation scientifique utilisant l'exponentiation en exposant au lieu des séparateurs informatiques "e" pour les puissances de 10. Autrement dit, 3,4 × 10⁵ au lieu de 3,4e+5. Étant donné que les chiffres en exposant sont disponibles sous forme de caractères Unicode, il est possible d'écrire ces nombres sous forme de texte normal, sans avoir besoin d'un exposant explicite. Et cela signifie que nous pouvons obtenir de tels nombres sur un axe avec un format d'étiquette personnalisé.
Les axes de graphique prennent en charge depuis longtemps les formats d'étiquettes personnalisés, qui sont des expressions JSL pouvant produire des étiquettes d'axe arbitraires. Voici un exemple qui ajoute "°F" aux étiquettes de l'axe y.
Je l'ai créé en sélectionnant Personnalisé comme format dans la boîte de dialogue Paramètres de l'axe.
Et puis en cliquant sur "Format personnalisé" pour afficher une version de l'éditeur de formule pour créer cette formule simple.
La formule pour scientifique est plus compliquée mais s'inscrit toujours dans le cadre. J'ai créé cette formule, qui commence par la notation scientifique habituelle de JMP, puis remplace les chiffres de l'exposant par les caractères en exposant correspondants.
Local( {supers = "⁰¹²³⁴⁵⁶⁷⁸⁹", d, parts},
parts = Words( Format( value, "Scientific", width, dec ), "e" ); // split on e
Substitute Into( parts[2], "+", "", "-", "⁻" ); // ignore +, superscript -
For( d = 0, d <= 9, d++, // superscript each digit
Substitute Into( parts[2], Char( d ), Substr( supers, d + 1, 1 ))
);
if (value == 0, "0", parts[1] || " × 10" || parts[2]); // add x10 unless 0
)
Voici un graphique utilisant ce format.
Enfin, voici le script complet du graphique, avec le format personnalisé dans le cadre des personnalisations d'axe et du filtre de données pour afficher uniquement les états supérieurs.
Open( "$SAMPLE_DATA/Corn Wheat Soybean Production.jmp" );
Graph Builder(
Transform Column(
"Maximum[Commodity Acres Planted][State,Commodity]",
Formula( Col Maximum( :Commodity Acres Planted, :State, :Commodity ) )
),
Size( 658, 487 ),
Show Control Panel( 0 ),
Variables(
X( :Year ),
Y( :Commodity Acres Planted ),
Group X( :Commodity ),
Overlay( :State )
),
Elements( Points( X, Y, Legend( 35 ) ), Smoother( X, Y, Legend( 36 ) ) ),
Local Data Filter(
Add Filter(
columns( :"Maximum[Commodity Acres Planted][State,Commodity]"n ),
Where(
:"Maximum[Commodity Acres Planted][State,Commodity]"n >= 4658000
)
)
),
SendToReport(
Dispatch( {}, "Year", ScaleBox,
{Min( 1999.5 ), Max( 2017.5 ), Inc( 10 ), Minor Ticks( 1 )}
),
Dispatch( {}, "Commodity Acres Planted", ScaleBox,
{Format( "Custom",
Formula(
Local( {supers = "⁰¹²³⁴⁵⁶⁷⁸⁹", d, parts},
parts = Words( Format( value, "Scientific", width, dec ), "e" );
Substitute Into( parts[2], "+", "", "-", "⁻" );
For( d = 0, d <= 9, d++,
Substitute Into( parts[2], Char( d ), Substr( supers, d + 1, 1 ))
);
if (value == 0, "0", parts[1] || " × 10" || parts[2]);
)
)
), Min( 0 ), Max( 15.5e6 ), Inc( 5e6 ), Minor Ticks( 4 )}
))
);
Cher,
Merci pour les explications.
Avec l'aide du forum, j'ai obtenu cette présentation de mon graphique Anova.
J'ai utilisé cette formule : 
Mais comme vous l'avez montré, j'aimerais supprimer le "^" et avoir le dernier chiffre dans l'exposant. Mais je ne comprends pas, comme je suis un débutant JMP, comment implémenter votre exposant. Pourriez-vous m'expliquer étape par étape ?
Merci d'avance
Meilleurs remerciements
