547432_zh-TW

liliconcom

使用頁面時在建構器上的每個圖表上顯示圖例

今天至少在聊天中有人問過這個問題。 以下是關於如何處理此問題的幾個可能的選項（我也將其作為建議發佈到願望清單中）新增選項以在使用頁面時將圖形產生器圖例擴展到每個頁面）

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Probe.jmp");

// Use XPatH() and Picture Box with legend
gb = dt << Graph Builder(
 Show Control Panel(0),
 Size(500, 9760),
 Variables(X(:DELW_NEMIT), Y(:DELL_RPNBR), Page(:Wafer Number), Color(:Process)),
 Elements(Points(X, Y, Legend(5)))
);

lg = (gb << XPath("//LegendBox"))[1];
lg_pic = lg << get picture;

fbs = (gb << XPath("//FrameBox")) << parent;
Remove From(fbs, 1); // first one already has "real" legend
//margins will need to be adjusted depending on GB size
fbs << append(Picture Box(lg_pic, << Margin(Left((gb << get size)[1]-130), Top(-15), Right(0), Bottom(0))));


// Loop over groups one by one while using Where()
nw = New Window("GBs",
 lub = Lineup Box(N Col(1));
);
Summarize(dt, pages = by(:Wafer Number));

For Each({page}, pages,
 gb_page_expr = Expr(
  Eval(EvalExpr(gb = dt << Graph Builder(
   Show Control Panel(0),
   Size(500, 500),
   Variables(X(:DELW_NEMIT), Y(:DELL_RPNBR), Color(:Process), Group X(:Wafer Number)),
   Elements(Points(X, Y, Legend(5))),
   Where(:Wafer Number == Expr(page))
  )));
 );
 lub << Append(gb_page_expr);
 // gb << Title("");
);
((lub << Top Parent) << XPath("//TextBox[contains(text(), 'Where(:')]")) << Visibility("Collapse");


// most likely best idea, use By()
gbs = Graph Builder(
 Size(534, 456),
 Show Control Panel(0),
 Variables(X(:DELW_NEMIT), Y(:DELL_RPNBR), Color(:Process)),
 Elements(Points(X, Y, Legend(1))),
 By(:Wafer Number)
);

Write();

回覆：使用頁面時在建構器上的每個圖表上顯示圖例

多謝@jthi ！ 它解決了我的問題

回覆：使用頁面時在建構器上的每個圖表上顯示圖例

@glimond67有兩種選擇：

使用對話框按鈕（朱利安在這裡演示回覆：每頁重複圖例）

 

或者

 

前往紅色三角形 -> 重做/重新啟動分析

這將打開您可以填寫的平台選單（如果您已經填寫了一些內容，那麼這些內容將被保留）

 

回覆：使用頁面時在建構器上的每個圖表上顯示圖例

@馬丁德梅爾

 

--> // 最可能最好的主意，用 By()

 

這有效。

但如何猜測Graph Builder上有BY函數，在Graph Builder的控制面板中哪裡可以找到它？

 

我的常規用例大多包含一個包裝，就像這樣。

gbs = Graph Builder(
 Size(534, 456),
 Show Control Panel(0),
 Variables(X(:DELW_NEMIT), Y(:DELL_RPNBR), Wrap( :Die X ), Color(:Process)),
 Elements(Points(X, Y, Legend(1))),
 By(:Wafer Number)
);

且腳本化的 BY() 仍然有效。

但我不知道如何單獨從圖形生成器介面生成它。