287220_zh-CN

liliconcom

图形生成器框中的 JSL 脚本根据晶圆编号绘制所有列

您好，我正在尝试根据晶圆编号绘制我的数据（多个参数）。 我从社区中找到了分布图的脚本。 因此，我通过将 Distribution 函数替换为 Graph Builder 函数对其进行了修改。 但是，报告中只显示了一张图表，而不是所有图表。 我能就这个剧本给你一些建议吗？ 谢谢你。

 

dt = Current Data Table ();

// Get all of the continuous data columns
colNames = dt << get column names( string, continuous );

// Create the JSL to create the script
theExpr = "Graph Builder(
 Size( 1414, 795 ),
 Show Control Panel( 0 ),
 Variables( X( :WF_NUM ), Y( colNames[1] ), Color( :WF_NUM ) ),
 Elements( Box Plot( X, Y, Legend( 7 ) ) )
);
)";

For( i = 1, i <= N Items( colNames ), i++,
 theExpr = theExpr || ", Graph Builder(
 Size( 1414, 795 ),
 Show Control Panel( 0 ),
 Variables( X( :WF_NUM ), Y(colNames[" || Char( i ) || "] ), Color( :WF_NUM ) ),
 Elements( Box Plot( X, Y, Legend( 7 ) ) )
)");

// place the closing ")" to complete the command string
theExpr = theExpr || ");";

// Run the created JSL
Eval(Parse(theExpr));

谢谢您的帮助。

 

多米尼克

图形脚本回复：图形生成器框中的 JSL 脚本将所有列与晶圆编号相对应

谢谢您的帮助@txnelson

 

通过详细信息和代码欣赏答案。

回复：图形生成器框上的 JSL 脚本绘制所有列与晶圆编号的关系

所需要做的就是将图形生成放在 New Window() 函数中。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

// Change the name of the Wafer column to match the name used
// in the Graph Builder code
dt:wafer << set name( "WF_NUM" );

colNames = dt << get column names( string, continuous );

nw = New Window( "Graphs", 

// Since there are 128 columns that could be plotted, the code has been
 // modified to just produce 3 of the plots.  The commented out code
 // should replace the "i <= 3, i++," to plot all graphs
 For( i = 1, i <= 3, i++, // N Items( colNames ), i++,
  dt << Graph Builder(
   Size( 1414, 795 ),
   Show Control Panel( 0 ),
   Variables(
    X( :WF_NUM ),
    Y( As Column( dt, colNames[i] ) ),
    Color( :WF_NUM )
   ),
   Elements( Box Plot( X, Y, Legend( 7 ) ) )
  ),

 );

);

回复：图形生成器框中的 JSL 脚本将所有列与晶圆编号相对应

你好@txnelson ,

 

感谢你的回复。

 

这些图表是使用您修改后的代码绘制的。 关于修改后的代码的一个额外问题。 当我使用社区的参考代码制作分布图时，所有的图表都被汇总到一个报告中，可以很容易地导出到 powerpoint。 请问您简化为汇总图表到单个报告中的代码需要哪些额外的行？

 

谢谢您的帮助。

多米尼克

回复：图形生成器框中的 JSL 脚本将所有列与晶圆编号相对应

您提供的 JSL 可以简化以生成您想要的图表。以下是您的代码的修改

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

// Change the name of the Wafer column to match the name used
// in the Graph Builder code
dt:wafer << set name( "WF_NUM" );<BR />colNames = dt << get column names( string, continuous );

// Since there are 128 columns that could be plotted, the code has been
// modified to just produce 3 of the plots.  The commented out code
// should replace the "i <= 3, i++," to plot all graphs
For( i = 1, i <= 3, i++, // N Items( colNames ), i++,
 dt << Graph Builder(
  Size( 1414, 795 ),
  Show Control Panel( 0 ),
  Variables(
   X( :WF_NUM ),
   Y( As Column( dt, colNames[i] ) ),
   Color( :WF_NUM )
  ),
  Elements( Box Plot( X, Y, Legend( 7 ) ) )
 )
);