534518_it-IT

liliconcom

Come applicare le operazioni matematiche solo alle righe selezionate?

Ciao,

Sono nuovo in JMP e faccio fatica a calcolare la variazione percentuale della corrente per 5 dispositivi diversi dopo 72 ore di stress test, come mostrato nella tabella seguente. La variazione percentuale della corrente viene calcolata come = (corrente a una determinata durata dello stress - corrente a 0 ore)/corrente a 0 ore*100

Questa operazione è abbastanza semplice in Excel ma non sai come applicare la formula a righe selettive? Qualsiasi aiuto sarà molto apprezzato! Sto usando la versione JMP15.0.

Modellazione statistica avanzataPersonalizzazione di massaIngegneria della qualità e dei processiRe: Come applicare le operazioni matematiche solo alle righe selezionate?

Di seguito sono riportati 3 metodi per fare ciò che vuoi.

Names Default To Here( 1 );
dt = Data Table( "Bluegalaxy" );

// Method 1
dt << New Column( "% Change 1",
 Format( "Percent", 9, 2 ),
 set each value(
  currDevice = :Device Number;
  zeroCurrent = :Current[((dt << get rows where(
   :Device Number == currDevice & :Stress Duration == 0
  ))[1])];
  value = (:Current - zeroCurrent) / zeroCurrent;
 )
);

// Method 2
// Sort the table in assending Device Number/Stress Duration
dt << sort(
 By( :Device Number, Stress Duration ),
 order( Ascending, Assending ),
 Replace Table( 0 )
);
dt << New Column( "% Change 2",
 Format( "Percent", 9, 2 ),
 set each value(
  If( :Stress Duration == 0,
   zeroCurrent = :Current
  );
  (:Current - zeroCurrent) / zeroCurrent;
 )
);
// Sort the table back to the original order
dt << sort(
 By( :Stress Duration, Device Number ),
 order( Ascending, Assending ),
 Replace Table( 0 )
);

// Method 3
// Create a data table with only the 0 Stress Duration values
dt << Select Where( :Stress Duration == 0 );
dtZero = dt << subset( selected rows( 1 ), columns( :device Number, :current ) );
dtZero:current << set name( "zeroCurrent" );
dt << Update( With( dtZero ), Match Columns( :Device Number = :Device Number ) );
dt << New Column( "% Change 3",
 Format( "Percent", 9, 2 ),
 set each value( (:Current - :zeroCurrent) / :zeroCurrent )
);
// Clean up 
dt << delete columns( zeroCurrent );
Close( dtZero, nosave );
dt << clear select;

Tutti questi metodi possono essere creati in modalità interattiva.

Nota: sto usando "Imposta ogni valore" nella specifica delle nuove colonne.Questo può essere sostituito con "Formula".La specifica Formula consente a tutti i nuovi record di applicare la formula quando vengono aggiunti o modificati.Nel caso che hai presentato, suppongo che vorrai che i valori vengano creati solo una volta, quando viene creata la nuova colonna.

 

Re: Come applicare le operazioni matematiche solo alle righe selezionate?

Grazie mille Jim, per aver mostrato diversi modi per risolvere questo problema! Il tuo aiuto è molto apprezzato!