549497_fr-FR

liliconcom

Meilleure façon de tracer un tracé GraphBuilder avec plusieurs variables Y à l'aide de JSL

Tous,

 

J'aimerais demander une entrée sur la meilleure façon de scripter un tracé GB avec plusieurs paramètres.

Disons que j'ai un tableau comme celui-ci:

New Table( "Untitled 140",
 Add Rows( 12 ),
 New Column( "Category",
  Character,
  "Nominal",
  Set Values( {"A", "A", "A", "B", "B", "B", "C", "C", "C", "D", "D", "D"} )
 ),
 New Column( "Value1",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [1, 4, 2, 3, 6, 2, 3, 5, 4, 1, 3, 6] )
 ),
 New Column( "Value2",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [6, 3, 5, 2, 8, 6, 5, 2, 6, 3, 5, 4] )
 )
)

Et je veux scénariser une intrigue comme celle-ci:

où le script généré automatiquement ressemble à ceci :

;Graph Builder(
 Size( 522, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :Category ), Y( :Value1 ), Y( :Value2, Position( 1 ) ) ),
 Elements( Bar( X, Y( 1 ), Y( 2 ), Legend( 4 ), Summary Statistic( "Range" ) ) )
)

avec le hic qu'il y a un nombre arbitraire de colonnes Y et que les noms sont également arbitraires.

Pour des parcelles comme la parcelle de variabilité, je voudrais quelque chose comme ceci:

parameters = {:"Value1"n, :"Value2"n};
yExpr = Expr( Y() );
For Each( {value, index}, parameters, Insert Into( yExpr, Name Expr( value ), 1 ) );

Eval(
 Substitute(
   Expr(
    Variability Chart( placeholder, X( :Category ),  Std Dev Chart( 0 )  )
   ),
  Expr( placeholder ), Name Expr( yExpr )
 )
);

où je reçois les noms des colonnes sous forme de liste, puis je construis une expression Y, puis je la place dans le script du graphique. Cela me donnerait une liste de parcelles de variabilité, mais ça me va.

 

 

Si je veux emprunter le même chemin dans le cas du GB, il semble que je devrai construire deux expressions :

Y( :Value1 ), Y( :Value2, Position( 1 ) )

et

Elements( Bar( X, Y( 1 ), Y( 2 ), Legend( 4 ), Summary Statistic( "Range" ) ) )

Ce qui est essentiellement tout le script.

Ma question : Existe-t-il un meilleur moyen plutôt que de faire des tas de substitutions avec des expressions pour assembler ces deux lignes ?

 

Merci!

 

 

Études de consommation et de marchéRe : Meilleur moyen de tracer un tracé GraphBuilder avec plusieurs variables Y à l'aide de JSL

Bon!Merci d'avoir ajouté cette touche.J'aurais aimé essayer ça moi-même !

Re : Meilleur moyen de tracer un tracé GraphBuilder avec plusieurs variables Y à l'aide de JSL

@pmroz voici le même code sans Eval(Parse()).Je suis d'accord c'est beaucoup plus propre !

 

Names default to here(1);

dt = New Table( "Test",
 Add Rows( 12 ),
 New Column( "Category", Character, "Nominal",
  Set Values( {"A", "A", "A", "B", "B", "B", "C", "C", "C", "D", "D", "D"} ) ),
 New Column( "Value1", Numeric, "Continuous", Format( "Best", 12 ),
  Set Values( [1, 4, 2, 3, 6, 2, 3, 5, 4, 1, 3, 6] ) ),
 New Column( "Value2", Numeric, "Continuous", Format( "Best", 12 ),
  Set Values( [6, 3, 5, 2, 8, 6, 5, 2, 6, 3, 5, 4] ) ),
 New Column( "Value3", Numeric, "Continuous", Format( "Best", 12 ),
  Set Values( [1, 4, 3, 6, 5, 7, 3, 4, 2, 8, 6, 1] ) )
);

dt_cols = dt << get column references();
remove from(dt_cols, 1); // Remove Category

dts = dt << Stack(invisible,
 columns( dt_cols ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" )
);
 
dts << Graph Builder(
 Size( 518, 448 ),
 Show Control Panel( 0 ),
 Variables( X( :Category ), Y( :Data ), Overlay( :Label ) ),
 Elements( Bar( X, Y, Legend( 7 ) ) )
);

 

Re : Meilleur moyen de tracer un tracé GraphBuilder avec plusieurs variables Y à l'aide de JSL

N'oubliez pas le EMPILER commande.Nécessite eval(parse()) mais c'est assez propre sinon.Voici un exemple avec trois colonnes à tracer.

dt = New Table( "Test",
 Add Rows( 12 ),
 New Column( "Category",
  Character,
  "Nominal",
  Set Values( {"A", "A", "A", "B", "B", "B", "C", "C", "C", "D", "D", "D"} )
 ),
 New Column( "Value1",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [1, 4, 2, 3, 6, 2, 3, 5, 4, 1, 3, 6] )
 ),
 New Column( "Value2",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [6, 3, 5, 2, 8, 6, 5, 2, 6, 3, 5, 4] )
 ),

 New Column( "Value3",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [1, 4, 3, 6, 5, 7, 3, 4, 2, 8, 6, 1] )
 )
);

dt_cols = dt << get column names(string);
removefrom(dt_cols, 1); // Remove Category

// Create the list of columns, like this: ":Value1, :Value2, :Value3"
col_list = ":" || concat items(dt_cols, ", :");

stack_str = evalinsert(
"\[dts = dt << Stack(invisible,
 columns( ^col_list^ ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" ))]\");
eval(parse(stack_str));

dts << Graph Builder(
 Size( 518, 448 ),
 Show Control Panel( 0 ),
 Variables( X( :Category ), Y( :Data ), Overlay( :Label ) ),
 Elements( Bar( X, Y, Legend( 7 ) ) )
);

 

 

Re : Meilleur moyen de tracer un tracé GraphBuilder avec plusieurs variables Y à l'aide de JSL

Cela utilise toujours des boucles pour construire ces expressions, mais il concatène des listes d'arguments au lieu de les remplacer :

 

Names default to here(1);

//call another function (f) with the arguments provided in a list (l)
do.call = function({l,f}, 
 Substitute(
  Name Expr(l),
  Expr({}),
  Name Expr(f)
 );
);

dt = New Table( "Data",
 Add Rows( 12 ),
 New Column( "Category", Character, "Nominal",
  Set Values( {"A", "A", "A", "B", "B", "B", "C", "C", "C", "D", "D", "D"} )
 ),
 New Column( "Value1", Numeric, "Continuous", Format( "Best", 12 ),
  Set Values( [1, 4, 2, 3, 6, 2, 3, 5, 4, 1, 3, 6] )
 ),
 New Column( "Value2", Numeric, "Continuous", Format( "Best", 12 ),
  Set Values( [6, 3, 5, 2, 8, 6, 5, 2, 6, 3, 5, 4] )
 )
);

vars = {:Value1, :Value2};

VarExpr = do.call(
 { X( :Category ) } || transform each({v}, vars, eval expr( Y( Expr( Name Expr( v ) ), Position( 1 ) ) ) ),
 expr(Variables())
);

BarExpr = do.call(
 { X } || transform each({v, i}, vars, eval expr( Y( Expr( i ) ) ) ) || { Legend( 4 ), Summary Statistic( "Range" ) },
 expr(Bar())
);

Eval( Eval Expr(
 dt << Graph Builder(
  Size( 522, 450 ),
  Show Control Panel( 0 ),
  Expr( Name Expr( VarExpr ) ),
  Elements( Expr( Name Expr( BarExpr ) ) )
 )
) );

Re : Meilleur moyen de tracer un tracé GraphBuilder avec plusieurs variables Y à l'aide de JSL

J'ai généralement utilisé des méthodes similaires à vous pour construire de tels constructeurs de graphes, cela pourrait être une bonne lecture Re : Pouvez-vous construire ceci sans écrire d'expression dans une chaîne ?

Re : Meilleur moyen de tracer un tracé GraphBuilder avec plusieurs variables Y à l'aide de JSL

Ok, c'est comme ça que j'ai résolu le problème, mais y a-t-il un moyen plus simple? Je ne peux pas croire que pour écrire un script aussi simple, j'ai besoin d'entrer dans ce genre de complexité... :

 

parameters = {:"Value1"n, :"Value2"n};

yExpr = Expr( Y() );
yExprPos = Expr( Y( Position( 1 ) ) );
barExpr = Expr(
 Bar( X, Summary Statistic( "Range" ) )
);
yNExpr = Expr( Y() );
variablesExpr = Expr(
 Variables( X( :Category ) )
);

For Each( {value, index}, parameters,
 Insert Into( yExpr, Name Expr( value ), 1 );
 yExprPos = Expr( Y( Position( 1 ) ) );
 Insert Into( yExprPos, Name Expr( value ), 1 );
 Insert Into( variablesExpr, Name Expr( yExprPos ) );
 //This is for Y(1) etc. in Bar()
 yNExpr = Expr( Y() );
 Insert Into( yNExpr, Name Expr( index ) );
 
 Insert Into( barExpr, Name Expr( yNExpr ), 2 );
);


//Name Expr( yExpr );
Show(Name Expr( variablesExpr ));
Show(Name Expr( barExpr ));

gbExpr = Expr(
 Graph Builder( Size( 522, 450 ), Show Control Panel( 0 ), placeholder1, Elements( placeholder2 ) )
 
);

Eval( 
 Substitute( 
  Substitute( 
   Name Expr(gbExpr),    
   Expr( placeholder1 ), 
   Name Expr( variablesExpr )
  ), 
  Expr( placeholder2 ), 
  Name Expr( barExpr ) 
 ) 
);