485814_zh-TW

liliconcom

FOR 和 FOR EACH 循環之間的區別

有人可以解釋為什麼會這樣：

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );
col = { :Runtime, :RunPulse, :RstPulse };

y expr  = Expr( Y() );
For( c = 1, c <= N Items( col ), c++,
 Insert Into( y expr, col[c] );
);

Name Expr(y expr);

產生預期的輸出

Y( :Runtime, :RunPulse, :RstPulse )

但是這個：

dt = Open( "$SAMPLE_DATA/Fitness.jmp" );
col = { :Runtime, :RunPulse, :RstPulse };

y expr  = Expr( Y() );
For each({coll, index},col,
 Insert Into( y expr, coll );
);

Name Expr(y expr);

產生這個：

Y( ., ., . )

我希望它給出相同的結果？ 我應該如何更改 FOR EACH 循環以給出相同的結果？

 

 

腳本回复： FOR 和 FOR EACH 循環之間的區別

我的猜測是，這些列被評估為 For Each 中的當前行值（例如，您可以通過添加 Row() = 1; 來測試它）。 您可以通過使用 Name Expr() 來避免這種情況

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Fitness.jmp");
col = {:Runtime, :RunPulse, :RstPulse};

y expr = Expr(Y());
For(c = 1, c <= N Items(col), c++,
 Insert Into(y expr, col[c]);
);
Show(Name Expr(y expr));

Row() = 1;
y expr = Expr(Y());
For Each({coll, index}, col, 
 Insert Into(y expr, coll);
);
Show(Name Expr(y expr));

y expr = Expr(Y());
For Each({coll, index}, col, 
 Insert Into(y expr, Name Expr(coll));
);
Show(Name Expr(y expr));

回复： FOR 和 FOR EACH 循環之間的區別

是的，就是這樣。

這是一種奇怪的行為，因為 1. 我們有 For Each Row 語句用於逐行評估，以及 2. For Each 應該將列表（並且我正在嘗試使用對列的引用列表）與 For 循環相同。

這是一個錯誤還是預期的行為？