안녕하세요,
저는 JMP를 처음 사용하며 아래 표에 표시된 대로 72시간의 스트레스 테스트 후 5개 장치에 대한 전류 변화율(%)을 계산하는 데 어려움을 겪고 있습니다. 전류의 % 변화는 = (전류 @ 주어진 스트레스 지속 시간 - 전류 @ 0hr)/전류 @0hr*100으로 계산됩니다.
이 작업은 Excel에서 매우 간단하지만 선택적 행에 수식을 적용하는 방법을 모르시나요? 어떤 도움이라도 대단히 감사하겠습니다! JMP15.0 버전을 사용하고 있습니다.
다음은 원하는 작업을 수행하는 3가지 방법입니다.
Names Default To Here( 1 );
dt = Data Table( "Bluegalaxy" );
// Method 1
dt << New Column( "% Change 1",
Format( "Percent", 9, 2 ),
set each value(
currDevice = :Device Number;
zeroCurrent = :Current[((dt << get rows where(
:Device Number == currDevice & :Stress Duration == 0
))[1])];
value = (:Current - zeroCurrent) / zeroCurrent;
)
);
// Method 2
// Sort the table in assending Device Number/Stress Duration
dt << sort(
By( :Device Number, Stress Duration ),
order( Ascending, Assending ),
Replace Table( 0 )
);
dt << New Column( "% Change 2",
Format( "Percent", 9, 2 ),
set each value(
If( :Stress Duration == 0,
zeroCurrent = :Current
);
(:Current - zeroCurrent) / zeroCurrent;
)
);
// Sort the table back to the original order
dt << sort(
By( :Stress Duration, Device Number ),
order( Ascending, Assending ),
Replace Table( 0 )
);
// Method 3
// Create a data table with only the 0 Stress Duration values
dt << Select Where( :Stress Duration == 0 );
dtZero = dt << subset( selected rows( 1 ), columns( :device Number, :current ) );
dtZero:current << set name( "zeroCurrent" );
dt << Update( With( dtZero ), Match Columns( :Device Number = :Device Number ) );
dt << New Column( "% Change 3",
Format( "Percent", 9, 2 ),
set each value( (:Current - :zeroCurrent) / :zeroCurrent )
);
// Clean up
dt << delete columns( zeroCurrent );
Close( dtZero, nosave );
dt << clear select;
이러한 모든 방법은 대화형 모드에서 만들 수 있습니다.
참고: 새 열의 사양에서 "각 값 설정"을 사용하고 있습니다.이것은 "Formula"로 교체할 수 있습니다.수식 사양을 사용하면 새 레코드가 추가되거나 변경될 때 수식을 적용할 수 있습니다.귀하가 제시한 경우 새 열이 생성될 때 값이 한 번만 생성되기를 원한다고 가정합니다.
이 문제를 해결하는 여러 가지 방법을 보여주신 Jim에게 감사드립니다! 귀하의 도움에 감사드립니다!
