549497_es-ES

liliconcom

La mejor manera de trazar el gráfico de GraphBuilder con múltiples variables Y usando JSL

Todo,

 

Me gustaría solicitar información sobre la mejor manera de escribir un gráfico de GB con múltiples parámetros.

Digamos que tengo una tabla como esta:

New Table( "Untitled 140",
 Add Rows( 12 ),
 New Column( "Category",
  Character,
  "Nominal",
  Set Values( {"A", "A", "A", "B", "B", "B", "C", "C", "C", "D", "D", "D"} )
 ),
 New Column( "Value1",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [1, 4, 2, 3, 6, 2, 3, 5, 4, 1, 3, 6] )
 ),
 New Column( "Value2",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [6, 3, 5, 2, 8, 6, 5, 2, 6, 3, 5, 4] )
 )
)

Y quiero escribir una trama como esta:

donde el script generado automáticamente se ve así:

;Graph Builder(
 Size( 522, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :Category ), Y( :Value1 ), Y( :Value2, Position( 1 ) ) ),
 Elements( Bar( X, Y( 1 ), Y( 2 ), Legend( 4 ), Summary Statistic( "Range" ) ) )
)

con el problema de que hay un número arbitrario de columnas Y y los nombres también son arbitrarios.

Para gráficos como el gráfico de variabilidad, haría algo como esto:

parameters = {:"Value1"n, :"Value2"n};
yExpr = Expr( Y() );
For Each( {value, index}, parameters, Insert Into( yExpr, Name Expr( value ), 1 ) );

Eval(
 Substitute(
   Expr(
    Variability Chart( placeholder, X( :Category ),  Std Dev Chart( 0 )  )
   ),
  Expr( placeholder ), Name Expr( yExpr )
 )
);

donde recibo los nombres de las columnas como una lista y luego construyo una expresión Y y luego la coloco en el script para el gráfico. Me daría una lista de diagramas de variabilidad, pero me parece bien.

 

 

Si quiero tomar la misma ruta en el caso del GB, parece que tendré que construir dos expresiones:

Y( :Value1 ), Y( :Value2, Position( 1 ) )

y

Elements( Bar( X, Y( 1 ), Y( 2 ), Legend( 4 ), Summary Statistic( "Range" ) ) )

Que es esencialmente todo el guión.

Mi pregunta: ¿hay una mejor manera en lugar de hacer un montón de sustituciones con expresiones para ensamblar esas dos líneas?

 

¡Gracias!

 

 

Investigación del Consumidor y del MercadoRe: La mejor manera de trazar el gráfico de GraphBuilder con múltiples variables Y usando JSL

¡Lindo!Gracias por agregar ese toque.¡Ojalá lo hubiera intentado yo mismo!

Re: La mejor manera de trazar el gráfico de GraphBuilder con múltiples variables Y usando JSL

@pmroz aquí está el mismo código sin Eval(Parse()).¡Estoy de acuerdo en que esto es mucho más limpio!

 

Names default to here(1);

dt = New Table( "Test",
 Add Rows( 12 ),
 New Column( "Category", Character, "Nominal",
  Set Values( {"A", "A", "A", "B", "B", "B", "C", "C", "C", "D", "D", "D"} ) ),
 New Column( "Value1", Numeric, "Continuous", Format( "Best", 12 ),
  Set Values( [1, 4, 2, 3, 6, 2, 3, 5, 4, 1, 3, 6] ) ),
 New Column( "Value2", Numeric, "Continuous", Format( "Best", 12 ),
  Set Values( [6, 3, 5, 2, 8, 6, 5, 2, 6, 3, 5, 4] ) ),
 New Column( "Value3", Numeric, "Continuous", Format( "Best", 12 ),
  Set Values( [1, 4, 3, 6, 5, 7, 3, 4, 2, 8, 6, 1] ) )
);

dt_cols = dt << get column references();
remove from(dt_cols, 1); // Remove Category

dts = dt << Stack(invisible,
 columns( dt_cols ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" )
);
 
dts << Graph Builder(
 Size( 518, 448 ),
 Show Control Panel( 0 ),
 Variables( X( :Category ), Y( :Data ), Overlay( :Label ) ),
 Elements( Bar( X, Y, Legend( 7 ) ) )
);

 

Re: La mejor manera de trazar el gráfico de GraphBuilder con múltiples variables Y usando JSL

no olvides el PILA dominio.Requiere eval(parse()) pero de lo contrario es bastante limpio.Aquí hay un ejemplo con tres columnas para trazar.

dt = New Table( "Test",
 Add Rows( 12 ),
 New Column( "Category",
  Character,
  "Nominal",
  Set Values( {"A", "A", "A", "B", "B", "B", "C", "C", "C", "D", "D", "D"} )
 ),
 New Column( "Value1",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [1, 4, 2, 3, 6, 2, 3, 5, 4, 1, 3, 6] )
 ),
 New Column( "Value2",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [6, 3, 5, 2, 8, 6, 5, 2, 6, 3, 5, 4] )
 ),

 New Column( "Value3",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [1, 4, 3, 6, 5, 7, 3, 4, 2, 8, 6, 1] )
 )
);

dt_cols = dt << get column names(string);
removefrom(dt_cols, 1); // Remove Category

// Create the list of columns, like this: ":Value1, :Value2, :Value3"
col_list = ":" || concat items(dt_cols, ", :");

stack_str = evalinsert(
"\[dts = dt << Stack(invisible,
 columns( ^col_list^ ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" ))]\");
eval(parse(stack_str));

dts << Graph Builder(
 Size( 518, 448 ),
 Show Control Panel( 0 ),
 Variables( X( :Category ), Y( :Data ), Overlay( :Label ) ),
 Elements( Bar( X, Y, Legend( 7 ) ) )
);

 

 

Re: La mejor manera de trazar el gráfico de GraphBuilder con múltiples variables Y usando JSL

Esto todavía usa bucles para construir esas expresiones, pero concatena listas de argumentos en lugar de sustituirlos:

 

Names default to here(1);

//call another function (f) with the arguments provided in a list (l)
do.call = function({l,f}, 
 Substitute(
  Name Expr(l),
  Expr({}),
  Name Expr(f)
 );
);

dt = New Table( "Data",
 Add Rows( 12 ),
 New Column( "Category", Character, "Nominal",
  Set Values( {"A", "A", "A", "B", "B", "B", "C", "C", "C", "D", "D", "D"} )
 ),
 New Column( "Value1", Numeric, "Continuous", Format( "Best", 12 ),
  Set Values( [1, 4, 2, 3, 6, 2, 3, 5, 4, 1, 3, 6] )
 ),
 New Column( "Value2", Numeric, "Continuous", Format( "Best", 12 ),
  Set Values( [6, 3, 5, 2, 8, 6, 5, 2, 6, 3, 5, 4] )
 )
);

vars = {:Value1, :Value2};

VarExpr = do.call(
 { X( :Category ) } || transform each({v}, vars, eval expr( Y( Expr( Name Expr( v ) ), Position( 1 ) ) ) ),
 expr(Variables())
);

BarExpr = do.call(
 { X } || transform each({v, i}, vars, eval expr( Y( Expr( i ) ) ) ) || { Legend( 4 ), Summary Statistic( "Range" ) },
 expr(Bar())
);

Eval( Eval Expr(
 dt << Graph Builder(
  Size( 522, 450 ),
  Show Control Panel( 0 ),
  Expr( Name Expr( VarExpr ) ),
  Elements( Expr( Name Expr( BarExpr ) ) )
 )
) );

Re: La mejor manera de trazar el gráfico de GraphBuilder con múltiples variables Y usando JSL

Por lo general, he usado métodos similares a los suyos para construir tales constructores de gráficos, esta podría ser una buena lectura Re: ¿Puedes construir esto sin escribir expresión en una cadena?

Re: La mejor manera de trazar el gráfico de GraphBuilder con múltiples variables Y usando JSL

Ok, así es como lo resolví, pero ¿hay una manera más simple? No puedo creer que para escribir algo tan simple tenga que entrar en ese tipo de complejidad...:

 

parameters = {:"Value1"n, :"Value2"n};

yExpr = Expr( Y() );
yExprPos = Expr( Y( Position( 1 ) ) );
barExpr = Expr(
 Bar( X, Summary Statistic( "Range" ) )
);
yNExpr = Expr( Y() );
variablesExpr = Expr(
 Variables( X( :Category ) )
);

For Each( {value, index}, parameters,
 Insert Into( yExpr, Name Expr( value ), 1 );
 yExprPos = Expr( Y( Position( 1 ) ) );
 Insert Into( yExprPos, Name Expr( value ), 1 );
 Insert Into( variablesExpr, Name Expr( yExprPos ) );
 //This is for Y(1) etc. in Bar()
 yNExpr = Expr( Y() );
 Insert Into( yNExpr, Name Expr( index ) );
 
 Insert Into( barExpr, Name Expr( yNExpr ), 2 );
);


//Name Expr( yExpr );
Show(Name Expr( variablesExpr ));
Show(Name Expr( barExpr ));

gbExpr = Expr(
 Graph Builder( Size( 522, 450 ), Show Control Panel( 0 ), placeholder1, Elements( placeholder2 ) )
 
);

Eval( 
 Substitute( 
  Substitute( 
   Name Expr(gbExpr),    
   Expr( placeholder1 ), 
   Name Expr( variablesExpr )
  ), 
  Expr( placeholder2 ), 
  Name Expr( barExpr ) 
 ) 
);