514558_fr-FR

liliconcom

Optimiser la boucle

Salut,

J'ai du code JSL qui prend beaucoup de temps à s'exécuter pour des ensembles de données plus volumineux.

Le code exécute une boucle for dans une boucle for pour calculer le décalage moyen par bandes. Je cherche un moyen plus rapide de le faire.

Existe-t-il un moyen d'accélérer le traitement ? Le script actuel prend environ 20 minutes pour terminer la boucle

 

Voici le script ci-dessous :

Names Default To Here( 1 );

dt1 =Data table( "Reference data table.jmp" );
dt2 = Current data table(); /// Select Data table.jmp
Col_List1 = dt2 << Get Column Names( "String" );

For( c = 1, c <= N Col( dt2 ) -1, c++,
 theMatrix = [];
 name = Column( Col_List1[c] ) << Get name;
 if (Contains( Col_List1[c], "Currents" )| Contains( Col_List1[c], "Voltage" )| Contains( Col_List1[c], "Resistance" ),
 For( r = 1, r <= N Rows( dt2 ), r++,
  mean = dt1:Mean[dt1 << Get Rows Where( :Tests == name )];
  measure = mean - Col Mean( If( dt2:Strips == dt2:Strips[r], Column( dt2, c ), . ) );
  theMatrix = theMatrix || Column( dt2, c )[r] + measure;
 );
 Column( dt2, c ) << Set Values( theMatrix );
););

 

ScriptRe : Optimiser la boucle

Merci beaucoup Jim.

Re : Optimiser la boucle

J'ai modifié votre code pour contourner le traitement si la propriété de colonne "theMean" n'avait pas été définie

Names Default To Here( 1 );
start = Today();
dt1 = Data Table( "Reference data table.jmp" );
dt2 = Current Data Table(); /// Select Data table.jmp

For( i = 1, i <= N Rows( dt1 ), i++,
 theTest = dt1:Tests[i];
 Try( Column( dt2, theTest ) << set property( "TheMean", dt1:mean[i] ) );
);

Col_List1 = dt2 << Get Column Names( "String" );

For( c = 1, c <= N Col( dt2 ) - 1, c++,
 theMatrix = [];
 name = Column( Col_List1[c] ) << Get name;
 If( Contains( Col_List1[c], "Currents" ) | Contains( Col_List1[c], "Voltage" ) | Contains( Col_List1[c], "Resistance" ), 
 //For( r = 1, r <= N Rows( dt2 ), r++,
  mean = .;
  Try( mean = Column( dt2, col_list1[c] ) << get property( "theMean" ) );
  // Don't process if a value for theMean does not exist
  If( Is Missing( mean ) == 0,
   For Each Row(
    r = Row();
  //mean = dt1:Mean[dt1 << Get Rows Where( :Tests == name )];
  
    //measure = mean - Col Mean( If( dt2:Strips == dt2:Strips[r], Column( dt2, c ), . ) );
    measure = mean - Col Mean( As Column( dt2, c ), :Strips );
    theMatrix = theMatrix || Column( dt2, c )[r] + measure;
   );
   Column( dt2, c ) << Set Values( theMatrix );
  );
 );
);
Show( (start - Today()) / 60 );

Re : Optimiser la boucle

Salut @txnelson ,

Il y a un problème dans la logique que vous avez suggérée. Si la table de données de référence ne contient pas les tests qui se trouvent dans la table de données principale, elle supprimera les valeurs de ligne de ces tests. J'ai seulement pour compenser le test qui sont dans la table de données de référence. Toute aide serait très appréciée

 

J'ai joint les tableaux de données ci-dessous. Je veux seulement décaler les tests qui sont spécifiés dans le tableau de référence

 

Re : Optimiser la boucle

Merci Jim. Cela fonctionne comme un charme

Re : Optimiser la boucle

@Jacksmith12 , je ne sais pas quel est le conditionnel dt2:Strips == dt2Strips[r] est censé résoudre, mais il ne fait probablement pas ce que vous voulez qu'il fasse.

 

Sans aucune donnée de test sur laquelle tester, voici comment je commencerais à optimiser cela - le principal est de prendre le dt1 << Obtenir les lignes Où( :Tests == nom ) en dehors de la boucle.

 

Names Default to Here( 1 );

dt1 = Data Table( "Reference Data Table.jmp" );
dt2 = Current Data Table();

col list1 = dt2 << Get Column Names( "String" );

Summation( c = 1, N Col( dt2 ) - 1,  //summation is faster that For() if you don't need to use Break() or Continue()
 values = [];
 name = Column( dt2, c ) << Get Name;
 If( Contains( name, "Currents" ) | Contains( name, "Voltage" ) | Contains( name, "Resistance" ),
  rows = dt1 << Get Rows Where( :tests == name );  // As Constant() prevents JMP from doing a lookup per row
  col = Column( dt2, c );
  col mean = Col Mean( col );
  For Each Row( dt2,
   mean = dt1:Mean[rows];
   measure = mean - If( dt2:Strips == dt2:Strips /* always true */, col mean, 0 );
   values |/= col[] + measure  // append value to
  );
  col << Set Values( values )
 );
 0 // summation needs to end in a numeric
)

Re : Optimiser la boucle

Les 2 endroits où je vois des problèmes sont les

mean = dt1:Mean[dt1 << Get Rows Where( :Tests == name )];

et

measure = mean - Col Mean( If( dt2:Strips == dt2:Strips[r], Column( dt2, c ), . ) );

Voici une solution pour les problèmes Vérifiez-les et voyez si les réponses sont correctes

Names Default To Here( 1 );
start=today();
dt1 =Data table( "Reference data table.jmp" );
dt2 = Current data table(); /// Select Data table.jmp

For(i=1,i<=nrows(dt1),i++,
 theTest = dt1:Tests[i];
 try(column(dt2,theTest) << set property("TheMean", dt1:mean[i]));
);

Col_List1 = dt2 << Get Column Names( "String" );

For( c = 1, c <= N Col( dt2 ) -1, c++,
 theMatrix = [];
 name = Column( Col_List1[c] ) << Get name;
 if (Contains( Col_List1[c], "Currents" )| Contains( Col_List1[c], "Voltage" )| Contains( Col_List1[c], "Resistance" ),
 //For( r = 1, r <= N Rows( dt2 ), r++,
 For Each Row( r=row();
  //mean = dt1:Mean[dt1 << Get Rows Where( :Tests == name )];
  mean = column(dt2,col_list1[c]) << get property("theMean");
  //measure = mean - Col Mean( If( dt2:Strips == dt2:Strips[r], Column( dt2, c ), . ) );
  measure = mean - Col Mean(as Column( dt2, c ),:Strips);
  theMatrix = theMatrix || Column( dt2, c )[r] + measure;
 );
 Column( dt2, c ) << Set Values( theMatrix );
););
show((start-today())/60);