519929_it-IT

liliconcom

expr ed evalexpr per i limiti del gradiente del Costruttore di grafici

Sto cercando di impostare uno script che genererà un generatore di grafici con gradiente minimo e massimo pari ai valori quantili della colonna da tracciare.

Sfortunatamente, la sintassi expr ed evalexpr che sto utilizzando non funziona per la matrice in "Scala valori".

Ho bisogno di aiuto.

dt0 = current data table();
param = "Voltage";
colp = dt0:param;
graph_high = Quantile( 0.975, column(dt0, param) << get as matrix() );
graph_low = Quantile( 0.025, column(dt0, param) << get as matrix() );

cmd = expr(
	Graph Builder(
		Size( 550, 550 ),
		Show Control Panel( 0 ),
		Variables(
			X( :x ),
			Y( :y ),
			Color( :expr(param) )
		),
		Elements( Points( X, Y, Legend( 6 ) ) ),
		SendToReport(
			Dispatch(
				{},
				"400",
				ScaleBox,
				{Legend Model(
					6,
					Properties(
						0,
						{gradient( {Scale Values( [expr(graph_low) expr(graph_high)] )} )}, // *Need Help Here*
						Item ID( expr(param), 1 )
					)
				)}
			)
		)
	);
);

eval(evalexpr(cmd));

Esplorazione e visualizzazione dei datiPersonalizzazione di massaRe: expr e evalexpr per i limiti del gradiente di Graph Builder

Non ho i tuoi dati da convalidare, ma questo dovrebbe funzionare:

 

dt0 = current data table();
param = "Voltage";
colp = dt0:param;
graph_high = Quantile( 0.975, column(dt0, param) << get as matrix() );
graph_low = Quantile( 0.025, column(dt0, param) << get as matrix() );
val matrix = [](1,0) || graph_low || graph_high;

cmd = expr(
 Graph Builder(
  Size( 550, 550 ),
  Show Control Panel( 0 ),
  Variables(
   X( :x ),
   Y( :y ),
   Color( :expr(param) )
  ),
  Elements( Points( X, Y, Legend( 6 ) ) ),
  SendToReport(
   Dispatch(
    {},
    "400",
    ScaleBox,
    {Legend Model(
     6,
     Properties(
      0,
      {gradient( {Scale Values( Expr( val matrix ) )} )}, // *Need Help Here*
      Item ID( expr(param), 1 )
     )
    )}
   )
  )
 );
);

eval(evalexpr(cmd));

Re: expr e evalexpr per i limiti del gradiente di Graph Builder

Molte grazie. Questo ha funzionato.

 

Ora che mi hai dato l'idea di creare una matrice usando le variabili e quindi di inserire quella matrice nello script di Graph Builder, ho deciso di giocare. Sembra che non sia necessario utilizzare Expr() attorno alla "matrice val".

 

Trovo che funzioni anche questo:

dt0 = current data table();
param = "Voltage";
colp = dt0:param;
graph_high = Quantile( 0.975, column(dt0, param) << get as matrix() );
graph_low = Quantile( 0.025, column(dt0, param) << get as matrix() );
val matrix = matrix( {graph_low, graph_high} );

cmd = expr(
 Graph Builder(
  Size( 550, 550 ),
  Show Control Panel( 0 ),
  Variables(
   X( :x ),
   Y( :y ),
   Color( :expr(param) )
  ),
  Elements( Points( X, Y, Legend( 6 ) ) ),
  SendToReport(
   Dispatch(
    {},
    "400",
    ScaleBox,
    {Legend Model(
     6,
     Properties(
      0,
      {gradient( {Scale Values( val matrix )} )},
      Item ID( expr(param), 1 )
     )
    )}
   )
  )
 );
);

eval(evalexpr(cmd));