543793_es-ES

liliconcom

¿Cómo denotar letras para marcar diferencias significativas en un diagrama de caja?

¡Hola! Tengo JMP Pro 14. Estoy creando varios diagramas de caja donde quiero mostrar las diferencias significativas entre categorías con letras arriba del Q3 como en este gráfico:

¿Cómo puedo poner las letras a y b encima de los recuadros? Mi trama es esta:

 

El código de Mi Graph Builder es:

Graph Builder(
 Size( 571, 448 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Show Title( 0 ),
 Show Footer( 0 ),
 Variables( X( :Cat ), Y( :Name( "Pl/min" ) ) ),
 Elements( Box Plot( X, Y, Legend( 6 ), Box Style( "Solid" ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Cat",
   ScaleBox,
   {Reversed Scale, Label Row(
    {Set Font Size( 12 ), Tick Mark( Label( "6" ), Label( "6 " ) ),
    Tick Mark( Label( "7" ), Label( "7 " ) )}
   )}
  ),
  Dispatch(
   {},
   "Pl/min",
   ScaleBox,
   {Min( 5.5 ), Max( 18 ), Inc( 2 ), Minor Ticks( 1 )}
  ),
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    6,
    Properties(
     0,
     {Line Color( 32 ), Fill Color( 0 )},
     Item ID( "Pl/min", 1 )
    )
   )}
  ),
  Dispatch( {}, "X title", TextEditBox, {Set Font Size( 12 )} ),
  Dispatch( {}, "Y title", TextEditBox, {Set Font Size( 12 )} ),
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   {DispatchSeg(
    Box Plot Seg( "Box Plot (4)" ),
    {Line Color( {128, 128, 128} ), Fill Color( "Medium Dark Red" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (5)" ),
    {Line Color( {128, 128, 128} ), Fill Color( "Medium Dark Yellow" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (6)" ),
    {Line Color( "Medium Dark Yellow" ),
    Fill Color( "Medium Dark Green" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (7)" ),
    {Line Color( "Medium Dark Yellow" ),
    Fill Color( "Medium Dark BlueCyan" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (8)" ),
    {Line Color( "Medium Dark Yellow" ),
    Fill Color( "Medium Dark Magenta" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (9)" ),
    {Line Color( "Medium Dark Purple" ),
    Fill Color( "Medium Dark Fuchsia" )}
   )}
  )
 )
);

Gracias de antemano.

Magali.

AnalíticaGráficosventanasRe: ¿Cómo denotar letras para marcar diferencias significativas en un diagrama de caja?

Creo que tendrías que:

1. Calcule esas letras (basado en mi búsqueda en Google de 5 segundos, esas letras son de la prueba de Tukey, así que solo usé un Informe de letras de conexión)
2. Cree una nueva columna que asignará esas letras a las filas correctas
3. Usa esa columna como marcador
4. Agregar puntos al generador de gráficos
5. Use una estadística de resumen adecuada para el gráfico de puntos para mostrarlos en una buena ubicación (puede requerir una nueva columna para crear algún desplazamiento)
6. Los marcadores deben mostrarse en el gráfico.

Lo más probable es que también pueda combinar los pasos 2 a 6 en un guión gráfico

 

Aquí hay un ejemplo bastante simple con Big Class usando la opción de script no gráfico:

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

fit = dt << Oneway(Y(:height), X(:age), All Pairs(1), invisible);
letters_tb = ((Report(fit)[OutlineBox("Connecting Letters Report")]) << child) << child;

tb_letter_cols = Filter Each({col_name}, letters_tb << Get Names,
 Starts With(col_name, "~Letter Column ")
);

aa_letters = Associative Array();
For Each({level, idx}, letters_tb[1] << get,
 aa_letters[level] = "";
 For Each({letter_col, idx_col}, tb_letter_cols,
  aa_letters[level] ||= letters_tb[1 + idx_col][idx];
 );
);
fit << close window;

dt << New Column("TukeyLetters", Character, Nominal, UseForMarker(1), << Set Each Value(
 aa_letters[char(:age)];
));

gb = dt << Graph Builder(
 Size(529, 451),
 Show Control Panel(0),
 Variables(X(:age), Y(:height)),
 Elements(
  Box Plot(X, Y, Legend(6), Box Style("Solid"), Fences(0)),
  Points(
   X,
   Y,
   Legend(7),
   Summary Statistic("Third Quartile"),
   Error Interval("None")
  )
 )
);

 

Editar:

Elemento de lista de deseos creado para esto Muestra letras de importancia en el generador de gráficos cuando se usa el diagrama de caja y ajusta y por x cuando se realiza la comparación