559110_zh-TW

liliconcom

回復全部：使用自定義軸格式的科學記數法，例如 6.02×10²³

A最近的願望清單項目要求一種數字格式，它是一種使用上標求冪而不是 10 的冪的計算機“e”分隔符的科學記數法。 換句話說，3.4 × 10⁵ 而不是 3.4e+5。 由於上標數字可用作 Unicode 字符，因此可以將此類數字編寫為常規文本，而無需顯式上標。 這意味著我們可以在具有自定義標籤格式的軸上獲得此類數字。

圖形軸長期以來一直支持自定義標籤格式，這些格式是可以生成任意軸標籤的 JSL 表達式。 下面是一個將“°F”添加到 y 軸標籤的示例。

我通過在軸設置對話框中選擇自定義作為格式來實現的。

然後單擊“自定義格式”以調出公式編輯器的一個版本來創建這個簡單的公式。

科學的公式更複雜，但仍然符合框架。 我創建了這個公式，它以 JMP 的常規科學記數法開頭，然後用相應的上標字符替換指數的數字。

Local( {supers = "⁰¹²³⁴⁵⁶⁷⁸⁹", d, parts},
 parts = Words( Format( value, "Scientific", width, dec ), "e" ); // split on e
 Substitute Into( parts[2], "+", "", "-", "⁻" ); // ignore +, superscript -
 For( d = 0, d <= 9, d++, // superscript each digit
  Substitute Into( parts[2], Char( d ), Substr( supers, d + 1, 1 ))
 );
 if (value == 0, "0", parts[1] || " × 10" || parts[2]); // add x10 unless 0
)

這是使用該格式的圖表。

 

最後，這是圖表的完整腳本，自定義格式作為軸自定義和數據過濾器的一部分，僅顯示頂部狀態。

Open( "$SAMPLE_DATA/Corn Wheat Soybean Production.jmp" );
Graph Builder(
 Transform Column(
  "Maximum[Commodity Acres Planted][State,Commodity]",
  Formula( Col Maximum( :Commodity Acres Planted, :State, :Commodity ) )
 ),
 Size( 658, 487 ),
 Show Control Panel( 0 ),
 Variables(
  X( :Year ),
  Y( :Commodity Acres Planted ),
  Group X( :Commodity ),
  Overlay( :State )
 ),
 Elements( Points( X, Y, Legend( 35 ) ), Smoother( X, Y, Legend( 36 ) ) ),
 Local Data Filter(
  Add Filter(
   columns( :"Maximum[Commodity Acres Planted][State,Commodity]"n ),
   Where(
    :"Maximum[Commodity Acres Planted][State,Commodity]"n >= 4658000
   )
  )
 ),
 SendToReport(
  Dispatch( {}, "Year", ScaleBox,
   {Min( 1999.5 ), Max( 2017.5 ), Inc( 10 ), Minor Ticks( 1 )}
  ),
  Dispatch( {}, "Commodity Acres Planted", ScaleBox,
  {Format( "Custom",
   Formula(
    Local( {supers = "⁰¹²³⁴⁵⁶⁷⁸⁹", d, parts},
     parts = Words( Format( value, "Scientific", width, dec ), "e" );
     Substitute Into( parts[2], "+", "", "-", "⁻" );
     For( d = 0, d <= 9, d++,
      Substitute Into( parts[2], Char( d ), Substr( supers, d + 1, 1 ))
     );
     if (value == 0, "0", parts[1] || " × 10" || parts[2]);
    )
   )
  ), Min( 0 ), Max( 15.5e6 ), Inc( 5e6 ), Minor Ticks( 4 )}
 ))
);

 

如何使用軸自定義標籤格式來獲取帶上標的科學記數法（以及更多！）

 

回覆：回覆全部：科學記數法，例如使用自訂軸格式的 6.02×10²³

親愛的，

謝謝你的解釋。

在論壇的幫助下，我獲得了 Anova 圖形的簡報。

我用了這個公式：

但正如您所示，我想刪除“^”並在指數中保留最後一個數字。但我不明白，因為我是一個JMP初學者，如何實現你的上標。你能一步步向我解釋嗎？

先致謝

最好的祝福