こんにちは、
私は JMP を初めて使用するため、以下の表に示すように、72 時間のストレス テスト後の 5 つの異なるデバイスの電流の変化率 (%) を計算するのに苦労しています。電流の変化率は次のように計算されます = (特定のストレス持続時間での電流 - 0 時間での電流)/0 時間での電流 *100
Excel ではこの操作は非常に簡単ですが、選択した行に数式を適用する方法がわかりませんか?ご協力をよろしくお願いいたします。 JMP15.0バージョンを使用しています。
以下は、あなたが望むことをするための3つの方法です。
Names Default To Here( 1 );
dt = Data Table( "Bluegalaxy" );
// Method 1
dt << New Column( "% Change 1",
Format( "Percent", 9, 2 ),
set each value(
currDevice = :Device Number;
zeroCurrent = :Current[((dt << get rows where(
:Device Number == currDevice & :Stress Duration == 0
))[1])];
value = (:Current - zeroCurrent) / zeroCurrent;
)
);
// Method 2
// Sort the table in assending Device Number/Stress Duration
dt << sort(
By( :Device Number, Stress Duration ),
order( Ascending, Assending ),
Replace Table( 0 )
);
dt << New Column( "% Change 2",
Format( "Percent", 9, 2 ),
set each value(
If( :Stress Duration == 0,
zeroCurrent = :Current
);
(:Current - zeroCurrent) / zeroCurrent;
)
);
// Sort the table back to the original order
dt << sort(
By( :Stress Duration, Device Number ),
order( Ascending, Assending ),
Replace Table( 0 )
);
// Method 3
// Create a data table with only the 0 Stress Duration values
dt << Select Where( :Stress Duration == 0 );
dtZero = dt << subset( selected rows( 1 ), columns( :device Number, :current ) );
dtZero:current << set name( "zeroCurrent" );
dt << Update( With( dtZero ), Match Columns( :Device Number = :Device Number ) );
dt << New Column( "% Change 3",
Format( "Percent", 9, 2 ),
set each value( (:Current - :zeroCurrent) / :zeroCurrent )
);
// Clean up
dt << delete columns( zeroCurrent );
Close( dtZero, nosave );
dt << clear select;
これらのメソッドはすべて、インタラクティブ モードで作成できます。
注: 新しい列の仕様で「各値を設定」を使用しています。これは「フォーミュラ」に置き換えることができます。式の指定により、新しいレコードが追加または変更されたときに式が適用されます。あなたが提示したケースでは、新しい列が作成されたときに、一度だけ値を作成したいと思っていると思います。
この問題を解決する複数の方法を示してくれた Jim に感謝します。 あなたの助けは大歓迎です!
