547167_fr-FR

liliconcom

Utilisation de FORMULA pour coller les valeurs d'une colonne en fonction de l'autre colonne à l'aide de l'instruction IF

J'essaie de remplir la colonne de Pentes_1 et Interception_1 (1000 lignes) de Pistes et Interception (36 lignes) , respectivement basés sur si Cycle 2 (1000 lignes) allumettes Cycle 3 (36 rangées)

Pouvez-vous suggérer une formule à saisir dans Pentes_1 et Interception_1 ?

 

 

Tableau de donnéesRe : Utiliser FORMULA pour coller les valeurs d'une colonne en fonction de l'autre colonne à l'aide de l'instruction IF

Vous pourriez faire quelque chose comme ceci :

If( Row() == 1, :Slopes, :Cycle 2 == Lag( :Cycle 2 ), Lag( :Slopes_1 ), :Slopes )

Par exemple:

Names Default To Here( 1 );

dt = Open( "$Sample_data/big class.jmp" );

dt << New Column( "height_1",
 Numeric,
 "Continuous",
 Format( "Best", 12 ),
 Formula( If( Row() == 1, :height, :age == Lag( :age ), Lag( :height_1 ), :height ) )
);

Re : Utiliser FORMULA pour coller les valeurs d'une colonne en fonction de l'autre colonne à l'aide de l'instruction IF

Il existe plusieurs façons de procéder, en voici une utilisant des tableaux associatifs :

Names Default To Here(1);

// Sample data
dt = New Table("Untitled",
 Add Rows(9),
 New Column("C3", Numeric, "Continuous", Format("Best", 12), Set Values([1, 2, 3, ., ., ., ., ., .])),
 New Column("S",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Set Values([0.11, 0.12, 0.13, ., ., ., ., ., .])
 ),
 New Column("I",
  Numeric,
  "Continuous",
  Format("Best", 12),
  Set Values([1.1, 1.2, 1.3, ., ., ., ., ., .])
 ),
 New Column("C2", Numeric, "Continuous", Format("Best", 12), Set Values([1, 1, 1, 2, 2, 2, 3, 3, 3])),
 New Column("S1", Numeric, "Continuous", Format("Best", 12), Set Values([., ., ., ., ., ., ., ., .])),
 New Column("I1", Numeric, "Continuous", Format("Best", 12), Set Values([., ., ., ., ., ., ., ., .]))
);

wait(1);
// Formulas start
Column(dt, "S1") << Formula(
 As Constant(
  aa_slope_c3 = Associative Array(Eval List(:c3 << get values), Eval List(:s << get values));
 );
 aa_slope_c3[:c2];
);

Column(dt, "I1") << Formula(
 As Constant(
  aa_intercept_c3 = Associative Array(Eval List(:c3 << get values), Eval List(:i << get values));
 );
 aa_intercept_c3[:c2];
);

// If data is always like this, can be simplified to
dt << New Column("ss", Numeric, Continuous, Formula(
 :S[:C2]
));
dt << New Column("ii", Numeric, Continuous, Formula(
 :I[:C2]
));

Si vous n'avez pas besoin d'une formule, vous pouvez également utiliser des jointures/jointures virtuelles.

Les formules peuvent être trouvées à partir du script ou du tableau de données joint