490857_zh-TW

liliconcom

滾動瀏覽文件夾中圖像的窗口

 

我需要一些有關腳本語法的幫助。 我正在使用 JMP 16。

 

我有一個腳本可以讀取子文件夾中的所有文件並識別具有 jpg 擴展名的文件。

 

我想做的是顯示一個窗口，帶有前進和後退按鈕，允許用戶顯示圖像。 我將如何創建它？

 

任何幫助，將不勝感激。

 

folder = char(Get Default Directory()) || "images/"; //subfolder is "images"
names = Files In Directory( folder );

dtpicnames = New Table( "Filenames of Images",
 New Column( "filename", character ),
 New Column( "inspection result", character ),
 New Column( "path", character )
);
dtpicnames << move window(800, 0);

for( ii = 1, ii <= N Items(names), ii++,
 if( Ends With( names[ii], ".jpg"),
  dtpicnames << Add Rows(1);
  dtpicnames:filename = names[ii];
  dtpicnames:path = folder || names[ii];
 );
);

img = new image(dtpicnames:path[1]);
 img << scale(0.5);

w = New Window( "Image", pb = Picture Box( img ) );
w << move window(0, 0);

 

 

高級統計建模自動化和腳本編寫消費者和市場研究內容組織質量和工藝工程回复：滾動瀏覽文件夾中圖像的窗口

這是對我係統上圖像文件夾的代碼的修改

Names Default To Here( 1 );

folder = char(Get Default Directory()) || "images/"; //subfolder is "images"

names = Files In Directory( folder );

dtpicnames = New Table( "Filenames of Images",
 New Column( "filename", character ),
 New Column( "inspection result", character ),
 New Column( "path", character )
);
dtpicnames << move window( 800, 0 );

For( ii = 1, ii <= N Items( names ), ii++,
 If( Ends With( Uppercase( names[ii] ), ".JPG" ),
  dtpicnames << Add Rows( 1 );
  dtpicnames:filename = names[ii];
  dtpicnames:path = folder || "\" || names[ii];
 )
);

theRow = 1;
img = New Image( dtpicnames:path[theRow] );
img << scale( 0.1 );
 

w = New Window( "Image",
 V List Box(
  vlb = V List Box( pb = Picture Box( img ) ),
  H List Box(
   Button Box( "Up",
    If( theRow > 1,
     theRow --;
     pb << delete;
     img = New Image( dtpicnames:path[theRow] );
     img << scale( 0.1 );
     vlb << append( pb = Picture Box( img ) )
    )
   ),
   Button Box( "Down",
    If( theRow < N Rows( dtpicnames ) - 1,
     theRow ++;
     pb << delete;
     img = New Image( dtpicnames:path[theRow] );
     img << scale( 0.1 );
     vlb << append( pb = Picture Box( img ) );
    )
   )
  )
 )
);
w << move window( 0, 0 );