543793_fr-FR

liliconcom

Comment désigner des lettres pour marquer des différences significatives dans une boîte à moustaches ?

Salut! J'ai JMPPro 14. Je crée plusieurs boîtes à moustaches où je veux montrer les différences significatives entre les catégories avec des lettres au-dessus du Q3 comme dans ce graphique :

Comment mettre les lettres a et b au-dessus des cases ? Mon intrigue est celle-ci :

 

Le code Mi Graph Builder est :

Graph Builder(
 Size( 571, 448 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Show Title( 0 ),
 Show Footer( 0 ),
 Variables( X( :Cat ), Y( :Name( "Pl/min" ) ) ),
 Elements( Box Plot( X, Y, Legend( 6 ), Box Style( "Solid" ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Cat",
   ScaleBox,
   {Reversed Scale, Label Row(
    {Set Font Size( 12 ), Tick Mark( Label( "6" ), Label( "6 " ) ),
    Tick Mark( Label( "7" ), Label( "7 " ) )}
   )}
  ),
  Dispatch(
   {},
   "Pl/min",
   ScaleBox,
   {Min( 5.5 ), Max( 18 ), Inc( 2 ), Minor Ticks( 1 )}
  ),
  Dispatch(
   {},
   "400",
   ScaleBox,
   {Legend Model(
    6,
    Properties(
     0,
     {Line Color( 32 ), Fill Color( 0 )},
     Item ID( "Pl/min", 1 )
    )
   )}
  ),
  Dispatch( {}, "X title", TextEditBox, {Set Font Size( 12 )} ),
  Dispatch( {}, "Y title", TextEditBox, {Set Font Size( 12 )} ),
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   {DispatchSeg(
    Box Plot Seg( "Box Plot (4)" ),
    {Line Color( {128, 128, 128} ), Fill Color( "Medium Dark Red" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (5)" ),
    {Line Color( {128, 128, 128} ), Fill Color( "Medium Dark Yellow" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (6)" ),
    {Line Color( "Medium Dark Yellow" ),
    Fill Color( "Medium Dark Green" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (7)" ),
    {Line Color( "Medium Dark Yellow" ),
    Fill Color( "Medium Dark BlueCyan" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (8)" ),
    {Line Color( "Medium Dark Yellow" ),
    Fill Color( "Medium Dark Magenta" )}
   ), DispatchSeg(
    Box Plot Seg( "Box Plot (9)" ),
    {Line Color( "Medium Dark Purple" ),
    Fill Color( "Medium Dark Fuchsia" )}
   )}
  )
 )
);

Merci d'avance.

Magali.

AnalytiqueGraphiqueles fenêtresRe : Comment désigner des lettres pour marquer des différences significatives dans une boîte à moustaches ?

Je pense qu'il faudrait :

1. Calculez ces lettres (sur la base de mes 5 secondes de recherche sur Google, ces lettres proviennent du test de Tukey, donc je viens d'utiliser un rapport de lettres de connexion)
2. Créez une nouvelle colonne qui mappera ces lettres pour corriger les lignes
3. Utilisez cette colonne comme marqueur
4. Ajouter des points au générateur de graphiques
5. Utilisez une statistique récapitulative appropriée pour le tracé des points afin de les afficher au bon emplacement (peut nécessiter une nouvelle colonne pour créer un décalage)
6. Les marqueurs doivent être affichés dans le graphique

Vous pouvez très probablement également combiner les étapes 2 à 6 dans un script graphique

 

Voici un exemple assez simple avec Big Class utilisant l'option de script non graphique :

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

fit = dt << Oneway(Y(:height), X(:age), All Pairs(1), invisible);
letters_tb = ((Report(fit)[OutlineBox("Connecting Letters Report")]) << child) << child;

tb_letter_cols = Filter Each({col_name}, letters_tb << Get Names,
 Starts With(col_name, "~Letter Column ")
);

aa_letters = Associative Array();
For Each({level, idx}, letters_tb[1] << get,
 aa_letters[level] = "";
 For Each({letter_col, idx_col}, tb_letter_cols,
  aa_letters[level] ||= letters_tb[1 + idx_col][idx];
 );
);
fit << close window;

dt << New Column("TukeyLetters", Character, Nominal, UseForMarker(1), << Set Each Value(
 aa_letters[char(:age)];
));

gb = dt << Graph Builder(
 Size(529, 451),
 Show Control Panel(0),
 Variables(X(:age), Y(:height)),
 Elements(
  Box Plot(X, Y, Legend(6), Box Style("Solid"), Fences(0)),
  Points(
   X,
   Y,
   Legend(7),
   Summary Statistic("Third Quartile"),
   Error Interval("None")
  )
 )
);

 

Modifier:

Création d'un élément de la liste de souhaits pour ce Afficher les lettres de signification dans le générateur de graphiques lors de l'utilisation de la boîte à moustaches et dans l'ajustement y par x lorsque la comparaison est effectuée