528447_ja-JP

liliconcom

時系列分析 - スクリプト作成者募集

時系列データで ARIMA (1,1,0) 分析を実行しようとしています (サンプルを添付)。テーブルには 450 の都市がありますが、サンプル ファイルには 2 つしかありません。各都市で同じ分析を実行したいです。多くの JMP プラットフォームでは、Ctrl キーを押したまま分析を実行すると、[By] ボックス内のすべての都市で分析が実行されます。ただし、ARIMA 値を設定するには、各都市 (450 個) ごとにダイアログが表示されます。ARIMA (1,1,0) を 1 回指定するだけで各都市に適用できるようにスクリプトを作成する方法があると思いますが、その方法がわかりません。誰か助けてくれませんか?

高度な統計モデリングRe: 時系列分析 - スクリプターが必要

次のスクリプトは、「Zillow Data の RegionName」の一意の値ごとに、「インデックス価格」と「月」の ARIMA(1,1,0) モデルを生成します。

 

Time Series(
 X( :month ),
 Y( :indexed prices ),
 ARIMA( 1, 1, 0 ),
 Forecast Periods( 24 ),
 By( :RegionName of Zillow Data)
);

Re: 時系列分析 - スクリプターが必要

これはあなたが望むものをあなたに与えますか？

New Window( "Subset of Comparison data - Time Series of prices",
 V List Box(
  Time Series(
   X( :month ),
   Y( :prices ),
   ARIMA( 1, 1, 0 ),
   Where(
    :RegionName of Zillow Data == "Los Angeles-Long Beach-Anaheim, CA"
   )
  ),
  Time Series(
   X( :month ),
   Y( :prices ),
   ARIMA( 1, 1, 0 ),
   by(:RegionName of Zillow Data),
   SendToReport(
    Dispatch(
     {"Model Comparison"},
     "",
     ScrollBox,
     {Background Color( 117 )}
    )
   )
  )
 )
);

Re: 時系列分析 - スクリプターが必要

ありがとう - これは私が求めていたものですが、もう 1 つ必要だと思います。これらのモデルからの予測を保存したいのですが、予測式の保存または列の保存の 2 つのオプションを使用すると、地域ごとに新しいデータ テーブルが作成されます (450 個)。予測 (標準誤差と信頼区間の有無にかかわらず) を同じデータ テーブルに表示したいのですが、予測列には各 By グループ領域の予測が含まれている必要があります。つまり、450 ではなく 1 つのデータ テーブルです (1 つの新しいデータ テーブルでも、既存のテーブルに追加された列でもかまいません)。

Re: 時系列分析 - スクリプターが必要

同じ問題 - ありがとう、これは私が求めていたものです。しかし、もう 1 つ必要なことがあります。モデルからの予測をすべて 1 つのテーブルに保存したいのです。保存オプションを Ctrl キーを押しながらクリックすると、地域名ごとに 1 つずつ、合計 450 のテーブルが表示されます。地域名の各値にリンクされた予測列を持つ 1 つのテーブルを取得する方法はありますか?

Re: 時系列分析 - スクリプターが必要

これは、あなたが望むものを与えると私が信じているスクリプトです

Names Default To Here( 1 );
dt = Current Data Table();

ts = Time Series(invisible,
 X( :month ),
 Y( :indexed prices ),
 Forecast Periods( 24 ),
 By( :RegionName of Zillow Data )
);

// Start final table
dtFinal = New Table( "Final", New Column( "RegionName of Zillow Data", character ) );

// Loop across output creating ARIMA and the Save Columns
For( i = 1, i <= N Items( ts ), i++,
 objt = ts[i] << arima( 1, 1, 0 );
 dtTemp = objt << save columns;
 
 // Add the By Group name to the data table
 RZD = Word( 2, Report( ts[i] )[Outline Box( 1 )] << get title, "=" );
 dtTemp << New Column( "RegionName of Zillow Data", character, set each value( RZD ) );

 // Add the new table to the Final data table
 dtFinal << concatenate( dtTemp, Append to first table( 1 ) );
 Close( dtTemp, nosave );
);

Re: 時系列分析 - スクリプターが必要

ジム、またやったね！完全！