533175_it-IT

liliconcom

Nome non risolto: Framebox e altre proprietà

Ciao a tutti,

Ho provato a creare una funzione ma continua a ricevere un errore con framebox, axisbox e contour box. Non capisco bene cosa c'è che non va nella funzione. Per favore aiutami e spiega

Nome non risolto: Framebox in accesso o valutazione di 'Framebox' , Framebox( 1 ) /*###*/

bivplot = Function( {x_param, y_param, int1, int2 },
	biv = Bivariate( X( Column( x_param ) ), Y( Column( y_param ) ), 
	Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
	Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
	Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} ));
	rbiv = biv << Report;
	rbiv[Framebox( 1 )] << {Marker Size( 3 )};
	rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
	rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
	rbiv[Framebox( 1 )] << Row Legend( Column( "Sex" ), Color( 1 ), Marker( 0 ), Color Theme( "JMP Default" ), Continuous Scale( 0 ) );
	rbiv[Outline Box( 3 )] << Close All Below;
);

colnamex = {"name1", "age1"};
colname = {"name2", "age2"};
int1 = {1.5, 2};
int2 ={-1.5, -2};

lapbiv = Fit Group (
			For( i = 1, i <= N Items( colname ), i++,
				bivplot( colname[i], colnamex[i], int1[i], int2[i] )
			); 
			<<{Arrange in Rows( 4 )}
			SendToReport(Dispatch({},"Fit Group", OutlineBox,{Set Title( "Correlation Plot (All)")}))	
);

Accesso ai datiRe: Nome non risolto: Framebox e altre proprietà

Ci sono un paio di problemi.  

1. La piattaforma Bivariata richiede 2 colonne numeriche.Stai specificando una colonna Nome che presumo sia una colonna di caratteri.
2. <<[Disponi in righe(4)} e SendToReport non sono sintatticamente corretti per essere passati al Display dopo che la piattaforma è stata completata.

Il codice seguente funziona con la tabella di dati Big Class

bivplot = Function( {x_param, y_param, int1, int2 },
 biv = Bivariate( X( Column( x_param ) ), Y( Column( y_param ) ), 
 Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
 Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
 Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} ));
 rbiv = biv << Report;
 rbiv[Framebox( 1 )] << {Marker Size( 3 )};
 rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[Framebox( 1 )] << Row Legend( Column( "Sex" ), Color( 1 ), Marker( 0 ), Color Theme( "JMP Default" ), Continuous Scale( 0 ) );
 rbiv[Outline Box( 3 )] << Close All Below;
);

colnamex = {"height", "weight"};
colname = {"weight", "height"};
int1 = {1.5, 2};
int2 ={-1.5, -2};

lapbiv = Fit Group (
   For( i = 1, i <= N Items( colname ), i++,
    bivplot( colname[i], colnamex[i], int1[i], int2[i] )
   ); 
   //<<{Arrange in Rows( 4 )}
   //SendToReport(Dispatch({},"Fit Group", OutlineBox,{Set Title( "Correlation Plot (All)")})) 
);

Re: Nome non risolto: Framebox e altre proprietà

Ciao txnelson, grazie. Posso sapere come posso organizzare i grafici in 4 righe se <<[Disponi in righe(4)} e SendToReport non sono sintatticamente corretti?

Re: Nome non risolto: Framebox e altre proprietà

Di seguito è riportata una versione funzionante del tuo script

bivplot = Function( {x_param, y_param, int1, int2},
 biv = Bivariate(
  X( Column( x_param ) ),
  Y( Column( y_param ) ),
  Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
  Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
  Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} )
 );
 rbiv = biv << Report;
 rbiv[Framebox( 1 )] << {Marker Size( 3 )};
 rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[Framebox( 1 )] << Row Legend(
  Column( "Sex" ),
  Color( 1 ),
  Marker( 0 ),
  Color Theme( "JMP Default" ),
  Continuous Scale( 0 )
 );
 rbiv[Outline Box( 3 )] << Close All Below;
);

colnamex = {"height", "weight"};
colname = {"weight", "height"};
int1 = {1.5, 2};
int2 = {-1.5, -2};

lapbiv = Fit Group(
 For( i = 1, i <= N Items( colname ), i++,
  bivplot( colname[i], colnamex[i], int1[i], int2[i] )
 )
);
lapbiv << Arrange in Rows( 4 );
Report( lapbiv )[Outline Box( 1 )] << Set Title( "Correlation Plot (All)" );

Re: Nome non risolto: Framebox e altre proprietà

Ora funziona bene, grazie.

Ma ho un'altra domanda, perché quando provo ad aggiungere Group By (:Sex), viene visualizzato un errore
Nome non risolto: Framebox nell'accesso o nella valutazione di 'Framebox' , Framebox( 1 ) /*###*/Eccezione nel lancio della piattaforma nell'accesso o nella valutazione di 'Fit Group'

 

bivplot = Function( {x_param, y_param, int1, int2},
 biv = Bivariate(
  X( Column( x_param ) ),
  Y( Column( y_param ) ),
        Group By (:Sex),
  Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
  Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
  Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} )
 );
 rbiv = biv << Report;
 rbiv[Framebox( 1 )] << {Marker Size( 3 )};
 rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[Framebox( 1 )] << Row Legend(
  Column( "Sex" ),
  Color( 1 ),
  Marker( 0 ),
  Color Theme( "JMP Default" ),
  Continuous Scale( 0 )
 );
 rbiv[Outline Box( 3 )] << Close All Below;
);

  

Re: Nome non risolto: Framebox e altre proprietà

Quando hai un elemento By() in Bivariate, viene creato un albero di visualizzazione separato per ogni livello di variabile By.È necessario specificare il riferimento di un oggetto al di sotto di un livello specifico nelle variabili By.

rbiv = report( biv[2] );

Di seguito è riportato un semplice esempio, eliminando l'intero report per il secondo livello della variabile Per sesso

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "/C:/Program Files/SAS/JMPPRO/15/Samples/Data/Big Class.jmp" );

biv = bivariate( x( :height ), y( :weight ), by( :sex ) );
Show( biv );
Report( biv[2] )[Outline Box( 1 )] << delete;

 

Re: Nome non risolto: Framebox e altre proprietà

Vedo. Grazie per la chiara spiegazione