533175_es-ES

liliconcom

Nombre sin resolver: Framebox y otras propiedades

Hola a todos,

Intenté crear una función pero sigue apareciendo un error con el cuadro de marco, el cuadro de eje y el cuadro de contorno. No entiendo bien qué está mal con la función. Por favor ayuda y explica

Nombre sin resolver: Framebox en acceso o evaluación de 'Framebox', Framebox( 1) /*###*/

bivplot = Function( {x_param, y_param, int1, int2 },
	biv = Bivariate( X( Column( x_param ) ), Y( Column( y_param ) ), 
	Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
	Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
	Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} ));
	rbiv = biv << Report;
	rbiv[Framebox( 1 )] << {Marker Size( 3 )};
	rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
	rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
	rbiv[Framebox( 1 )] << Row Legend( Column( "Sex" ), Color( 1 ), Marker( 0 ), Color Theme( "JMP Default" ), Continuous Scale( 0 ) );
	rbiv[Outline Box( 3 )] << Close All Below;
);

colnamex = {"name1", "age1"};
colname = {"name2", "age2"};
int1 = {1.5, 2};
int2 ={-1.5, -2};

lapbiv = Fit Group (
			For( i = 1, i <= N Items( colname ), i++,
				bivplot( colname[i], colnamex[i], int1[i], int2[i] )
			); 
			<<{Arrange in Rows( 4 )}
			SendToReport(Dispatch({},"Fit Group", OutlineBox,{Set Title( "Correlation Plot (All)")}))	
);

Acceso a los datosRe: Nombre sin resolver: Framebox y otras propiedades

Hay un par de problemas.  

1. La plataforma Bivariante requiere 2 columnas numéricas.Está especificando una columna de nombre que supongo que es una columna de caracteres.
2. <<[Organizar en filas (4)} y SendToReport no son sintácticamente correctos para pasar a la pantalla una vez que se completa la plataforma.

El siguiente código funciona con la tabla de datos Big Class

bivplot = Function( {x_param, y_param, int1, int2 },
 biv = Bivariate( X( Column( x_param ) ), Y( Column( y_param ) ), 
 Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
 Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
 Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} ));
 rbiv = biv << Report;
 rbiv[Framebox( 1 )] << {Marker Size( 3 )};
 rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[Framebox( 1 )] << Row Legend( Column( "Sex" ), Color( 1 ), Marker( 0 ), Color Theme( "JMP Default" ), Continuous Scale( 0 ) );
 rbiv[Outline Box( 3 )] << Close All Below;
);

colnamex = {"height", "weight"};
colname = {"weight", "height"};
int1 = {1.5, 2};
int2 ={-1.5, -2};

lapbiv = Fit Group (
   For( i = 1, i <= N Items( colname ), i++,
    bivplot( colname[i], colnamex[i], int1[i], int2[i] )
   ); 
   //<<{Arrange in Rows( 4 )}
   //SendToReport(Dispatch({},"Fit Group", OutlineBox,{Set Title( "Correlation Plot (All)")})) 
);

Re: Nombre sin resolver: Framebox y otras propiedades

Hola txnelson, gracias. ¿Puedo saber cómo puedo organizar los gráficos en 4 filas si <<[Organizar en filas (4)} y SendToReport no son sintácticamente correctos?

Re: Nombre sin resolver: Framebox y otras propiedades

A continuación se muestra una versión de trabajo de su secuencia de comandos

bivplot = Function( {x_param, y_param, int1, int2},
 biv = Bivariate(
  X( Column( x_param ) ),
  Y( Column( y_param ) ),
  Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
  Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
  Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} )
 );
 rbiv = biv << Report;
 rbiv[Framebox( 1 )] << {Marker Size( 3 )};
 rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[Framebox( 1 )] << Row Legend(
  Column( "Sex" ),
  Color( 1 ),
  Marker( 0 ),
  Color Theme( "JMP Default" ),
  Continuous Scale( 0 )
 );
 rbiv[Outline Box( 3 )] << Close All Below;
);

colnamex = {"height", "weight"};
colname = {"weight", "height"};
int1 = {1.5, 2};
int2 = {-1.5, -2};

lapbiv = Fit Group(
 For( i = 1, i <= N Items( colname ), i++,
  bivplot( colname[i], colnamex[i], int1[i], int2[i] )
 )
);
lapbiv << Arrange in Rows( 4 );
Report( lapbiv )[Outline Box( 1 )] << Set Title( "Correlation Plot (All)" );

Re: Nombre sin resolver: Framebox y otras propiedades

Ahora funciona bien, gracias.

Pero tengo una pregunta adicional, ¿por qué cuando intento agregar Agrupar por (: sexo), aparece un error?
Nombre no resuelto: Framebox en acceso o evaluación de 'Framebox', Framebox( 1 ) /*###*/Excepción en lanzamiento de plataforma en acceso o evaluación de 'Fit Group'

 

bivplot = Function( {x_param, y_param, int1, int2},
 biv = Bivariate(
  X( Column( x_param ) ),
  Y( Column( y_param ) ),
        Group By (:Sex),
  Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
  Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
  Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} )
 );
 rbiv = biv << Report;
 rbiv[Framebox( 1 )] << {Marker Size( 3 )};
 rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[Framebox( 1 )] << Row Legend(
  Column( "Sex" ),
  Color( 1 ),
  Marker( 0 ),
  Color Theme( "JMP Default" ),
  Continuous Scale( 0 )
 );
 rbiv[Outline Box( 3 )] << Close All Below;
);

  

Re: Nombre sin resolver: Framebox y otras propiedades

Cuando tiene un elemento By() en Bivariate, se crea un árbol de visualización separado para cada nivel de variable By.Es necesario especificar la referencia de un objeto por debajo de un nivel específico en Por variable(s).

rbiv = report( biv[2] );

A continuación se muestra un ejemplo simple, eliminando todo el informe para el segundo nivel de la variable Por sexo

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "/C:/Program Files/SAS/JMPPRO/15/Samples/Data/Big Class.jmp" );

biv = bivariate( x( :height ), y( :weight ), by( :sex ) );
Show( biv );
Report( biv[2] )[Outline Box( 1 )] << delete;

 

Re: Nombre sin resolver: Framebox y otras propiedades

Ya veo. gracias por la clara explicacion