511642_es-ES

liliconcom

Agregar línea de referencia de la tabla de referencia

Hola, @txnelson

Estoy tratando de crear un gráfico de trama de variabilidad y agregar líneas de referencia con diferentes valores para cada uno de los gráficos individuales. Actualmente puedo trazar la línea de referencia, pero el problema es que si la tabla de referencia no contiene todas las columnas de prueba de la tabla de datos, el script no funcionará.

 

Esto es lo que probé y funciona si la tabla de referencia tiene todas las pruebas de la tabla de datos:

 

Names Default To Here( 1 );
Clear Globals();


dt = Open("Data table.jmp"); // Open data table

// Loop to get column name Currents and Voltages
colist = {};
Col_List = dt << Get Column Names( "String" );
 
 For( q = 1, q <= N Items( Col_List ), q++, 
    
  If( Contains( Col_List[q], "Currents" ) | Contains( Col_List[q], "Voltages" ),
   Column( Col_List[q] ) << Set Selected( 1 );
   Insert Into( colist, Col_List[q] );
  )
 );
 // Var Chart
 vc= dt << Variability Chart(
        Y( (Eval( colist )) ),
        X( :Wafer ID ),
        Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
        Show Range Bars( 0 ),
        Std Dev Chart( 0 ),
        Points Jittered( 1 )
       
       );<BR />// Reference data table
dt1 = Open ("Reference table.jmp");
xb = Column(dt1, "Reference") << getValues;
// Loop to add reference line to the variability chart 
 For( i = 1, i <= N Items( vc ), i++,
  Report( vc[i] )[Framebox( 1 )] << DispatchSeg( CustomStreamSeg( 3 ), {Line Width( 2 )} );
  Report( vc[i] )[AxisBox( 1 )] << {Add Ref Line( xb[i], "Solid", "Green", "RTS", 2 )};
 );

secuencias de comandosRe: Agregar línea de referencia de la tabla de referencia

Puede recorrer colist y verificar si dt1 tiene ese valor específico con la declaración if y, si lo tiene, luego agregue una línea de referencia basada en el valor encontrado en dt1. Aquí hay una opción que usa la matriz asociativa (es posible que deba agregar una escala al eje Y para los gráficos de variabilidad, ya que las líneas de referencia se pueden ocultar según su valor).

Names Default To Here(1);

// dt = Open("Data table.jmp"); // Open data table
// dt1 = Open("Reference table.jmp");

// Loop to get column name Currents and Voltages
colist = {};
Col_List = dt << Get Column Names("String");
 
For(q = 1, q <= N Items(Col_List), q++, 
 If(Contains(Col_List[q], "Current") | Contains(Col_List[q], "Voltage"),
  Column(Col_List[q]) << Set Selected(1);
  Insert Into(colist, Col_List[q]);
 )
);
 // Var Chart
vc = dt << Variability Chart(
 Y((Eval(colist))),
 X(:Wafer ID),
 Analysis Type("Choose best analysis (EMS REML Bayesian)"),
 Show Range Bars(0),
 Std Dev Chart(0),
 Points Jittered(1) 
);// Reference data table

aa_refs = Associative Array(dt1:Tests << get values, dt1:Reference << get values);
// Loop to add reference line to the variability chart
For(i = 1, i <= N Items(colist), i++,
 If(Contains(aa_refs, colist[i]),
  Report(vc[i])[Framebox(1)] << DispatchSeg(CustomStreamSeg(3), {Line Width(2)});
  Report(vc[i])[AxisBox(1)] << {Add Ref Line(aa_refs[colist[i]], "Solid", "Green", "RTS", 2)};
 );
);

Re: Agregar línea de referencia de la tabla de referencia

Aquí hay una solución ligeramente diferente, leyendo la tabla de referencia directamente

Names Default To Here( 1 );
Clear Globals();


//dt = Open( "Data table.jmp" ); // Open data table
dt = Data Table( "data table" );

// Loop to get column name Currents and Voltages
colist = {};
Col_List = dt << Get Column Names( "String" );
 
For( q = 1, q <= N Items( Col_List ), q++, 
    
 If( Contains( Col_List[q], "Current" ) | Contains( Col_List[q], "Voltage" ),
  Column( Col_List[q] ) << Set Selected( 1 );
  Insert Into( colist, Col_List[q] );
 )
);
 // Var Chart
vc = dt << Variability Chart(
 Y( (Eval( colist )) ),
 X( :Wafer ID ),
 Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
 Show Range Bars( 0 ),
 Std Dev Chart( 0 ),
 Points Jittered( 1 )
       
);// Reference data table
//dt1 = Open( "Reference table.jmp" );
dt1 = Data Table( "reference table" );
xb = Column( dt1, "Reference" ) << getValues;
// Loop to add reference line to the variability chart 
For( i = 1, i <= N Items( vc ), i++, 
 //Report( vc[i] )[Framebox( 1 )] << DispatchSeg( CustomStreamSeg( 3 ), {Line Width( 2 )} );
 testVal = Word( -2, Report( vc[i] )[Outline Box( 2 )] << get title, " " ) || " " || Word(
  -1,
  Report( vc[i] )[Outline Box( 2 )] << get title,
  " "
 );
 testRow = dt1 << get rows where( :tests == testVal );
 If( N Rows( testRow ) > 0,
  Report( vc[i] )[AxisBox( 1 )] << Add Ref Line( dt1:Reference[testRow[1]], "Solid", "Green", "RTS", 2 )
 );
);

Re: Agregar línea de referencia de la tabla de referencia

Hola @jthi ,

Cansé su código en gráficos superpuestos, pero parece que hay un error. ¿Alguna sugerencia?

 

Names Default To Here(1);

// dt = Open("Data table.jmp"); // Open data table
// dt1 = Open("Reference table.jmp");

// Loop to get column name Currents and Voltages
colist = {};
Col_List = dt << Get Column Names("String");
 
For(q = 1, q <= N Items(Col_List), q++, 
 If(Contains(Col_List[q], "Current") | Contains(Col_List[q], "Voltage"),
  Column(Col_List[q]) << Set Selected(1);
  Insert Into(colist, Col_List[q]);
 )
);
 // Overlay Plot

  vc = dt2 << Overlay Plot( Y( Eval( colist ) ), No Overlay( 1 ),Ungroup Plots( 1 ) );
         
aa_refs = Associative Array(dt1:Tests << get values, dt1:Reference << get values);
// Loop to add reference line to the variability chart
For(i = 1, i <= N Items(colist), i++,
 If(Contains(aa_refs, colist[i]),
  Report(vc[i])[Framebox(1)] << DispatchSeg(CustomStreamSeg(3), {Line Width(2)});
  Report(vc[i])[AxisBox(1)] << {Add Ref Line(aa_refs[colist[i]], "Solid", "Green", "RTS", 2)};
 );
);

 

 

Re: Agregar línea de referencia de la tabla de referencia

Hay un par de problemas.

1. Las diferentes plataformas tienen diferentes estructuras de árbol porque tienen diferentes estructuras de salida.Por lo tanto, la asignación a los diferentes objetos dentro de la salida es diferente.
2. Especifica dt como el puntero a la "Tabla de datos", pero más adelante en el script, intenta ejecutar el gráfico de superposición, apuntando a una tabla de datos a la que hace referencia una variable dt2, que no existe en su código.
3. En su código que crea la Matriz Asociativa, usa una variable de su Tabla de Datos de Referencia, llamada Referencia.En los datos de muestra que proporcionó en la Discusión de Optimize Loop, la variable en esa tabla de datos se llama Promedio.

A continuación se muestra una modificación de su código que produce el siguiente resultado

Names Default To Here(1);

// dt = Open("Data table.jmp"); // Open data table
dt=data table("Data Table");
// dt1 = Open("Reference table.jmp");
dt1=data table("Reference data table");
// Loop to get column name Currents and Voltages
colist = {};
Col_List = dt << Get Column Names("String");
 
For(q = 1, q <= N Items(Col_List), q++, 
 If(Contains(Col_List[q], "Current") | Contains(Col_List[q], "Voltage"),
  Column(Col_List[q]) << Set Selected(1);
  Insert Into(colist, Col_List[q]);
 )
);
 // Overlay Plot

  vc = dt << Overlay Plot( Y( Eval( colist ) ), No Overlay( 1 ),Ungroup Plots( 1 ) );
         
aa_refs = Associative Array(dt1:Tests << get values, dt1:mean << get values);
// Loop to add reference line to the variability chart
For(i = 14, i <= N Items(colist), i++,
 If(Contains(aa_refs, colist[i]),
  Report(vc)[AxisBox(1)] << Add Ref Line(aa_refs[colist[i]], "Solid", "Green", "RTS", 2);
 );
);

Tómese el tiempo para leer sobre los árboles de visualización en la Guía de secuencias de comandos, disponible en la Biblioteca de documentación de JMP, en el menú desplegable Ayuda.