528447_it-IT

liliconcom

Analisi delle serie temporali: sono necessari scripter

Sto cercando di fare un'analisi ARIMA (1,1,0) su dati di serie temporali - campione allegato. La mia tabella ha 450 città, solo 2 sono nel file campione. Voglio fare la stessa analisi per ogni città. In molte piattaforme JMP, posso tenere premuto il tasto Ctrl e chiedere l'analisi e verrà eseguita per tutte le città nella casella Per. Tuttavia, per impostare i valori ARIMA, mi viene mostrata la finestra di dialogo per ogni città (450!). Sospetto che ci sia un modo per scrivere questo in modo che io debba specificare ARIMA (1,1,0) solo una volta e applicarlo a ogni città, ma non so come farlo. Qualcuno può aiutarmi?

Modellazione statistica avanzataRe: Analisi delle serie temporali - sono necessari sceneggiatori

Lo script seguente genererà un modello ARIMA(1,1,0) per "prezzi indicizzati" rispetto a "mese" per ogni valore univoco in "RegionName of Zillow Data".

 

Time Series(
 X( :month ),
 Y( :indexed prices ),
 ARIMA( 1, 1, 0 ),
 Forecast Periods( 24 ),
 By( :RegionName of Zillow Data)
);

Re: Analisi delle serie temporali - sono necessari sceneggiatori

Questo ti dà quello che vuoi?

New Window( "Subset of Comparison data - Time Series of prices",
 V List Box(
  Time Series(
   X( :month ),
   Y( :prices ),
   ARIMA( 1, 1, 0 ),
   Where(
    :RegionName of Zillow Data == "Los Angeles-Long Beach-Anaheim, CA"
   )
  ),
  Time Series(
   X( :month ),
   Y( :prices ),
   ARIMA( 1, 1, 0 ),
   by(:RegionName of Zillow Data),
   SendToReport(
    Dispatch(
     {"Model Comparison"},
     "",
     ScrollBox,
     {Background Color( 117 )}
    )
   )
  )
 )
);

Re: Analisi delle serie temporali - sono necessari sceneggiatori

Grazie - questo fa quello che ho chiesto, ma credo di aver bisogno di un'altra cosa.Voglio salvare le previsioni da questi modelli, ma le due opzioni: salva formula di previsione o Salva colonne creano entrambe una nuova tabella di dati per ciascuna regione (450 di esse).Vorrei che le previsioni (con o senza errori standard e intervalli di confidenza) appaiano nella stessa tabella di dati, ma la colonna delle previsioni dovrebbe contenere le previsioni per ciascuna regione del gruppo Per.In altre parole, una tabella di dati, non 450 di esse (può essere una nuova tabella di dati o solo colonne aggiunte alla tabella esistente).

Re: Analisi delle serie temporali - sono necessari sceneggiatori

Stesso problema - grazie, questo fa quello che ho chiesto.Ma ho bisogno di un'altra cosa: voglio salvare le previsioni dal modello in un'unica tabella.Se faccio clic tenendo premuto il tasto Ctrl sulle opzioni di salvataggio, ottengo 450 tabelle, una per ogni nome regione.C'è un modo per ottenere una tabella con la colonna di previsione collegata a ciascun valore in Nome regione?

Re: Analisi delle serie temporali - sono necessari sceneggiatori

Ecco una sceneggiatura che credo ti darà quello che vuoi

Names Default To Here( 1 );
dt = Current Data Table();

ts = Time Series(invisible,
 X( :month ),
 Y( :indexed prices ),
 Forecast Periods( 24 ),
 By( :RegionName of Zillow Data )
);

// Start final table
dtFinal = New Table( "Final", New Column( "RegionName of Zillow Data", character ) );

// Loop across output creating ARIMA and the Save Columns
For( i = 1, i <= N Items( ts ), i++,
 objt = ts[i] << arima( 1, 1, 0 );
 dtTemp = objt << save columns;
 
 // Add the By Group name to the data table
 RZD = Word( 2, Report( ts[i] )[Outline Box( 1 )] << get title, "=" );
 dtTemp << New Column( "RegionName of Zillow Data", character, set each value( RZD ) );

 // Add the new table to the Final data table
 dtFinal << concatenate( dtTemp, Append to first table( 1 ) );
 Close( dtTemp, nosave );
);

Re: Analisi delle serie temporali - sono necessari sceneggiatori

jim, l'hai fatto di nuovo!Perfetto!