548023_ko-KR

liliconcom

참조선 사이의 그래프 배경색 변경

안녕하세요, 저는 x축에 2개의 참조선을 추가한 최적의 선이 있는 산점도를 가지고 있습니다.

두 참조선 사이의 영역 배경을 밝은 회색으로 쉽게 변경할 수 있는 방법이 있습니까?

 

감사!

제도법Re: 참조선 사이의 그래프 배경색 변경

한 가지 옵션은 일부 스크립팅을 사용하고 그래픽 스크립트를 추가하는 것입니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
 Variables(X(:weight), Y(:height)),
 Elements(Points(X, Y, Legend(3))),
 SendToReport(
  Dispatch(
   {},
   "height",
   ScaleBox,
   {Add Ref Line(65, "Solid", "Black", "", 1),
   Add Ref Line(55, "Solid", "Black", "", 1)}
  )
 )
);

rep = gb << report;
framebox = rep[frame box(1)];
framebox << Add Graphics Script(
 Transparency(0.5);
 Fill Color("Gray");
 Rect(X Origin(), 65, X Origin() + X Range(), 55, 1)
);

Re: 참조선 사이의 그래프 배경색 변경

참조 영역을 사용할 수도 있습니다. 영역은 선과 독립적입니다. 둘 중 하나 또는 둘 다를 사용할 수 있습니다.

 

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

gb = dt << Graph Builder(
 Variables( X( :weight ), Y( :height) ),
 Elements( Points( X, Y, Legend( 3 ) ) )
);

rpt = gb << Report;

rpt[AxisBox(2)]
 << Add Ref Line( 55, "Solid", "Black", "", 1 )
 << Add Ref Line( 65, "Solid", "Black", "", 1 )
 << Add Ref Line( { 55, 65 }, "Solid", "Green", "", 1, 0.25 );