511218_ko-KR

liliconcom

여러 CMD 명령을 실행하려면 어떻게 합니까?

안녕하십니까,

명령 프롬프트를 사용하여 JMP에서 zip 파일(TGZ)의 간단한 추출을 시도하고 있으며 다음 접근 방식을 사용하여 수행할 수 없습니다(많은 어리석은 아이디어를 시도했지만 아무 것도 작동하지 않는 것 같습니다...) :

 

 

Names Default To Here( 1 );

path1="C:/Users/niros/Downloads/";
path2="C:/Program Files/WinRAR/WinRAR.exe";
path3="C:/Users/niros/Downloads/LP.tgz";

RP = RunProgram(
 Executable( "CMD.EXE" ),
 Options( { {"cd", path1}, {"mkdir", "testing"}, {"cd", "testing"}, {path2,"x", path3} } ),
 Read Function("text")
);

 

감사!

스크립팅Re: 여러 CMD 명령을 실행하려면 어떻게 해야 합니까?

스크립팅 인덱스의 예 3

RunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeRunProgram set up to feed commands to CMD.exeCMD.exe에 명령을 공급하도록 설정된 RunProgram

한 가지 방법입니다.

또 다른 방법은 매개변수 내에서 명령 구분 기호를 사용하는 것입니다. 예제 1에서 수정:

RP = Run Program(
    Executable( "CMD.EXE"/*path probably not needed*/ ),
    Options( {"/a", "/q", "/c dir && echo hello && ping localhost"} ),
    ReadFunction( Function( {this}, Write( this << read ) ) )
);

(위의 두 가지 모두 cmd.exe가 실행될 때 읽고 JMP 로그에 답을 쓰도록 설정되어 있습니다. readfunction("text")이 있는 원래 예제는 모든 출력을 수집하고 끝에 표시하는 더 간단하고 덜 유연한 방법입니다.)

Re: 여러 CMD 명령을 실행하려면 어떻게 해야 합니까?

모든 명령을 하나의 CMD 파일에 쓰고 실행할 수도 있습니다.

path1="C:/Users/niros/Downloads/";
path2="C:/Program Files/WinRAR/WinRAR.exe";
path3="C:/Users/niros/Downloads/LP.tgz";

//-------------------------------------------------------------------------------
// Create a command file to run multiple commands
cmd_file_text = evalinsert(
"rem Run multiple commands\!N
C:\!N
cd ^path1^\!N
mkdir testing\!N
cd testing\!N
^path2^ x ^path3^\!N
pause\!N
");
cmd_file_name = "c:\temp\run_commands.cmd";

// Save command file to disk
save text file(cmd_file_name, cmd_file_text, mode("replace"));

//-------------------------------------------------------------------------------
// The /c option carries out the command before terminating
run_cmds = runprogram(executable("cmd.exe"), options("/c " || cmd_file_name), readfunction("text"));

nw = new window("Output", << modal,
 panel box("CMD output:",
  text box(run_cmds, set width(800), set wrap(800), 
    << Set Font( "Courier New" )),
 )
);

Re: 여러 CMD 명령을 실행하려면 어떻게 해야 합니까?

그만한 가치가 있기 때문에 RunProgram을 사용하는 것은 까다롭습니다 ... 나는 우리 대부분이 작동하기 전에 많은 어리석은 아이디어를 시도해야한다고 생각합니다.

Re: 여러 CMD 명령을 실행하려면 어떻게 해야 합니까?

"\!N"을 사용하여 JSL에 의해 생성된 .cmd 파일에 하드 리턴을 추가해야 했습니다.

Re: 여러 CMD 명령을 실행하려면 어떻게 해야 합니까?

여러 번 감사합니다! PMROZ 귀하의 답변이 제가 찾던 바로 그 것입니다!

내 부분의 마지막 잘못은 \!" 문자로 쉽게 해결되는 경로의 공백입니다...

해결책:

path1="C:/Users/niros/Downloads/";
path2="\!"C:/Program Files/WinRAR/WinRAR.exe\!"";
path3="C:/Users/niros/Downloads/LP.tgz";

//-------------------------------------------------------------------------------
// Create a command file to run multiple commands
cmd_file_text = evalinsert(
"rem Run multiple commands\!N
cd ^path1^\!N
mkdir testing\!N
cd testing\!N
^path2^ x ^path3^\!N
pause\!N
");
cmd_file_name = "c:\temp\run_commands.cmd";

// Save command file to disk
save text file(cmd_file_name, cmd_file_text, mode("replace"));

//-------------------------------------------------------------------------------
// The /c option carries out the command before terminating
run_cmds = runprogram(executable("cmd.exe"), options("/c " || cmd_file_name), readfunction("text"));

nw = new window("Output", << modal,
 panel box("CMD output:",
  text box(run_cmds, set width(800), set wrap(800), 
    << Set Font( "Courier New" )),
 )
);