62449_it-IT

liliconcom

Disporre in righe per gruppo

CIAO,

 

Ecco il problema che sto cercando di risolvere:

6 variabili continue Y (Y1,Y2,..Y6), stessa variabile X continua (1) e campo ID campione (SID).

Sto eseguendo un raggruppamento di adattamento BiVariate per SID. Vorrei che tutte e 6 le trame fossero di fila e con ciascun gruppo SID.

ID=1

Y1,Y2,Y3,Y4,Y5,Y6,

ID=2

Y1,Y2,Y3,Y4,Y5,Y6,

......

 

Come scriverei questo script? Le Y e le X sono note e fisse, mentre il numero di ID campione varierà.

 

Andy

 

Re: Disporre in righe per gruppo

Penso che in questo modo potrebbe essere più semplice e darti il layout che desideri:

New Window( "Fitness - Bivariate",
 V List Box(
  Fit Group(
   Bivariate( Y( :Age ), X( :MaxPulse ) ),
   Bivariate( Y( :Weight ), X( :MaxPulse ) ),
   Bivariate( Y( :Oxy ), X( :MaxPulse ) ),
   Bivariate( Y( :Runtime ), X( :MaxPulse ) ),
   Bivariate( Y( :RunPulse ), X( :MaxPulse ) ),
   Bivariate( Y( :RstPulse ), X( :MaxPulse ) ),
   <<{Arrange in Rows( 2 )},
   By( :Sex )
  ),
  Fit Group(
   Bivariate( Y( :Age ), X( :MaxPulse ) ),
   Bivariate( Y( :Weight ), X( :MaxPulse ) ),
   Bivariate( Y( :Oxy ), X( :MaxPulse ) ),
   Bivariate( Y( :Runtime ), X( :MaxPulse ) ),
   Bivariate( Y( :RunPulse ), X( :MaxPulse ) ),
   Bivariate( Y( :RstPulse ), X( :MaxPulse ) ),
   <<{Arrange in Rows( 2 )},
   By( :Sex )
  )
 )
);

Re: Disporre in righe per gruppo

Questo mostra un modo per controllare il layout, ma la matrice di grafici risultante è la trasposizione di ciò che desideri.

New Window( "In a Row",
 Line Up Box( N Col( 2 ),
  Bivariate(
   Y( :age, :weight, :oxy, :runtime ),
   X( :runpulse ),
   By( :sex )
  )
 )
);

Re: Disporre in righe per gruppo

Il codice di txnelson fa il lavoro, anche se nel suo esempio avevo bisogno di commentare la riga di codice

//dt << cancella colonne( Index( 9, 129 ) ); perché funzioni.

 

Devo ammetterlo, non lo capisco del tutto e sono inciampato un po' con questa frase

dt << seleziona dove ( : SID == Num ( SIDgrps [ io ] ) ) ; dal momento che il mio ID è in realtà carattere. Ho rimosso Num() per farlo funzionare.

 

La soluzione di Mark esegue solo il raggruppamento per SID ma non raggruppa i grafici in righe.

 

Andy

Re: Disporre in righe per gruppo

Dalla tua descrizione, sembra che tutto ciò che devi fare sia usare SID nel ruolo By.

Bivariate(
 Y( :Y1, :Y2, :Y3, :Y4, :Y5, :Y6 ),
 X( :X ),
 By( :SID )
);

Re: Disporre in righe per gruppo

Ecco uno script di esempio che utilizza una metodologia che ho usato molte volte, che penso produca i risultati desiderati.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

// Setup data to look somewhat like your data
dt << delete columns( 1, 2, 3 );
Column( dt, 1 ) << set name( "SID" );
Column( dt, 2 ) << set name( "X" );
Column( dt, 3 ) << set name( "Y1" );
Column( dt, 4 ) << set name( "Y2" );
Column( dt, 5 ) << set name( "Y3" );
Column( dt, 6 ) << set name( "Y4" );
Column( dt, 7 ) << set name( "Y5" );
Column( dt, 8 ) << set name( "Y6" );
dt << delete columns( Index( 9, 129 ) );

// Determine the number of SIDs
Summarize( dt, SIDgrps = by( SID ) );

// Create the output window
nw = New Window( "Report", MainVLB = V List Box() );

// Create a list to hold the data table names 
dtList = {};

// Setup what to do when the display window is closed
nw << on close( For( i = 1, i <= N Items( SIDgrps ), i++, Close( dtList[i], nosave ) ) );

// Loop through the SIDs and generate the required reports
For( i = 1, i <= N Items( SIDgrps ), i++,
 dt << select where( :SID == Num( SIDgrps[i] ) );
 dtSub = dt << subset( selected rows( 1 ), selected columns( 0 ), invisible );
 Insert Into( dtList, dtSub );
 dtSub << set name( "SID=" || SIDgrps[i] );
 ob = Outline Box( "SID=" || SIDgrps[i],
  H List Box(
   dtSub = Bivariate( Y( :Y1 ), X( :X ) ),
   dtSub = Bivariate( Y( :Y2 ), X( :X ) ),
   dtSub = Bivariate( Y( :Y3 ), X( :X ) ),
   dtSub = Bivariate( Y( :Y4 ), X( :X ) ),
   dtSub = Bivariate( Y( :Y5 ), X( :X ) ),
   dtSub = Bivariate( Y( :Y6 ), X( :X ) ),

  )
 );
 // Add the current set of reports to the main display
 MainVLB << append( ob );
);