is there a way to find evaluation value ?

medo

Hello,

i would like to thank all community staffs who helped me a lot to fix my script 

i have a question, is there a way to find evaluation values(design diagnostics) for criterion (D,G,A,AV) for example PDF with all designs results  because when I evaluate my scripts , i have to see each design( 28 designs) and write criterion vlue

thank you a lot 

this is my script 

 

dt2_5_2=New Table( "First Example",
Add Rows( 17 ),
New Column( "Column 1",
Numeric,
"Continuous",
Format( "Best", 12 ),
Set Values( [-1, -1, -1, -1, -1, -1, -1, 0, 0, 0, 1, 1, 1, 1, 1, 1, 1] )
),
New Column( "Column 2",
Numeric,
"Continuous",
Format( "Best", 12 ),
Set Values( [-1, -1, -1, 0, 1, 1, 1, -1, 0, 1, -1, -1, -1, 0, 1, 1, 1] )
),
New Column( "Column 3",
Numeric,
"Continuous",
Format( "Best", 12 ),
Set Values( [-1, 1, 1, -1, -1, 0, 1, -1, 0, 1, -1, 0, 1, 1, -1, -1, 1] )
),
New Column( "Column 4",
Numeric,
"Continuous",
Format( "Best", 12 ),
Set Values( [1, -1, 1, -1, 1, -1, 0, -1, 0, 1, 0, 1, -1, 1, -1, 1, -1] )
),
New Column( "Column 5",
Numeric,
"Continuous",
Format( "Best", 12 ),
Set Values( [-1, 1, 0, 1, 1, -1, -1, -1, 0, 1, 1, 1, -1, -1, 0, -1, 1] )
),
New Column( "Column 6",
Numeric,
"Continuous",
Format( "Best", 12 ),
Set Values( [1, 1, -1, -1, 0, 1, -1, -1, 0, 1, 1, -1, 0, 1, 1, -1, -1] )
),
New Column( "Column 7",
Numeric,
"Continuous",
Format( "Best", 12 ),
Set Values( [1, 0, -1, 1, -1, -1, 1, -1, 0, 1, -1, 1, 1, -1, 1, 0, -1] )
),
New Column( "Column 8",
Numeric,
"Continuous",
Format( "Best", 12 ),
Set Selected,
Set Values( [0, -1, 1, 1, -1, 1, -1, -1, 0, 1, 1, -1, 1, -1, -1, 1, 0] )
),
Set Row States( [1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1] )
);

 

NamesDefaultToHere(1);

dt = DataTable("First Example");
cols = dt << getColumnNames;

For( c1 = 1, c1 <= N Items( cols ), c1++,
For( c2 = c1 + 1, c2 <= N Items( cols ), c2++,
For( c3 = c2 + 1, c3 <= N Items( cols ), c3++,
For( c4 = c3 + 1, c4 <= N Items( cols ), c4++,
For( c5 = c4 + 1, c5 <= N Items( cols ), c5++,
For( c6 = c5 + 1, c6 <= N Items( cols ), c6++,
//dt << Subset(Columns(cols[c1], cols[c2]))
//dt << Subset(Columns(cols[c1], cols[c2], cols[c3]));
//dt << Subset(Columns(cols[c1], cols[c2], cols[c3], cols[c4]));
//dt << Subset(Columns(cols[c1], cols[c2], cols[c3], cols[c4], cols[c5]));
dt2 = dt << Subset(
Columns(
cols[c1],
cols[c2],
cols[c3],
cols[c4],
cols[c5],
cols[c6]
)
);
dt2 << Evaluate Design(
X(
cols[c1],
cols[c2],
cols[c3],
cols[c4],
cols[c5],
cols[c6]
),
{Add Term( {1, 0} ), Add Term( {1, 1} ),
Add Term( {2, 1} ), Add Term( {3, 1} ),
Add Term( {4, 1} ), Add Term( {5, 1} ),
Add Term( {6, 1} ), Add Alias Term( {1, 1}, {2, 1} ),
Add Alias Term( {1, 1}, {3, 1} ),
Add Alias Term( {1, 1}, {4, 1} ),
Add Alias Term( {1, 1}, {5, 1} ),
Add Alias Term( {1, 1}, {6, 1} ),
Add Alias Term( {2, 1}, {3, 1} ),
Add Alias Term( {2, 1}, {4, 1} ),
Add Alias Term( {2, 1}, {5, 1} ),
Add Alias Term( {2, 1}, {6, 1} ),
Add Alias Term( {3, 1}, {4, 1} ),
Add Alias Term( {3, 1}, {5, 1} ),
Add Alias Term( {3, 1}, {6, 1} ),
Add Alias Term( {4, 1}, {5, 1} ),
Add Alias Term( {4, 1}, {6, 1} ),
Add Alias Term( {5, 1}, {6, 1} )}
);
Close(dt2, no save);
)
)
)
)
)
);

    

cwillden

@txnelson beat me to the post, but I was working on a solution that involved saving the results to a data table.  This could be made more efficient and dry, but it at least shows you how to grab values from reports by navigating through the display tree structure.  Interesting that all of the designs are exactly equivalent.

Names Default To Here( 1 );

dt = Data Table( "First Example" );
cols = dt << getColumnNames;

D_eff = List();
G_eff = List();
A_eff = List();
PredVar = List();


For( c1 = 1, c1 <= N Items( cols ), c1++,
	For( c2 = c1 + 1, c2 <= N Items( cols ), c2++,
		For( c3 = c2 + 1, c3 <= N Items( cols ), c3++,
			For( c4 = c3 + 1, c4 <= N Items( cols ), c4++,
				For( c5 = c4 + 1, c5 <= N Items( cols ), c5++,
					For( c6 = c5 + 1, c6 <= N Items( cols ), c6++, 
						dt2 = dt << Subset(
							Columns(
								cols[c1],
								cols[c2],
								cols[c3],
								cols[c4],
								cols[c5],
								cols[c6]
							)
						);
						
						//Get Evaluate Designs as Report Object
						rpt = (dt2 << Evaluate Design(
							X( cols[c1], cols[c2], cols[c3], cols[c4], cols[c5], cols[c6] ),
							{Add Term( {1, 0} ), Add Term( {1, 1} ), Add Term( {2, 1} ),
							Add Term( {3, 1} ), Add Term( {4, 1} ), Add Term( {5, 1} ),
							Add Term( {6, 1} ), Add Alias Term( {1, 1}, {2, 1} ),
							Add Alias Term( {1, 1}, {3, 1} ), Add Alias Term( {1, 1}, {4, 1} ),
							Add Alias Term( {1, 1}, {5, 1} ), Add Alias Term( {1, 1}, {6, 1} ),
							Add Alias Term( {2, 1}, {3, 1} ), Add Alias Term( {2, 1}, {4, 1} ),
							Add Alias Term( {2, 1}, {5, 1} ), Add Alias Term( {2, 1}, {6, 1} ),
							Add Alias Term( {3, 1}, {4, 1} ), Add Alias Term( {3, 1}, {5, 1} ),
							Add Alias Term( {3, 1}, {6, 1} ), Add Alias Term( {4, 1}, {5, 1} ),
							Add Alias Term( {4, 1}, {6, 1} ), Add Alias Term( {5, 1}, {6, 1} )}
						))<<Report;
						
						//Gets Reference to Design Diagnostics outline box
						Diagnostics = rpt["Design Diagnostics"]; 

						//Inserts design evaluation criteria into lists
						Insert Into(D_eff,(Diagnostics[Number Col Box(1)] << Get)[1]);
						Insert Into(G_eff,(Diagnostics[Number Col Box(2)] << Get)[1]);
						Insert Into(A_eff,(Diagnostics[Number Col Box(3)] << Get)[1]);
						Insert Into(PredVar,(Diagnostics[Number Col Box(4)] << Get)[1]);

						rpt << Close Window(); //closes Evaluate Design window						
						Close( dt2, no save ); //closes current design subset table
					)
				)
			)
		)
	)
);

dt_out = New Table("Design Evaluation Criteria");
dt_out << Set Matrix(Transpose(Matrix(list(D_eff,G_eff, A_eff, PredVar))));

Column(dt_out,1) << Set Name("D Efficiency");
Column(dt_out,2) << Set Name("G Efficiency");
Column(dt_out,3) << Set Name("A Efficiency");
Column(dt_out,4) << Set Name("Average Prediction Variance");