485814_zh-TW

liliconcom

FOR 和 FOR EACH 迴圈之間的區別

有人可以解釋為什麼會這樣嗎：

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );
col = { :Runtime, :RunPulse, :RstPulse };

y expr  = Expr( Y() );
For( c = 1, c <= N Items( col ), c++,
 Insert Into( y expr, col[c] );
);

Name Expr(y expr);

產生預期的輸出

Y( :Runtime, :RunPulse, :RstPulse )

但是這個：

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );
col = { :Runtime, :RunPulse, :RstPulse };

y expr  = Expr( Y() );
For each({coll, index},col,
 Insert Into( y expr, coll );
);

Name Expr(y expr);

產生這個：

Y( ., ., . )

我希望它能給出相同的結果？ 我應該如何更改 FOR EACH 迴圈才能得到相同的結果？

 

 

消費者與市場研究分享和交流成果回覆：FOR 和 FOR EACH 迴圈之間的區別

這不是一個錯誤——在這種情況下，它實際上是 JMP 保持一致的。對清單建立索引時，傳回的結果未計算。當將索引項的結果儲存到變數中時，它會評估結果。請記住For Each( {值, 索引}, 列表, 表達式... ）相當於For( 索引 = 1, 索引 <= N 項( 列表 ), 索引++, 值 = 列表[索引]; 表達式... ）

 

A = {1 + 2, 2 + 3, 3 + 4};
b = {};
res = A[1];
Insert Into( b, A[1] );
Insert Into( b, res );
b
/*:

{1 + 2, 3}

 

回覆：FOR 和 FOR EACH 迴圈之間的區別

是的，就是這樣。

這是一種奇怪的行為，因為 1. 我們有 For Each Row 語句用於按行評估，並且 2. For Each 應該像 For 循環一樣對待一個列表（我正在嘗試使用對列的引用列表）。

這是一個錯誤還是有意的行為？

回覆：FOR 和 FOR EACH 迴圈之間的區別

我的猜測是，列被評估為 For Each 中的當前行值（例如，您可以透過添加 Row() = 1; 來測試這一點）。 您可以透過使用 Name Expr() 來避免這種情況

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Fitness.jmp");
col = {:Runtime, :RunPulse, :RstPulse};

y expr = Expr(Y());
For(c = 1, c <= N Items(col), c++,
 Insert Into(y expr, col[c]);
);
Show(Name Expr(y expr));

Row() = 1;
y expr = Expr(Y());
For Each({coll, index}, col, 
 Insert Into(y expr, coll);
);
Show(Name Expr(y expr));

y expr = Expr(Y());
For Each({coll, index}, col, 
 Insert Into(y expr, Name Expr(coll));
);
Show(Name Expr(y expr));