547169_es-ES

liliconcom

Color de matriz de confusión y conteo basado en diferentes variables

Hola,

Estoy trabajando en una matriz de confusión usando el generador de gráficos. Tengo 2 columnas, una es clase conocida (eje y) y la otra clase prevista (eje x). Quiero que los números dentro de las cajas muestren la cantidad de muestras en cada caja. Como se muestra en la imagen de abajo.

 

 

Sin embargo, en lugar del mapa de gradiente de color, me gustaría que la diagonal principal (Verdaderos positivos) sea de un color y el resto de los cuadros de un color diferente. Tengo una columna que es 1 o 0 dependiendo de si la muestra es un verdadero positivo o no, sin embargo, cuando agrego esta columna a la opción de color en Graph Builder, esto sucede:

¿Hay alguna manera de que pueda tener los colores como en la segunda imagen, pero las etiquetas de la primera imagen?

 

¡Gracias!

 

 

GráficosRe: Color de matriz de confusión y conteo basado en diferentes variables

Podrías resumir la tabla primero y luego dibujar tu gráfico usando etiquetas de fila en lugar de los conteos:

 

 

 

Names Default To Here( 1 );

dt = Open( "$Sample_data/big class.jmp" );
<BR />random reset(2);
dt << New Column("Age 2", Numeric, "Ordinal", Format("Fixed Dec", 5, 0), Formula(:age[Col Shuffle()]));
dt:age << Set Name("Age 1");
dtSum = (dt << Tabulate(
 Add Table(
  Column Table( Statistics( N ) ),
  Row Table( Grouping Columns( :"Age 2"n, :"Age 1"n ) )
 )
)) << Make Into Data Table;

dtSum << New Column("Is Diagonal", Numeric, "Nominal", Format("Best", 12), Formula(:Age 1 == :Age 2));

dtSum << Graph Builder(
 Size( 525, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :Age 1 ), Y( :Age 2 ), Color( :Is Diagonal ) ),
 Elements( Heatmap( X, Y, Legend( 5 ), Label( "Label by Row" ) ) ),
 SendToReport(
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    5,
    Properties( 0, {Fill Color( -15790017 )}, Item ID( "0", 1 ) ),
    Properties( 1, {Fill Color( 5 )}, Item ID( "1", 1 ) )
   )}
  )
 )
);

 

Re: Color de matriz de confusión y conteo basado en diferentes variables

Gracias por su respuesta, pero no creo que esto brinde la solución correcta, consulte a continuación:

 

La izquierda muestra los valores reales que deben mostrarse, la derecha es lo que da como resultado el script proporcionado.

Re: Color de matriz de confusión y conteo basado en diferentes variables

Lo siento, me perdí guardar ese paso.De nuevo aquí yo Primero resumí la tabla y luego dibujé el gráfico usando etiquetas de fila en lugar de conteos, pero esta vez definí etiquetas de fila:

 

 

Names Default To Here( 1 );

dt = Open( "$Sample_data/big class.jmp" );

random reset(2);
dt << New Column("Age 2", Numeric, "Ordinal", Format("Fixed Dec", 5, 0), Formula(:age[Col Shuffle()]));
dt << Run Formulas;
dt:age << Set Name("Age 1");
dtSum = (sum = dt << Tabulate(
 Add Table(
  Column Table( Statistics( N ) ),
  Row Table( Grouping Columns( :"Age 2"n, :"Age 1"n ) )
 )
)) << Make Into Data Table;

dtSum << New Column("Is Diagonal", Numeric, "Nominal", Format("Best", 12), Formula(:Age 1 == :Age 2));

dtSum:N << Label( 1 );

gb = dtSum << Graph Builder(
 Size( 525, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :Age 1 ), Y( :Age 2 ), Color( :Is Diagonal ) ),
 Elements( Heatmap( X, Y, Legend( 5 ), Label( "Label by Row" ) ) ),
 SendToReport(
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    5,
    Properties( 0, {Fill Color( -15790017 )}, Item ID( "0", 1 ) ),
    Properties( 1, {Fill Color( 5 )}, Item ID( "1", 1 ) )
   )}
  )
 )
);