547432_de-DE

liliconcom

Zeigen Sie die Legende in jedem Diagramm im Builder an, wenn Sie die Seite verwenden

Dies wurde heute zumindest im Chat gefragt. Im Folgenden finden Sie einige mögliche Optionen, wie Sie damit umgehen können (ich habe dies auch als Vorschlag auf die Wunschliste gesetzt Fügen Sie eine Option hinzu, um die Graph Builders-Legende auf jede Seite zu erweitern, wenn die Seite verwendet wird )

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Probe.jmp");

// Use XPatH() and Picture Box with legend
gb = dt << Graph Builder(
 Show Control Panel(0),
 Size(500, 9760),
 Variables(X(:DELW_NEMIT), Y(:DELL_RPNBR), Page(:Wafer Number), Color(:Process)),
 Elements(Points(X, Y, Legend(5)))
);

lg = (gb << XPath("//LegendBox"))[1];
lg_pic = lg << get picture;

fbs = (gb << XPath("//FrameBox")) << parent;
Remove From(fbs, 1); // first one already has "real" legend
//margins will need to be adjusted depending on GB size
fbs << append(Picture Box(lg_pic, << Margin(Left((gb << get size)[1]-130), Top(-15), Right(0), Bottom(0))));


// Loop over groups one by one while using Where()
nw = New Window("GBs",
 lub = Lineup Box(N Col(1));
);
Summarize(dt, pages = by(:Wafer Number));

For Each({page}, pages,
 gb_page_expr = Expr(
  Eval(EvalExpr(gb = dt << Graph Builder(
   Show Control Panel(0),
   Size(500, 500),
   Variables(X(:DELW_NEMIT), Y(:DELL_RPNBR), Color(:Process), Group X(:Wafer Number)),
   Elements(Points(X, Y, Legend(5))),
   Where(:Wafer Number == Expr(page))
  )));
 );
 lub << Append(gb_page_expr);
 // gb << Title("");
);
((lub << Top Parent) << XPath("//TextBox[contains(text(), 'Where(:')]")) << Visibility("Collapse");


// most likely best idea, use By()
gbs = Graph Builder(
 Size(534, 456),
 Show Control Panel(0),
 Variables(X(:DELW_NEMIT), Y(:DELL_RPNBR), Color(:Process)),
 Elements(Points(X, Y, Legend(1))),
 By(:Wafer Number)
);

Write();

Betreff: Legende in jedem Diagramm im Builder anzeigen, wenn die Seite verwendet wird

@glimond67 Es gibt zwei Möglichkeiten:

Verwenden Sie die Schaltfläche „Dialog“ (Julian demonstriert es hier). Betreff: Legende auf jeder Seite wiederholen )

 

oder

 

Gehen Sie zum roten Dreieck -> Analyse wiederholen / neu starten

Dadurch wird das Plattformmenü geöffnet, das Sie ausfüllen können (und wenn Sie bereits etwas ausgefüllt hatten, bleiben diese erhalten).

 

Betreff: Legende in jedem Diagramm im Builder anzeigen, wenn die Seite verwendet wird

@martindemel

 

--> // höchstwahrscheinlich beste Idee, verwenden Sie By()

 

Das funktioniert.

Aber wie kann man erraten, dass es in Graph Builder eine BY-Funktion gibt? Wo kann man sie in der Systemsteuerung von Graph Builder finden?

 

In meinem regulären Anwendungsfall ist meistens eine Verpackung wie diese enthalten.

gbs = Graph Builder(
 Size(534, 456),
 Show Control Panel(0),
 Variables(X(:DELW_NEMIT), Y(:DELL_RPNBR), Wrap( :Die X ), Color(:Process)),
 Elements(Points(X, Y, Legend(1))),
 By(:Wafer Number)
);

und das Skript BY() funktioniert immer noch.

Ich sehe jedoch nicht ein, wie ich dies allein über die Graph Builder-Schnittstelle erstellen kann.