523181_es-ES

liliconcom

Usar variable en el generador de gráficos personalizar la ventana de secuencia de comandos

Hola

 

Me gustaría trazar 3 líneas y un área sombreada entre las líneas exteriores usando el script de personalización en el generador de gráficos. La primera es la línea y0=x. La segunda y tercera líneas son y1= a*x e y2 = b*x. (ejemplo a = 1.05 y b = 0.95 Quiero sombrear entre las líneas y1 e y2. Utilizo un relleno de polígono para hacer esto, pero la función de polígono requiere valores fijos y no escala con los ejes del gráfico. ¿Cómo puedo hacer que la región sombreada se escale con el gráfico como lo hacen las tres líneas? es decir, poner una variable en la función poligonal

 

 

Pen Size( 4 );
Line Style( dashed );
Pen Color( "black" );
Y Function( x, x );
Pen Size( 4 );
Line Style( dashed );
Pen Color( "red" );
Y Function( 1.1 * x, x );
Pen Size( 4 );
Line Style( dashed );
Pen Color( "red" );
Y Function( .9 * x, x );
Transparency( 0.5 );
Fill Color( {0.38, 0.84, 0.67} );
Polygon( [0.05, 1, 1, .05], [.045, .95, 1.05, .055] );

 

 

La personalización en masaRe: Usar variable en la ventana de script para personalizar el generador de gráficos

Gracias, adapté esto un poco e incluí coronel max (Columna 2) como límite superior para que todo esto entre en el entorno de script más pequeño del generador de scripts sin tener que definir un script completo del generador de gráficos. Gracias por la ayuda

Pen Size( 4 );
Line Style( dashed );
Pen Color( "black" );
Y Function( x, x );
Pen Size( 4 );
Line Style( dashed );
Pen Color( "red" );
Y Function( 1.1 * x, x );
Pen Size( 4 );
Line Style( dashed );
Pen Color( "red" );
Y Function( .9 * x, x );
Transparency( 0.5 );
Fill Color( {0.38, 0.84, 0.67} );
xMat = [0];
yMat = [0];
xMax = 2*Col Max (Column 1);
yMax = 2*Col Max (Column 2);
xMat = xMat || xMax || xMax || [0];
yMat = yMat || xMax * 1.1 || xMax * .9 || [0];
Polygon( xMat, yMat );

Re: Usar variable en la ventana de script para personalizar el generador de gráficos

Aquí hay un ejemplo simple de cómo puede cambiar el polígono para que coincida con la configuración del eje.

Names Default To Here( 1 );
dt = New Table( "Sample",
 Add Rows( 7 ),
 New Column( "Column 1",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [0.1, 0.2, 0.3, 0.4, 0.5, 0.6, 0.65] )
 ),
 New Column( "Column 2",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [0.2, 0.3, 0.25, 0.3, 0.55, 0.68, 0.9] )
 )
);

gb = Graph Builder(
 Size( 528, 454 ),
 Show Control Panel( 0 ),
 Variables( X( :Column 1 ), Y( :Column 2 ) ),
 Elements( Points( X, Y, Legend( 5 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Column 1",
   ScaleBox,
   {Min( -0.0389121338912134 ), Max( 1.21814306472226 ), Inc( 0.2 ), Minor Ticks( 1 ),
   Label Row(
    {Major Grid Line Color( 1 ), Minor Grid Line Color( 1 ), Show Major Grid( 1 ),
    Show Minor Grid( 1 )}
   )}
  ),
  Dispatch(
   {},
   "Column 2",
   ScaleBox,
   {Min( -0.05302734375 ), Max( 1.20978927612305 ), Inc( 0.2 ), Minor Ticks( 2 ),
   Label Row(
    {Major Grid Line Color( 1 ), Minor Grid Line Color( 1 ), Show Major Grid( 1 ),
    Show Minor Grid( 1 )}
   )}
  )
 )
);

Report( gb )[FrameBox( 1 )] << Add Graphics Script(
 Pen Size( 4 );
 Line Style( dashed );
 Pen Color( "black" );
 Y Function( x, x );
 Pen Size( 4 );
 Line Style( dashed );
 Pen Color( "red" );
 Y Function( 1.1 * x, x );
 Pen Size( 4 );
 Line Style( dashed );
 Pen Color( "red" );
 Y Function( .9 * x, x );
 Transparency( 0.5 );
 Fill Color( {0.38, 0.84, 0.67} );
 xMat = [0.05];
 yMat = [.045];
 xMax = Report( gb )[AxisBox( 2 )] << get max;
 xMat = xMat || xMax || xMax || [0.045];
 yMat = yMat || xMax * 1.1 || xMax * .9 || [0.055];
 Polygon( xMat, yMat );
);