533175_fr-FR

liliconcom

Nom non résolu : Framebox et autres propriétés

Salut tout le monde,

J'ai essayé de créer une fonction mais une erreur persiste avec la framebox, l'axisbox et la zone de contour. Je ne comprends pas bien ce qui ne va pas avec la fonction. S'il vous plaît, aidez et expliquez

Nom non résolu : Framebox en accès ou évaluation de 'Framebox' , Framebox( 1 ) /*###*/

bivplot = Function( {x_param, y_param, int1, int2 },
	biv = Bivariate( X( Column( x_param ) ), Y( Column( y_param ) ), 
	Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
	Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
	Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} ));
	rbiv = biv << Report;
	rbiv[Framebox( 1 )] << {Marker Size( 3 )};
	rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
	rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
	rbiv[Framebox( 1 )] << Row Legend( Column( "Sex" ), Color( 1 ), Marker( 0 ), Color Theme( "JMP Default" ), Continuous Scale( 0 ) );
	rbiv[Outline Box( 3 )] << Close All Below;
);

colnamex = {"name1", "age1"};
colname = {"name2", "age2"};
int1 = {1.5, 2};
int2 ={-1.5, -2};

lapbiv = Fit Group (
			For( i = 1, i <= N Items( colname ), i++,
				bivplot( colname[i], colnamex[i], int1[i], int2[i] )
			); 
			<<{Arrange in Rows( 4 )}
			SendToReport(Dispatch({},"Fit Group", OutlineBox,{Set Title( "Correlation Plot (All)")}))	
);

Accès aux donnéesRe : Nom non résolu : Framebox et autres propriétés

Il y a quelques problèmes.  

1. La plate-forme bivariée nécessite 2 colonnes numériques.Vous spécifiez une colonne de nom qui, je suppose, est une colonne de caractères.
2. Le <<[Arranger en lignes (4)} et SendToReport ne sont pas syntaxiquement corrects pour être transmis à l'affichage une fois la plate-forme terminée.

Le code suivant fonctionne avec la table de données Big Class

bivplot = Function( {x_param, y_param, int1, int2 },
 biv = Bivariate( X( Column( x_param ) ), Y( Column( y_param ) ), 
 Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
 Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
 Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} ));
 rbiv = biv << Report;
 rbiv[Framebox( 1 )] << {Marker Size( 3 )};
 rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[Framebox( 1 )] << Row Legend( Column( "Sex" ), Color( 1 ), Marker( 0 ), Color Theme( "JMP Default" ), Continuous Scale( 0 ) );
 rbiv[Outline Box( 3 )] << Close All Below;
);

colnamex = {"height", "weight"};
colname = {"weight", "height"};
int1 = {1.5, 2};
int2 ={-1.5, -2};

lapbiv = Fit Group (
   For( i = 1, i <= N Items( colname ), i++,
    bivplot( colname[i], colnamex[i], int1[i], int2[i] )
   ); 
   //<<{Arrange in Rows( 4 )}
   //SendToReport(Dispatch({},"Fit Group", OutlineBox,{Set Title( "Correlation Plot (All)")})) 
);

Re : Nom non résolu : Framebox et autres propriétés

Salut txnelson, merci. Puis-je savoir comment organiser les tracés en 4 lignes si <<[Arrange in rows(4)} et SendToReport ne sont pas syntaxiquement corrects ?

Re : Nom non résolu : Framebox et autres propriétés

Vous trouverez ci-dessous une version de travail de votre script

bivplot = Function( {x_param, y_param, int1, int2},
 biv = Bivariate(
  X( Column( x_param ) ),
  Y( Column( y_param ) ),
  Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
  Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
  Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} )
 );
 rbiv = biv << Report;
 rbiv[Framebox( 1 )] << {Marker Size( 3 )};
 rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[Framebox( 1 )] << Row Legend(
  Column( "Sex" ),
  Color( 1 ),
  Marker( 0 ),
  Color Theme( "JMP Default" ),
  Continuous Scale( 0 )
 );
 rbiv[Outline Box( 3 )] << Close All Below;
);

colnamex = {"height", "weight"};
colname = {"weight", "height"};
int1 = {1.5, 2};
int2 = {-1.5, -2};

lapbiv = Fit Group(
 For( i = 1, i <= N Items( colname ), i++,
  bivplot( colname[i], colnamex[i], int1[i], int2[i] )
 )
);
lapbiv << Arrange in Rows( 4 );
Report( lapbiv )[Outline Box( 1 )] << Set Title( "Correlation Plot (All)" );

Re : Nom non résolu : Framebox et autres propriétés

Cela fonctionne maintenant bien, merci.

Mais j'ai une question supplémentaire, pourquoi est-ce que lorsque j'essaie d'ajouter Group By (:Sex), cela provoque une erreur
Nom non résolu : Framebox lors de l'accès ou de l'évaluation de 'Framebox' , Framebox( 1 ) /*###*/Exception lors du lancement de la plateforme lors de l'accès ou de l'évaluation de 'Fit Group'

 

bivplot = Function( {x_param, y_param, int1, int2},
 biv = Bivariate(
  X( Column( x_param ) ),
  Y( Column( y_param ) ),
        Group By (:Sex),
  Fit Line( {Confid Curves Indiv( 0 ), Line Color( "Black" )} ),
  Fit Special( Intercept( int1 ), Slope( 1 ), {Line Color( "Purple" )} ),
  Fit Special( Intercept( int2 ), Slope( 1 ), {Line Color( "Purple" )} )
 );
 rbiv = biv << Report;
 rbiv[Framebox( 1 )] << {Marker Size( 3 )};
 rbiv[axisbox( 2 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[axisbox( 1 )] << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) <<
 Show Minor Grid( 1 ) << Show Minor Ticks( 1 );
 rbiv[Framebox( 1 )] << Row Legend(
  Column( "Sex" ),
  Color( 1 ),
  Marker( 0 ),
  Color Theme( "JMP Default" ),
  Continuous Scale( 0 )
 );
 rbiv[Outline Box( 3 )] << Close All Below;
);

  

Re : Nom non résolu : Framebox et autres propriétés

Lorsque vous avez un élément By() dans Bivariate, une arborescence d'affichage distincte est créée pour chaque niveau de variable By.Le référencement d'un objet au-dessous d'un niveau spécifique dans la ou les variables Par doit être spécifié.

rbiv = report( biv[2] );

Vous trouverez ci-dessous un exemple simple, supprimant tout le rapport pour le deuxième niveau de la variable Par sexe

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "/C:/Program Files/SAS/JMPPRO/15/Samples/Data/Big Class.jmp" );

biv = bivariate( x( :height ), y( :weight ), by( :sex ) );
Show( biv );
Report( biv[2] )[Outline Box( 1 )] << delete;

 

Re : Nom non résolu : Framebox et autres propriétés

Je vois. Merci pour l'explication claire