534518_es-ES

liliconcom

¿Cómo aplicar operaciones matemáticas solo a filas seleccionadas?

Hola,

Soy nuevo en JMP y tengo dificultades para calcular el porcentaje de cambio en la corriente para 5 dispositivos diferentes después de 72 horas de pruebas de esfuerzo, como se muestra en la siguiente tabla. El % de cambio en la corriente se calcula como = (actual @ una duración de estrés determinada - actual @ 0 h)/actual @ 0 h * 100

Esta operación es bastante sencilla en Excel, pero ¿no está seguro de cómo aplicar la fórmula a filas selectivas? ¡Cualquier ayuda será apreciada! Estoy usando la versión JMP15.0.

Modelado estadístico avanzadoLa personalización en masaIngeniería de Calidad y ProcesosRe: ¿Cómo aplicar operaciones matemáticas solo a filas seleccionadas?

A continuación hay 3 métodos para hacer lo que quieras.

Names Default To Here( 1 );
dt = Data Table( "Bluegalaxy" );

// Method 1
dt << New Column( "% Change 1",
 Format( "Percent", 9, 2 ),
 set each value(
  currDevice = :Device Number;
  zeroCurrent = :Current[((dt << get rows where(
   :Device Number == currDevice & :Stress Duration == 0
  ))[1])];
  value = (:Current - zeroCurrent) / zeroCurrent;
 )
);

// Method 2
// Sort the table in assending Device Number/Stress Duration
dt << sort(
 By( :Device Number, Stress Duration ),
 order( Ascending, Assending ),
 Replace Table( 0 )
);
dt << New Column( "% Change 2",
 Format( "Percent", 9, 2 ),
 set each value(
  If( :Stress Duration == 0,
   zeroCurrent = :Current
  );
  (:Current - zeroCurrent) / zeroCurrent;
 )
);
// Sort the table back to the original order
dt << sort(
 By( :Stress Duration, Device Number ),
 order( Ascending, Assending ),
 Replace Table( 0 )
);

// Method 3
// Create a data table with only the 0 Stress Duration values
dt << Select Where( :Stress Duration == 0 );
dtZero = dt << subset( selected rows( 1 ), columns( :device Number, :current ) );
dtZero:current << set name( "zeroCurrent" );
dt << Update( With( dtZero ), Match Columns( :Device Number = :Device Number ) );
dt << New Column( "% Change 3",
 Format( "Percent", 9, 2 ),
 set each value( (:Current - :zeroCurrent) / :zeroCurrent )
);
// Clean up 
dt << delete columns( zeroCurrent );
Close( dtZero, nosave );
dt << clear select;

Todos estos métodos se pueden crear en un modo interactivo.

Nota: estoy usando "Establecer cada valor" en la especificación de las nuevas columnas.Esto se puede cambiar por "Fórmula".La especificación de fórmula permite que se aplique la fórmula a cualquier registro nuevo cuando se agreguen o cambien.En el caso que ha presentado, supongo que querrá que los valores se creen solo una vez, cuando se cree la nueva columna.

 

Re: ¿Cómo aplicar operaciones matemáticas solo a filas seleccionadas?

¡Muchas gracias Jim, por mostrar múltiples formas de resolver este problema! ¡Tu ayuda es muy apreciada!