543793_it-IT

liliconcom

Come denotare le lettere per contrassegnare differenze significative in un boxplot?

CIAO! Ho JMP Pro 14. Sto creando diversi boxplot in cui voglio mostrare le differenze significative tra le categorie con lettere sopra Q3 come in questo grafico:

Come posso mettere le lettere a e b sopra le caselle? La mia trama è questa:

 

Il codice Mi Graph Builder è:

Graph Builder(
 Size( 571, 448 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Show Title( 0 ),
 Show Footer( 0 ),
 Variables( X( :Cat ), Y( :Name( "Pl/min" ) ) ),
 Elements( Box Plot( X, Y, Legend( 6 ), Box Style( "Solid" ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Cat",
   ScaleBox,
   {Reversed Scale, Label Row(
    {Set Font Size( 12 ), Tick Mark( Label( "6" ), Label( "6 " ) ),
    Tick Mark( Label( "7" ), Label( "7 " ) )}
   )}
  ),
  Dispatch(
   {},
   "Pl/min",
   ScaleBox,
   {Min( 5.5 ), Max( 18 ), Inc( 2 ), Minor Ticks( 1 )}
  ),
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    6,
    Properties(
     0,
     {Line Color( 32 ), Fill Color( 0 )},
     Item ID( "Pl/min", 1 )
    )
   )}
  ),
  Dispatch( {}, "X title", TextEditBox, {Set Font Size( 12 )} ),
  Dispatch( {}, "Y title", TextEditBox, {Set Font Size( 12 )} ),
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   {DispatchSeg(
    Box Plot Seg( "Box Plot (4)" ),
    {Line Color( {128, 128, 128} ), Fill Color( "Medium Dark Red" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (5)" ),
    {Line Color( {128, 128, 128} ), Fill Color( "Medium Dark Yellow" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (6)" ),
    {Line Color( "Medium Dark Yellow" ),
    Fill Color( "Medium Dark Green" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (7)" ),
    {Line Color( "Medium Dark Yellow" ),
    Fill Color( "Medium Dark BlueCyan" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (8)" ),
    {Line Color( "Medium Dark Yellow" ),
    Fill Color( "Medium Dark Magenta" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (9)" ),
    {Line Color( "Medium Dark Purple" ),
    Fill Color( "Medium Dark Fuchsia" )}
   )}
  )
 )
);

Grazie in anticipo.

Magali.

AnaliticaGraficafinestreRi: Come denotare le lettere per evidenziare differenze significative in un boxplot?

secondo me dovresti:

1. Calcola quelle lettere (sulla base dei miei 5 secondi di ricerca su Google, quelle lettere provengono dal test di Tukey, quindi ho appena usato un rapporto sulle lettere di connessione)
2. Crea una nuova colonna che mapperà quelle lettere per correggere le righe
3. Usa quella colonna come indicatore
4. Aggiungi punti al generatore di grafici
5. Usa una statistica di riepilogo adatta per il grafico dei punti per mostrarli in una buona posizione (potrebbe richiedere una nuova colonna per creare un offset)
6. I marcatori dovrebbero essere mostrati nel grafico

Molto probabilmente potresti anche combinare i passaggi 2-6 in uno script grafico

 

Ecco un esempio abbastanza semplice con Big Class che utilizza l'opzione di script non grafica:

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

fit = dt << Oneway(Y(:height), X(:age), All Pairs(1), invisible);
letters_tb = ((Report(fit)[OutlineBox("Connecting Letters Report")]) << child) << child;

tb_letter_cols = Filter Each({col_name}, letters_tb << Get Names,
 Starts With(col_name, "~Letter Column ")
);

aa_letters = Associative Array();
For Each({level, idx}, letters_tb[1] << get,
 aa_letters[level] = "";
 For Each({letter_col, idx_col}, tb_letter_cols,
  aa_letters[level] ||= letters_tb[1 + idx_col][idx];
 );
);
fit << close window;

dt << New Column("TukeyLetters", Character, Nominal, UseForMarker(1), << Set Each Value(
 aa_letters[char(:age)];
));

gb = dt << Graph Builder(
 Size(529, 451),
 Show Control Panel(0),
 Variables(X(:age), Y(:height)),
 Elements(
  Box Plot(X, Y, Legend(6), Box Style("Solid"), Fences(0)),
  Points(
   X,
   Y,
   Legend(7),
   Summary Statistic("Third Quartile"),
   Error Interval("None")
  )
 )
);

 

Modificare:

Elemento della lista dei desideri creato per questo Visualizza lettere significative nel generatore di grafici quando si utilizza il boxplot e in forma y per x quando viene eseguito il confronto