Graph Box with one discrete axis

DMR

Hi - my apologies in advance if the answer to this is trivial, but I want to create a Graph Box that has one continuous axis, and one discrete axis (i.e. this axis will need to show a set of text items taken from a list, shown in the order in which they appear in that list). Can this be done? If so, could somebody show me an example of the JSL needed to do it please?

txnelson

I am not aware of JMP having the ability to have an axis in a graph box that is text.  When I have such needs, one can use one of the JMP platforms that handles text axes, and then add the graphics that you need to the platform.  Or, you can use Value Labels for the text based axis, with the values of the cells being numeric.

Here is a simple example

Names Default To Here( 1 );

// Text list
NameList = {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "ROBERT", "BARBARA",
"ALICE"};

// Other axis values
AgeList = {12, 14, 13, 16, 15, 12, 12, 15, 14, 16};

// Put into a table
dt = New Table( "test data",
	New Column( "Ages", values( AgeList ) ),
	New Column( "Ordering", nominal, formula( Row() ) )
);
Wait( .1 ); // Make sure formula gets completed

// I do this to change the formula column to static values
dt:Ordering << delete formula;

// Change the NameList into the form required for Value Labels
For( i = 1, i <= N Items( NameList ), i++,
	namelist[i] = Parse( Char( dt:ordering[i] ) || " = \!"" || namelist[i] || "\!"" )
);

// Apply the Value Labels
dt:Ordering << set property("Value Labels",eval(NameList));

// Use the platform to generate the frame box
gb = Graph Builder(
	Size( 528, 464 ),
	Show Control Panel( 0 ),
	Variables( X( :Ordering ), Y( :Ages ) ),
	Elements( Points( X, Y, Legend( 3 ) ) )
);

// Sample of adding to the results of the platform
report(gb)[Frame Box(1)] << Add Graphics Script(
	Text( Center Justified, {5, 14}, "Text Added" )
);

// open a new window
nw=New Window("test", myVLB = V List Box());

// Add the platform output to the display
myVLB << append(report(gb)[frame box(1)]);