547169_de-DE

liliconcom

Farbe und Anzahl der Verwirrungsmatrix basierend auf verschiedenen Variablen

Hallo,

Ich arbeite mit dem Graph Builder an einer Verwirrungsmatrix. Ich habe 2 Spalten, eine davon ist die bekannte Klasse (y-Achse) und die andere die vorhergesagte Klasse (x-Achse). Ich möchte, dass die Zahlen in den Kästchen die Anzahl der Proben in jedem Kästchen anzeigen. Wie im Bild unten gezeigt.

 

 

Anstelle der Farbverlaufskarte möchte ich jedoch, dass die Hauptdiagonale (True Positives) eine Farbe und die restlichen Kästchen eine andere Farbe haben. Ich habe eine Spalte, die entweder 1 oder 0 ist, je nachdem, ob die Probe ein echtes Positiv ist oder nicht. Wenn ich diese Spalte jedoch zur Farboption im Graph Builder hinzufüge, passiert Folgendes:

Gibt es eine Möglichkeit, die Farben wie im zweiten Bild, aber die Beschriftungen des ersten Bildes zu verwenden?

 

Danke schön!

 

 

MassenanpassungBetreff: Farbe und Anzahl der Verwirrungsmatrix basierend auf verschiedenen Variablen

Tut mir leid, ich habe diesen Schritt nicht gespeichert.Auch hier wieder ich habe zuerst die Tabelle zusammengefasst und dann das Diagramm mit Zeilenbeschriftungen anstelle der Anzahlen gezeichnet, aber dieses Mal habe ich tatsächlich Zeilenbeschriftungen definiert:

 

 

Names Default To Here( 1 );

dt = Open( "$Sample_data/big class.jmp" );

random reset(2);
dt << New Column("Age 2", Numeric, "Ordinal", Format("Fixed Dec", 5, 0), Formula(:age[Col Shuffle()]));
dt << Run Formulas;
dt:age << Set Name("Age 1");
dtSum = (sum = dt << Tabulate(
 Add Table(
  Column Table( Statistics( N ) ),
  Row Table( Grouping Columns( :"Age 2"n, :"Age 1"n ) )
 )
)) << Make Into Data Table;

dtSum << New Column("Is Diagonal", Numeric, "Nominal", Format("Best", 12), Formula(:Age 1 == :Age 2));

dtSum:N << Label( 1 );

gb = dtSum << Graph Builder(
 Size( 525, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :Age 1 ), Y( :Age 2 ), Color( :Is Diagonal ) ),
 Elements( Heatmap( X, Y, Legend( 5 ), Label( "Label by Row" ) ) ),
 SendToReport(
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    5,
    Properties( 0, {Fill Color( -15790017 )}, Item ID( "0", 1 ) ),
    Properties( 1, {Fill Color( 5 )}, Item ID( "1", 1 ) )
   )}
  )
 )
);

 

Betreff: Farbe und Anzahl der Verwirrungsmatrix basierend auf verschiedenen Variablen

Vielen Dank für Ihre Antwort, aber ich glaube nicht, dass dies die richtige Lösung ist, siehe unten:

 

Links werden die tatsächlichen Werte angezeigt, die angezeigt werden sollen, rechts die Ergebnisse des bereitgestellten Skripts.

Betreff: Farbe und Anzahl der Verwirrungsmatrix basierend auf verschiedenen Variablen

Sie können die Tabelle zunächst zusammenfassen und dann Ihr Diagramm mithilfe von Zeilenbeschriftungen anstelle der Anzahl zeichnen:

 

 

 

Names Default To Here( 1 );

dt = Open( "$Sample_data/big class.jmp" );
<BR />random reset(2);
dt << New Column("Age 2", Numeric, "Ordinal", Format("Fixed Dec", 5, 0), Formula(:age[Col Shuffle()]));
dt:age << Set Name("Age 1");
dtSum = (dt << Tabulate(
 Add Table(
  Column Table( Statistics( N ) ),
  Row Table( Grouping Columns( :"Age 2"n, :"Age 1"n ) )
 )
)) << Make Into Data Table;

dtSum << New Column("Is Diagonal", Numeric, "Nominal", Format("Best", 12), Formula(:Age 1 == :Age 2));

dtSum << Graph Builder(
 Size( 525, 450 ),
 Show Control Panel( 0 ),
 Variables( X( :Age 1 ), Y( :Age 2 ), Color( :Is Diagonal ) ),
 Elements( Heatmap( X, Y, Legend( 5 ), Label( "Label by Row" ) ) ),
 SendToReport(
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    5,
    Properties( 0, {Fill Color( -15790017 )}, Item ID( "0", 1 ) ),
    Properties( 1, {Fill Color( 5 )}, Item ID( "1", 1 ) )
   )}
  )
 )
);