489914_ko-KR

liliconcom

Re: 여러 세그먼트의 파티션을 위한 JSL 코딩

예를 들어 버튼을 사용하여 새 테이블을 만들 수 있습니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA\semiconductor capability.jmp");
filepath = "$Desktop";

nw = New window("part test",
 V List Box(
  obj = dt << Partition(
   Y(:NPN1), 
   X(:PNP1, :PNP2, :PNP3, :PNP4, :NPN2, :NPN3, :NPN4), 
   Method("Decision Tree")
  ),
  Button box("make splits",
   make_splits_expr
  );
 )
);

obj << ShowGraph(0);
obj << SplitBest(4);
obj << Show Split Count(1);
obj << Show Split Prob(1);

make_splits_expr = Expr(
 sel_rows = dt << Get Selected Rows;
 If(N Items(sel_rows > 0),
  dtTemp = dt << subset(invisible, rows(), selected columns(0));
  Close(dtTemp, save(filepath || "\" || "badpopulation.jmp"));
  dt << invert row selection;
  sel_rows = dt << Get Selected Rows;
  dtSEG = dt << subset(invisible, selected rows(1), selected columns(0));
  Close(dtSEG, save(filepath || "\" || "goodpopulation.jmp"));
 );
 dt << Clear Selected;
);

이 예제에서는 적절한 오류 처리 및 진행 상황을 사용자에게 알려주지 않습니다.

다중 세그먼트 분할을 위한 JSL 코딩

다음 코드를 사용하면 행 선택 옵션을 통해 파티션 트리에서 여러 리프 노드를 선택할 수 있습니다. 그러나 사용자가 좋은 개체군과 나쁜 개체군을 파일 생성하기 위해 리프 노드를 선택한 후에는 파티션 창을 닫아야 합니다. 파티션 창을 닫을 필요가 없는 대안이 있습니까? 또는 내가 사용할 수있는 onClose() 대신 다른 기능이 있습니까?

 

dt = Open( "$SAMPLE_DATA\semiconductor capability.jmp" );
// Matrix of all rows that were selected
::wasSelected = [];

// Row state handler function
updateWasSelected = Function( {x},
 {Default Local}, 
    // 'x' is a column vector of row states that have CHANGED. We just need those that are now selected . . .
 For( i = 1, i <= N Row( x ), i++, 
        // Need to accumulate selected rows, not adding duplicates
  If( Selected( Row State( x[i] ) ) & !Contains( ::wasSelected, x[i] ),
   ::wasSelected = V Concat( ::wasSelected, x[i] )
  )
 )
);

// Assign the handler to the table
rsh = dt << MakeRowStateHandler( updateWasSelected );

obj = dt << Partition(
 Y( :NPN1 ),
 X( :PNP1, :PNP2, :PNP3, :PNP4, :NPN2, :NPN3, :NPN4 ),
 Method( "Decision Tree" )
);
obj << ShowGraph( 0 );
obj << SplitBest( 4 );
obj << Show Split Count( 1 );
obj << Show Split Prob( 1 );
obj << onClose(
 If( N Rows( ::wasSelected ) > 0,
  filepath = "$Desktop";
  Try(
   dtTemp = dt << subset( invisible, rows( ::wasSelected ), selected columns( 0 ) );
   Close( dtTemp, save( filepath || "\" || "badpopulation.jmp" ) );
  ,
   Print( "No rows for table!" )
  );
  dt << invert row selection;
  Try(
   dtSEG = dt << subset( invisible, selected rows( 1 ), selected columns( 0 ) );
   Close( dtSEG, save( filepath || "\" || "goodpopulation.jmp" ) );
  ,
   Print( "No rows" )
  );
 );
 dt << clearRowStates;
);

 

 

해석학스크립팅창