514558_ja-JP

liliconcom

ループを最適化する

やあ、

大規模なデータセットの実行に時間がかかる JSL コードがあります。

このコードは、for ループ内で for ループを実行して、ストリップによる平均オフセットを計算します。 これを行うより速い方法を探しています。

処理を速くする方法はありますか？ 現在のスクリプトは、ループを完了するのに約 20 分かかります

 

以下にスクリプトを示します。

Names Default To Here( 1 );

dt1 =Data table( "Reference data table.jmp" );
dt2 = Current data table(); /// Select Data table.jmp
Col_List1 = dt2 << Get Column Names( "String" );

For( c = 1, c <= N Col( dt2 ) -1, c++,
 theMatrix = [];
 name = Column( Col_List1[c] ) << Get name;
 if (Contains( Col_List1[c], "Currents" )| Contains( Col_List1[c], "Voltage" )| Contains( Col_List1[c], "Resistance" ),
 For( r = 1, r <= N Rows( dt2 ), r++,
  mean = dt1:Mean[dt1 << Get Rows Where( :Tests == name )];
  measure = mean - Col Mean( If( dt2:Strips == dt2:Strips[r], Column( dt2, c ), . ) );
  theMatrix = theMatrix || Column( dt2, c )[r] + measure;
 );
 Column( dt2, c ) << Set Values( theMatrix );
););

 

スクリプティングRe: ループを最適化する

どうもありがとうジム。

Re: ループを最適化する

列プロパティ「theMean」が設定されていない場合、処理をバイパスするようにコードを修正しました

Names Default To Here( 1 );
start = Today();
dt1 = Data Table( "Reference data table.jmp" );
dt2 = Current Data Table(); /// Select Data table.jmp

For( i = 1, i <= N Rows( dt1 ), i++,
 theTest = dt1:Tests[i];
 Try( Column( dt2, theTest ) << set property( "TheMean", dt1:mean[i] ) );
);

Col_List1 = dt2 << Get Column Names( "String" );

For( c = 1, c <= N Col( dt2 ) - 1, c++,
 theMatrix = [];
 name = Column( Col_List1[c] ) << Get name;
 If( Contains( Col_List1[c], "Currents" ) | Contains( Col_List1[c], "Voltage" ) | Contains( Col_List1[c], "Resistance" ), 
 //For( r = 1, r <= N Rows( dt2 ), r++,
  mean = .;
  Try( mean = Column( dt2, col_list1[c] ) << get property( "theMean" ) );
  // Don't process if a value for theMean does not exist
  If( Is Missing( mean ) == 0,
   For Each Row(
    r = Row();
  //mean = dt1:Mean[dt1 << Get Rows Where( :Tests == name )];
  
    //measure = mean - Col Mean( If( dt2:Strips == dt2:Strips[r], Column( dt2, c ), . ) );
    measure = mean - Col Mean( As Column( dt2, c ), :Strips );
    theMatrix = theMatrix || Column( dt2, c )[r] + measure;
   );
   Column( dt2, c ) << Set Values( theMatrix );
  );
 );
);
Show( (start - Today()) / 60 );

Re: ループを最適化する

やあ@txnelson 、

あなたが提案したロジックにはいくつかの問題があります。 参照データ テーブルにメイン データ テーブルにあるテストが含まれていない場合、それらのテストから行の値が削除されます。 参照データテーブルにあるテストをオフセットするだけです。 どんな助けでも大歓迎です

 

以下にデータ表を添付しました。 参照テーブルに指定されているテストのみをオフセットしたい

 

Re: ループを最適化する

ジムに感謝します。 それは魅力のように機能します

Re: ループを最適化する

@ジャックスミス12 、条件が何であるかわかりませんdt2:ストリップ == dt2Strips[r]に解決されるはずですが、おそらくあなたがやりたいことをしていません。

 

テストするテスト データがない場合、これを最適化する方法を次に示します。主な方法は、dt1 を取得することです。 << Get Rows Where( :Tests == name )ループの外側。

 

Names Default to Here( 1 );

dt1 = Data Table( "Reference Data Table.jmp" );
dt2 = Current Data Table();

col list1 = dt2 << Get Column Names( "String" );

Summation( c = 1, N Col( dt2 ) - 1,  //summation is faster that For() if you don't need to use Break() or Continue()
 values = [];
 name = Column( dt2, c ) << Get Name;
 If( Contains( name, "Currents" ) | Contains( name, "Voltage" ) | Contains( name, "Resistance" ),
  rows = dt1 << Get Rows Where( :tests == name );  // As Constant() prevents JMP from doing a lookup per row
  col = Column( dt2, c );
  col mean = Col Mean( col );
  For Each Row( dt2,
   mean = dt1:Mean[rows];
   measure = mean - If( dt2:Strips == dt2:Strips /* always true */, col mean, 0 );
   values |/= col[] + measure  // append value to
  );
  col << Set Values( values )
 );
 0 // summation needs to end in a numeric
)

Re: ループを最適化する

問題が見られる2つの場所は、

mean = dt1:Mean[dt1 << Get Rows Where( :Tests == name )];

と

measure = mean - Col Mean( If( dt2:Strips == dt2:Strips[r], Column( dt2, c ), . ) );

ここに問題の回避策があります。それらをチェックして、答えが正しいかどうかを確認してください。

Names Default To Here( 1 );
start=today();
dt1 =Data table( "Reference data table.jmp" );
dt2 = Current data table(); /// Select Data table.jmp

For(i=1,i<=nrows(dt1),i++,
 theTest = dt1:Tests[i];
 try(column(dt2,theTest) << set property("TheMean", dt1:mean[i]));
);

Col_List1 = dt2 << Get Column Names( "String" );

For( c = 1, c <= N Col( dt2 ) -1, c++,
 theMatrix = [];
 name = Column( Col_List1[c] ) << Get name;
 if (Contains( Col_List1[c], "Currents" )| Contains( Col_List1[c], "Voltage" )| Contains( Col_List1[c], "Resistance" ),
 //For( r = 1, r <= N Rows( dt2 ), r++,
 For Each Row( r=row();
  //mean = dt1:Mean[dt1 << Get Rows Where( :Tests == name )];
  mean = column(dt2,col_list1[c]) << get property("theMean");
  //measure = mean - Col Mean( If( dt2:Strips == dt2:Strips[r], Column( dt2, c ), . ) );
  measure = mean - Col Mean(as Column( dt2, c ),:Strips);
  theMatrix = theMatrix || Column( dt2, c )[r] + measure;
 );
 Column( dt2, c ) << Set Values( theMatrix );
););
show((start-today())/60);