Smith Charts

MikeD_Anderson

Before I dust off my map-making tools and dive headlong into another shapefile exercise I thought I'd check with everyone - Has anyone seen or done anything along the lines of a Smith Chart in JMP?  Looks like it's come up a couple of times in the community (thread 1 and thread 2), but I'm guessing it's too nitch for active development on the main product.  

 

I'm contemplating creating a shapefile that can be used in Graph Builder as an overlay with cartesian transformed data, but I wanted to make sure I'm not reinventing the wheel.

 

Thoughts?

 

M

Craige_Hales

 

I'm not sure if I'm answering the question; smith charts and shape files seem unrelated. This answer is about smith charts, but substituting polar charts instead.

Use the XYFunction, it will save you a lot of time. If you have the function of your transform, the XY function can use that to warp the lines appropriately. Here's a polar chart example. For the XY function, t is a parameter that goes from 0 to 1 and selects the fraction of the starting angle/radius to the ending angle/radius.

// polar coordinate example
// x,y -> polar: angle = atan(y,x), radius = sqrt(x^2+y^2)
// a,r -> rect: x = r*cos(angle), y = r*sin(angle)
//
polarDrawLine = Function( {a1, r1, a2, r2},
	{},
	XY Function(
		((1 - t) * r1 + t * r2) * Cos( (1 - t) * a1 + t * a2 ),
		((1 - t) * r1 + t * r2) * Sin( (1 - t) * a1 + t * a2 ),
		t,
		Min( 0 ),
		Max( 1 )
	)
);

polarDrawText = Function( {a, r, t},
	Text( {r * Cos( a ), r * Sin( a )}, t )
);

New Window( "polar",
	Graph Box(
		suppressaxes,
		Frame Size( 800, 800 ),
		X Scale( -105, 105 ),
		Y Scale( -105, 105 ),
		Pen Color( "Blue" );
		For( r = 10, r <= 100, r += 10,
			polarDrawLine( 0, r, 2 * Pi(), r );
			polarDrawText( Pi() / 3, r - 5, Char( r, 3 ) );
		);
		Pen Color( "red" );
		For( a = 0, a < 2 * Pi(), a += Pi() / 4,
			polarDrawLine( a, 0, a, 100 );
			polarDrawText( a, 95, Char( a, 4 ) );
		);
		Pen Color( "green" );
		Pen Size( 3 );
		polarDrawLine( 1, 10, 2, 70 );
	)
);

polar graph bends a straight line

(For fun, change the green line to wrap around several times polarDrawLine( 1, 10, 20, 70 ); ... the angles 1 and 20 are in radians and 6.28 is a full circle so you get ~3 wraps.)

three loops