514827_it-IT

liliconcom

Hai bisogno di aiuto con lo script JSL per la selezione della partizione multisegmento

Il codice seguente aiuta a creare nuove tabelle con valore buono, ma è possibile scegliere solo una selezione per il popolamento non corretto con la finestra di partizione aperta. Voglio che la schermata di partizione sia aperta ma l'utente può selezionare più di un nodo foglia per la popolazione cattiva e il resto andrà alla popolazione buona. C'è un modo per fare questo?

dt = Open("$SAMPLE_DATA\semiconductor capability.jmp");
filepath = "$Desktop";

nw = New window("part test",
 V List Box(
  obj = dt << Partition(
   Y(:NPN1), 
   X(:PNP1, :PNP2, :PNP3, :PNP4, :NPN2, :NPN3, :NPN4), 
   Method("Decision Tree")
  ),
  Button box("make splits",
   make_splits_expr
  );
 )
);

obj << ShowGraph(0);
obj << SplitBest(4);
obj << Show Split Count(1);
obj << Show Split Prob(1);

make_splits_expr = Expr(
 sel_rows = dt << Get Selected Rows;
 If(N Items(sel_rows > 0),
  dtTemp = dt << subset(invisible, rows(), selected columns(0));
  Close(dtTemp, save(filepath || "\" || "badpopulation.jmp"));
  dt << invert row selection;
  sel_rows = dt << Get Selected Rows;
  dtSEG = dt << subset(invisible, selected rows(1), selected columns(0));
  Close(dtSEG, save(filepath || "\" || "goodpopulation.jmp"));
 );
 dt << Clear Selected;
);

Voglio essere in grado di selezionare i nodi evidenziati in giallo come popolazione cattiva e riposare come popolazione buona mantenendo aperta questa finestra di partizione e modificare la selezione del nodo se non sono soddisfatto del risultato.

C'è un modo per realizzarlo?

Accesso ai datifinestreRi: Hai bisogno di aiuto con lo script JSL per la selezione della partizione multisegmento

Ecco un tentativo:

 

lstSelectedRows = {};

dt = Open("$SAMPLE_DATA\semiconductor capability.jmp");
filepath = "$Desktop";

nw = New window("part test",
 V List Box(
  obj = dt << Partition(
   Y(:NPN1), 
   X(:PNP1, :PNP2, :PNP3, :PNP4, :NPN2, :NPN3, :NPN4), 
   Method("Decision Tree")
  ),
  HListBox(
   TextBox("rows selected in node = "),
   tb1 = TextBox("0"),
  ),
  HListBox(
   TextBox("total rows selected = "),
   tb2 = TextBox("0")
  ),
  ButtonBox("clear all selections",
   clear_selections
   , underlinestyle(1)
  ),
  Button box("make splits",
   make_splits_expr
  );
 )
);

// in the partition platform from any node you can select rows
// but we need to detect this event ... do it by detecting 
// row state changes in the table


rs = dt << make row state handler(
 function({a},
  cdt = current data table();
  sel = cdt << Get Selected Rows;
  insertinto(lstSelectedRows,aslist(sel));
  tmp = [=>];
  insertInto( tmp, lstSelectedRows );
  lstSelectedRows = tmp << getKeys;  // <--- dedupe
  tb1 << settext(char(nrows(sel)));
  tb2 << settext(char(nitems(lstSelectedRows)));
 )
);

obj << ShowGraph(0);
obj << SplitBest(4);
obj << Show Split Count(1);
obj << Show Split Prob(1);

clear_selections = Expr(
 dt << Clear Selected;
 tb1 << settext("0");
 tb2 << settext("0");
 lstSelectedRows = {};
);

make_splits_expr = Expr(
 dt << select rows(lstSelectedRows);
 sel_rows = dt << Get Selected Rows;
 tb1 << settext(char(nrows(sel_rows)));
 If(N Items(sel_rows > 0),
  dtTemp = dt << subset(rows(), selected columns(0), output table("Selected"));
  //Close(dtTemp, save(filepath || "\" || "badpopulation.jmp"));
  dt << invert row selection;
  sel_rows = dt << Get Selected Rows;
  dtSEG = dt << subset(selected rows(1), selected columns(0), output table("Not Selected"));
  //Close(dtSEG, save(filepath || "\" || "goodpopulation.jmp"));
 );
 dt << Clear Selected;
);

Potrei non aver capito cosa stai cercando di fare e quindi non cercherò di spiegare cosa sta succedendo con il codice - ma se è quello che stai cercando di fare sono felice di darti una spiegazione di cosa sta succedendo - fammelo sapere.Parte del codice è un po' brutta, ma volevo solo vedere se riuscivo a capire cosa stavi cercando di fare.Per mia comodità, invece di salvare 2 tabelle sul desktop, ne creo 2 (tabelle visibili) intitolate "selezionate" e "non selezionate".