548023_es-ES

liliconcom

Cambiar el color de fondo del gráfico entre las líneas de referencia

Hola, tengo un diagrama de dispersión con una línea de mejor ajuste a la que he agregado 2 líneas de referencia en el eje x.

¿Hay una manera fácil de cambiar el fondo del área entre ambas líneas de referencia a gris claro?

 

¡Gracias!

GráficosRe: Cambiar el color de fondo de un grafico entre lineas de referencia

Una opción es usar algunas secuencias de comandos y agregar secuencias de comandos gráficas.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
 Variables(X(:weight), Y(:height)),
 Elements(Points(X, Y, Legend(3))),
 SendToReport(
  Dispatch(
   {},
   "height",
   ScaleBox,
   {Add Ref Line(65, "Solid", "Black", "", 1),
   Add Ref Line(55, "Solid", "Black", "", 1)}
  )
 )
);

rep = gb << report;
framebox = rep[frame box(1)];
framebox << Add Graphics Script(
 Transparency(0.5);
 Fill Color("Gray");
 Rect(X Origin(), 65, X Origin() + X Range(), 55, 1)
);

Re: Cambiar el color de fondo de un grafico entre lineas de referencia

También puede utilizar una región de referencia. La región es independiente de las rectas. Puedes usar uno o ambos.

 

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

gb = dt << Graph Builder(
 Variables( X( :weight ), Y( :height) ),
 Elements( Points( X, Y, Legend( 3 ) ) )
);

rpt = gb << Report;

rpt[AxisBox(2)]
 << Add Ref Line( 55, "Solid", "Black", "", 1 )
 << Add Ref Line( 65, "Solid", "Black", "", 1 )
 << Add Ref Line( { 55, 65 }, "Solid", "Green", "", 1, 0.25 );